source: stable/1.6/Clp/configure.ac @ 1133

Last change on this file since 1133 was 1088, checked in by andreasw, 13 years ago

merging changes from Bug Squashing Party Aug 2007 to regular trunk

  • Property svn:keywords set to Author Date Id Revision
File size: 4.7 KB
Line 
1# Copyright (C) 2006 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Common Public License.
4
5## $Id: configure.ac 1088 2007-08-20 04:05:19Z ladanyi $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8
9#############################################################################
10#                       Names and other basic things                        #
11#############################################################################
12
13AC_PREREQ(2.59)
14
15AC_INIT([Clp],[1.4trunk],[coin-clp@list.coin-or.org])
16
17AC_COPYRIGHT([
18Copyright 2006 International Business Machines and others.
19All Rights Reserved.
20This file is part of the open source package Coin which is distributed
21under the Common Public License.])
22
23# List one file in the package so that the configure script can test
24# whether the package is actually there
25AC_CONFIG_SRCDIR(src/ClpCholeskyBase.cpp)
26
27# Where should everything be installed by default?  Here, we want it
28# to be installed directly in 'bin', 'lib', 'include' subdirectories
29# of the directory where configure is run.  The default would be
30# /usr/local.
31AC_PREFIX_DEFAULT([`pwd`])
32
33#############################################################################
34#                         Standard build tool stuff                         #
35#############################################################################
36
37# Get the system type
38AC_CANONICAL_BUILD
39
40# If this project depends on external projects, the Externals file in
41# the source root directory contains definition of where to find those
42# externals.  The following macro ensures that those externals are
43# retrieved by svn if they are not there yet.
44AC_COIN_PROJECTDIR_INIT
45
46# Check if user wants to produce debugging code
47AC_COIN_DEBUG_COMPILE(Clp)
48
49# Get the name of the C++ compiler and appropriate compiler options
50AC_COIN_PROG_CXX
51
52# Initialize automake and libtool
53AC_COIN_INIT_AUTO_TOOLS
54
55#############################################################################
56#                              COIN components                              #
57#############################################################################
58
59AC_COIN_HAS_PROJECT(CoinUtils)
60AC_COIN_HAS_PROJECT(Clp)
61
62#############################################################################
63#                        Third party linear solvers                         #
64#############################################################################
65
66# WSMP
67AC_ARG_WITH([wsmp],
68            AC_HELP_STRING([--with-wsmp],
69                           [specify WSMP library]),
70            [use_wsmp=$withval], [use_wsmp=no])
71
72if test "$use_wsmp" != "no"; then
73  LIBS="$use_wsmp $LIBS"
74  ADDLIBS="$use_wsmp $ADDLIBS"
75
76  defval=
77  AC_MSG_CHECKING([whether user-supplied WSMP library \"$use_wsmp\" works (symbol wssmp_)])
78  AC_TRY_LINK([],[wssmp_()],
79              [AC_MSG_RESULT(yes)
80               defval=2],
81              [AC_MSG_RESULT(no)])
82  if test "$defval" = ""; then
83    AC_MSG_CHECKING([whether user-supplied WSMP library \"$use_wsmp\" works (symbol wssmp)])
84    AC_TRY_LINK([],[wssmp()],
85                [AC_MSG_RESULT(yes)
86                 defval=3],
87                [AC_MSG_RESULT(no)])
88  fi
89  if test "$defval" = ""; then
90    AC_MSG_ERROR([WSMP library $use_wsmp does not seem to work])
91  fi
92
93  AC_DEFINE_UNQUOTED([WSSMP_BARRIER], [$defval],
94                     [Define to 2 if wssmp_ is available, and to 3 if wssmp is available])
95fi
96
97#############################################################################
98#                             Other dependencies                            #
99#############################################################################
100
101AC_COIN_CHECK_GNU_READLINE
102
103##############################################################################
104#                   VPATH links for example input files                      #
105##############################################################################
106
107# In case this is a VPATH configuration we need to make sure that the
108# input files for the examples are available in the VPATH directory.
109
110AC_COIN_VPATH_LINK(examples/hello.mps)
111AC_COIN_VPATH_LINK(examples/input.130)
112
113##############################################################################
114#                   Finishing up by writing all the output                   #
115##############################################################################
116
117# Here list all the files that configure should create (except for the
118# configuration header file)
119AC_CONFIG_FILES([Makefile
120                 examples/Makefile
121                 src/Makefile
122                 test/Makefile
123                 clp_addlibs.txt])
124
125# Here put the location and name of the configuration header file
126AC_CONFIG_HEADER([inc/config_clp.h])
127
128# Finally, we let configure write all the output...
129AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.