source: trunk/Clp/configure.ac @ 1655

Last change on this file since 1655 was 1655, checked in by mjs, 8 years ago

Relicense under the Eclipse Public License.

  • Property svn:keywords set to Id
File size: 5.5 KB
Line 
1# Copyright (C) 2006 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Eclipse Public License.
4
5## $Id: configure.ac 1655 2010-12-30 21:26:23Z mjs $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8
9#############################################################################
10#                       Names and other basic things                        #
11#############################################################################
12
13AC_PREREQ(2.59)
14
15AC_INIT([Clp],[trunk],[clp@list.coin-or.org])
16
17AC_COPYRIGHT([
18Copyright 2006 International Business Machines and others.
19All Rights Reserved.
20This file is part of the open source package Coin which is distributed
21under the Eclipse Public License.])
22
23# List one file in the package so that the configure script can test
24# whether the package is actually there
25AC_CONFIG_SRCDIR(src/ClpSimplex.cpp)
26
27# Where should everything be installed by default?  Here, we want it
28# to be installed directly in 'bin', 'lib', 'include' subdirectories
29# of the directory where configure is run.  The default would be
30# /usr/local.
31AC_PREFIX_DEFAULT([`pwd`])
32
33#############################################################################
34#                         Standard build tool stuff                         #
35#############################################################################
36
37# Get the system type
38AC_CANONICAL_BUILD
39
40# If this project depends on external projects, the Externals file in
41# the source root directory contains definition of where to find those
42# externals.  The following macro ensures that those externals are
43# retrieved by svn if they are not there yet.
44AC_COIN_PROJECTDIR_INIT(Clp)
45
46# Check if user wants to produce debugging code
47AC_COIN_DEBUG_COMPILE(Clp)
48
49# Get the name of the C++ compiler and appropriate compiler options
50AC_COIN_PROG_CXX
51
52# Initialize automake and libtool
53AC_COIN_INIT_AUTO_TOOLS
54
55#############################################################################
56#                              COIN-OR components                           #
57#############################################################################
58
59AC_COIN_CHECK_PACKAGE(CoinUtils, [coinutils], [ClpLib])
60if test $coin_has_coinutils != yes ; then
61  AC_MSG_ERROR([Required package CoinUtils not available.])
62fi
63AC_COIN_CHECK_PACKAGE(Osi,       [osi],               [OsiClpLib])
64AC_COIN_CHECK_PACKAGE(OsiTests,  [osi-unittests])
65AC_COIN_CHECK_PACKAGE(Sample,    [coindatasample])
66AC_COIN_CHECK_PACKAGE(Netlib,    [coindatanetlib])
67
68#############################################################################
69#                        Third party linear solvers                         #
70#############################################################################
71
72# WSMP
73AC_ARG_WITH([wsmp],
74            AC_HELP_STRING([--with-wsmp],
75                           [specify WSMP library]),
76            [use_wsmp=$withval], [use_wsmp=no])
77
78if test "$use_wsmp" != "no"; then
79  CLPLIB_LIBS="$use_wsmp $CLPLIB_LIBS"
80  CLPLIB_PCLIBS="$use_wsmp $CLPLIB_PCLIBS"
81
82  defval=
83  AC_MSG_CHECKING([whether user-supplied WSMP library \"$use_wsmp\" works (symbol wssmp_)])
84  AC_TRY_LINK([],[wssmp_()],
85              [AC_MSG_RESULT(yes)
86               defval=2],
87              [AC_MSG_RESULT(no)])
88  if test "$defval" = ""; then
89    AC_MSG_CHECKING([whether user-supplied WSMP library \"$use_wsmp\" works (symbol wssmp)])
90    AC_TRY_LINK([],[wssmp()],
91                [AC_MSG_RESULT(yes)
92                 defval=3],
93                [AC_MSG_RESULT(no)])
94  fi
95  if test "x$defval" = "x"; then
96    AC_MSG_ERROR([WSMP library $use_wsmp does not seem to work])
97  fi
98
99  AC_DEFINE_UNQUOTED([WSSMP_BARRIER], [$defval],
100                     [Define to 2 if wssmp_ is available, and to 3 if wssmp is available])
101fi
102
103#############################################################################
104#                             Other dependencies                            #
105#############################################################################
106
107AC_COIN_CHECK_GNU_READLINE(ClpLib)
108
109##############################################################################
110#                   VPATH links for example input files                      #
111##############################################################################
112
113# In case this is a VPATH configuration we need to make sure that the
114# input files for the examples are available in the VPATH directory.
115
116AC_COIN_VPATH_LINK(examples/hello.mps)
117AC_COIN_VPATH_LINK(examples/input.130)
118
119#############################################################################
120#                  Check for doxygen                                        #
121#############################################################################
122
123AC_COIN_DOXYGEN(CoinUtils Osi)
124
125##############################################################################
126#                   Finishing up by writing all the output                   #
127##############################################################################
128
129# Here list all the files that configure should create (except for the
130# configuration header file)
131AC_CONFIG_FILES([Makefile
132                 examples/Makefile
133                 src/Makefile
134                 src/OsiClp/Makefile
135                 test/Makefile
136                 clp.pc
137                 clp-uninstalled.pc])
138                 
139if test $coin_has_osi = yes ; then
140  AC_CONFIG_FILES([osi-clp.pc:src/OsiClp/osi-clp.pc.in
141                   osi-clp-uninstalled.pc:src/OsiClp/osi-clp-uninstalled.pc.in])
142fi
143
144AC_CONFIG_FILES([doxydoc/doxygen.conf])
145
146# Here put the location and name of the configuration header file
147AC_CONFIG_HEADER([inc/config_clp.h])
148
149# Finally, we let configure write all the output...
150AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.