source: branches/split/Clp/configure.ac @ 1522

Last change on this file since 1522 was 1522, checked in by stefan, 10 years ago

merge chgsets 1391:1520 from BSPsplit branch: pkg-config setup

  • Property svn:keywords set to Id
File size: 5.6 KB
Line 
1# Copyright (C) 2006 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Common Public License.
4
5## $Id: configure.ac 1522 2010-02-21 18:56:28Z stefan $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8
9#############################################################################
10#                       Names and other basic things                        #
11#############################################################################
12
13AC_PREREQ(2.59)
14
15AC_INIT([Clp],[trunk],[coin-clp@list.coin-or.org])
16
17AC_COPYRIGHT([
18Copyright 2006 International Business Machines and others.
19All Rights Reserved.
20This file is part of the open source package Coin which is distributed
21under the Common Public License.])
22
23# List one file in the package so that the configure script can test
24# whether the package is actually there
25AC_CONFIG_SRCDIR(src/ClpCholeskyBase.cpp)
26
27# Where should everything be installed by default?  Here, we want it
28# to be installed directly in 'bin', 'lib', 'include' subdirectories
29# of the directory where configure is run.  The default would be
30# /usr/local.
31AC_PREFIX_DEFAULT([`pwd`])
32
33#############################################################################
34#                         Standard build tool stuff                         #
35#############################################################################
36
37# Get the system type
38AC_CANONICAL_BUILD
39
40# If this project depends on external projects, the Externals file in
41# the source root directory contains definition of where to find those
42# externals.  The following macro ensures that those externals are
43# retrieved by svn if they are not there yet.
44AC_COIN_PROJECTDIR_INIT
45
46# Check if user wants to produce debugging code
47AC_COIN_DEBUG_COMPILE(Clp)
48
49# Get the name of the C++ compiler and appropriate compiler options
50AC_COIN_PROG_CXX
51
52# Initialize automake and libtool
53AC_COIN_INIT_AUTO_TOOLS
54
55#############################################################################
56#                              COIN components                              #
57#############################################################################
58
59AC_COIN_HAS_MODULE(CoinUtils,  [coinutils = split])
60AC_COIN_HAS_MODULE(Sample,     [coindatasample], [required=0])
61AC_COIN_HAS_MODULE(Netlib,     [coindatanetlib], [required=0])
62
63if test "$coin_has_coinutils" != yes ; then
64  AC_COIN_HAS_PROJECT(CoinUtils)
65  if test $coin_has_coinutils != notGiven && test $coin_has_coinutils != skipping ; then
66    COINUTILS_CFLAGS="-I`${CYGPATH_W} ${COINUTILSSRCDIR}/src` -I`${CYGPATH_W} ${COINUTILSOBJDIR}/inc`"
67    COINUTILS_LIBS="${COINUTILSOBJDIR}/src/libCoinUtils.la `cat ${COINUTILSOBJDIR}/coinutils_addlibs.txt`"
68  else
69    AC_MSG_ERROR("Required package CoinUtils unavailable.")
70  fi
71fi
72
73#############################################################################
74#                        Third party linear solvers                         #
75#############################################################################
76
77# WSMP
78AC_ARG_WITH([wsmp],
79            AC_HELP_STRING([--with-wsmp],
80                           [specify WSMP library]),
81            [use_wsmp=$withval], [use_wsmp=no])
82
83if test "$use_wsmp" != "no"; then
84  LIBS="$use_wsmp $LIBS"
85  ADDLIBS="$use_wsmp $ADDLIBS"
86
87  defval=
88  AC_MSG_CHECKING([whether user-supplied WSMP library \"$use_wsmp\" works (symbol wssmp_)])
89  AC_TRY_LINK([],[wssmp_()],
90              [AC_MSG_RESULT(yes)
91               defval=2],
92              [AC_MSG_RESULT(no)])
93  if test "$defval" = ""; then
94    AC_MSG_CHECKING([whether user-supplied WSMP library \"$use_wsmp\" works (symbol wssmp)])
95    AC_TRY_LINK([],[wssmp()],
96                [AC_MSG_RESULT(yes)
97                 defval=3],
98                [AC_MSG_RESULT(no)])
99  fi
100  if test "$defval" = ""; then
101    AC_MSG_ERROR([WSMP library $use_wsmp does not seem to work])
102  fi
103
104  AC_DEFINE_UNQUOTED([WSSMP_BARRIER], [$defval],
105                     [Define to 2 if wssmp_ is available, and to 3 if wssmp is available])
106fi
107
108#############################################################################
109#                           CLP version number                              #
110#############################################################################
111
112AC_DEFINE_UNQUOTED(CLPVERSION, "$PACKAGE_VERSION", "Version of Clp")
113
114#############################################################################
115#                             Other dependencies                            #
116#############################################################################
117
118AC_COIN_CHECK_GNU_READLINE
119
120##############################################################################
121#                   VPATH links for example input files                      #
122##############################################################################
123
124# In case this is a VPATH configuration we need to make sure that the
125# input files for the examples are available in the VPATH directory.
126
127AC_COIN_VPATH_LINK(examples/hello.mps)
128AC_COIN_VPATH_LINK(examples/input.130)
129
130##############################################################################
131#                   Finishing up by writing all the output                   #
132##############################################################################
133
134# Here list all the files that configure should create (except for the
135# configuration header file)
136AC_CONFIG_FILES([Makefile
137                 examples/Makefile
138                 src/Makefile
139                 test/Makefile
140                 clp_addlibs.txt
141                 clp.pc
142                 clp-uninstalled.pc])
143
144# Here put the location and name of the configuration header file
145AC_CONFIG_HEADER([inc/config_clp.h])
146
147# Finally, we let configure write all the output...
148AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.