source: stable/2.9/Cbc/configure.ac @ 2212

Last change on this file since 2212 was 2212, checked in by tkr, 3 years ago

temporarily committing release candidate

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 15.2 KB
Line 
1# Copyright (C) 2006, 2007 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Eclipse Public License.
4
5## $Id: configure.ac 2212 2015-09-22 16:20:00Z tkr $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8
9#############################################################################
10#                       Names and other basic things                        #
11#############################################################################
12
13AC_PREREQ(2.59)
14
15AC_INIT([Cbc],[2.9.6],[cbc@lists.coin-or.org])
16
17AC_COPYRIGHT([
18Copyright 2006 International Business Machines and others.
19All Rights Reserved.
20This file is part of the open source package Coin which is distributed
21under the Eclipse Public License.])
22
23# List one file in the package so that the configure script can test
24# whether the package is actually there
25AC_CONFIG_SRCDIR(src/CbcTree.hpp)
26
27# Where should everything be installed by default?  Here, we want it
28# to be installed directly in 'bin', 'lib', 'include' subdirectories
29# of the directory where configure is run.  The default would be
30# /usr/local.
31AC_PREFIX_DEFAULT([`pwd`])
32
33#############################################################################
34#                         Standard build tool stuff                         #
35#############################################################################
36
37# Get the system type
38AC_CANONICAL_BUILD
39
40# If this project depends on external projects, the Externals file in
41# the source root directory contains definition of where to find those
42# externals.  The following macro ensures that those externals are
43# retrieved by svn if they are not there yet.
44AC_COIN_PROJECTDIR_INIT(Cbc,12:6:9)
45
46# Check if user wants to produce debugging code
47AC_COIN_DEBUG_COMPILE(Cbc)
48
49# Get the name of the C++ compiler and appropriate compiler options
50AC_COIN_PROG_CXX
51
52# Initialize automake and libtool
53AC_COIN_INIT_AUTO_TOOLS
54
55#############################################################################
56#                            COIN-OR components                             #
57#############################################################################
58
59AC_COIN_CHECK_PACKAGE(CoinDepend, [cgl osi coinutils], [CbcLib CbcGeneric])
60if test $coin_has_coindepend != yes ; then
61  AC_MSG_ERROR([One or more required packages CoinUtils, Osi, and Cgl are not available.])
62fi
63
64# Clp and OsiClp are inseparable here.
65
66AC_COIN_CHECK_PACKAGE(Clp, [osi-clp], [CbcLib CbcGeneric])
67if test $coin_has_clp != yes ; then
68  AC_MSG_ERROR("Required package Clp unavailable.")
69fi
70
71# The rest are not required for linking against Cbc
72
73AC_COIN_CHECK_PACKAGE(OsiTests, [osi-unittests])
74AC_COIN_CHECK_PACKAGE(Sample,   [coindatasample])
75AC_COIN_CHECK_PACKAGE(Netlib,   [coindatanetlib])
76AC_COIN_CHECK_PACKAGE(Miplib3,  [coindatamiplib3])
77
78# Cbc really should make these tests; right now it assumes far too much about
79# its environment. Needed for cbc-generic.
80
81AC_COIN_CHECK_CXX_CHEADER(math)
82AC_COIN_CHECK_CXX_CHEADER(float)
83AC_COIN_CHECK_CXX_CHEADER(ieeefp)
84
85AC_COIN_CHECK_GNU_READLINE(CbcLib CbcGeneric)
86
87#############################################################################
88#                    LP solvers other than CLP                              #
89#############################################################################
90
91# Check which other LP solvers are available, some of them become a dependency of CbcGeneric
92AC_COIN_CHECK_PACKAGE(DyLP, [osi-dylp],   [CbcGeneric])
93AC_COIN_CHECK_PACKAGE(Vol,  [osi-vol])
94AC_COIN_CHECK_PACKAGE(Cpx,  [osi-cplex],  [CbcLib CbcGeneric])
95AC_COIN_CHECK_PACKAGE(Glpk, [osi-glpk],   [CbcGeneric])
96AC_COIN_CHECK_PACKAGE(Grb,  [osi-gurobi])
97AC_COIN_CHECK_PACKAGE(Msk,  [osi-mosek],  [CbcGeneric])
98AC_COIN_CHECK_PACKAGE(Spx,  [osi-soplex], [CbcGeneric])
99AC_COIN_CHECK_PACKAGE(Xpr,  [osi-xpress])
100
101#############################################################################
102#                       Other third party software                          #
103#############################################################################
104
105# Ampl Solver library
106AC_COIN_CHECK_PACKAGE(ASL, [coinasl], [CbcLib CbcGeneric])
107
108# Nauty library (for symmetry detection)
109AC_LANG_PUSH(C)
110AC_COIN_CHECK_USER_LIBRARY([Nauty],[NTY],[nauty.h],[nauty],,[CbcLib CbcGeneric])
111AC_LANG_POP(C)
112
113#############################################################################
114#                       CbcGeneric configuration                            #
115#############################################################################
116
117# Are we building cbc-generic? Default is no (false).
118
119AC_ARG_WITH([cbc-generic],
120  AS_HELP_STRING([--with-cbc-generic],
121                 [specify whether to build cbc-generic (default: no)]),
122  [case $withval in
123    yes) cbc_with_cbc_generic=true ;;
124      *) cbc_with_cbc_generic=false ;;
125   esac],
126  [cbc_with_cbc_generic=false])
127if test x"$cbc_with_cbc_generic" = xyes ; then
128  AC_MSG_NOTICE([building cbc-generic])
129fi
130AM_CONDITIONAL(CBC_BUILD_CBC_GENERIC,
131               test x"$cbc_with_cbc_generic" = xtrue)
132
133# Set the default solver for cbc-generic. In theory, any OsiXXX should work.
134# In practice, only the three listed below have had any testing.
135
136AC_MSG_CHECKING(for cbc-generic default solver)
137AC_ARG_WITH([cbc-generic-solver],
138            AC_HELP_STRING([--with-cbc-generic-solver],
139                           [specify default solver for cbc-generic in lower
140                            case letters (if not given, clp is assumed)]),
141            [cbc_default_solver=$withval],
142            [cbc_default_solver=clp])
143AC_MSG_RESULT($cbc_default_solver)
144
145# FIXME what about cplex and mosek here?
146case $cbc_default_solver in
147    clp)
148      ;;
149   dylp)
150      ;;
151   glpk)
152      ;;
153 soplex)
154      ;;
155      *)
156      AC_MSG_WARN([Unrecognised solver $cbc_default_solver chosen as cbc-generic default solver.])
157      ;;
158esac
159AC_DEFINE_UNQUOTED([CBC_DEFAULT_SOLVER],"$cbc_default_solver",
160  [Define to the name of the default solver to be used in cbc-generic in small letters])
161
162
163#############################################################################
164#                       Cbc parallel configuration                          #
165#############################################################################
166
167# First we define a new option, --enable-cbc-parallel
168
169AC_ARG_ENABLE([cbc-parallel],
170[AC_HELP_STRING([--enable-cbc-parallel],
171                [enables compilation of the SMP version of Cbc])])
172
173if test "$enable_cbc_parallel" = yes; then
174  # Define the preprocessor macro
175  AC_DEFINE([CBC_THREAD],[1],[Define to 1 if the SMP version of Cbc should be compiled])
176  if test $coin_cxx_is_cl = true ;
177  then
178    # TODO we should check whether the library works and pthread.h is indeed there
179    AC_ARG_WITH(pthreadsw32-lib,
180                AC_HELP_STRING([--with-pthreadsw32-lib],
181                               [specify the name of the pthreads win32 library (for cl/icl builds only)]),
182                [CBCLIB_LIBS="$withval $CBCLIB_LIBS"
183                 CBCLIB_PCLIBS="$withval $CBCLIB_PCLIBS"],
184                [AC_MSG_WARN([--enable-cbc-parallel selected, but --with-pthreadsw32-lib not given])
185                 CBCLIB_LIBS="pthreadVCE2.lib $CBCLIB_LIBS"])
186   
187    AC_ARG_WITH(pthreadsw32-incdir,
188                AC_HELP_STRING([--with-pthreadsw32-incdir],
189                               [specify the path of the pthreads win32 header file (for cl/icl builds only)]),
190                [CXXFLAGS="$CXXFLAGS -I$withval"],
191                [AC_MSG_WARN([--enable-cbc-parallel selected, but --with-pthreadsw32-incdir not given])])
192  else
193    AC_CHECK_LIB([rt],[clock_gettime],
194                 [CBCLIB_LIBS="-lrt $CBCLIB_LIBS"
195                  CBCLIB_PCLIBS="-lrt $CBCLIB_PCLIBS"
196                  AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Define if clock_gettime and rt library is available])
197                 ],
198                 [AC_MSG_WARN([--enable-cbc-parallel selected, but -lrt unavailable; using gettimeofday instead of clock_gettime])])
199    AC_CHECK_LIB([pthread],[pthread_create],
200                 [CBCLIB_LIBS="-lpthread $CBCLIB_LIBS"
201                  CBCLIB_PCLIBS="-lpthread $CBCLIB_PCLIBS"
202                 ],
203                 [AC_MSG_ERROR([--enable-cbc-parallel selected, but -lpthreads unavailable])])
204  fi
205  AC_MSG_NOTICE([Cbc multithreading enabled]);
206fi
207
208##############################################################################
209#                            OsiCbc configuration                            #
210##############################################################################
211
212# Handles configuration of the underlying default solver in OsiCbc. The issue
213# is that OsiCbc defines a default solver, used when the client does not     
214# specify a solver in the constructor. The default solver must, therefore,   
215# be present in the build. This macro checks that this is true, and sets the
216# compile-time symbols OSICBC_DFLT_SOLVER, OSICBC_CLP_DFLT_SOLVER, and
217# OSICBC_DFLT_SOLVER_HPP that control the build. The parameter default_solver
218# should normally be clp, unless you're working on some other solver.
219
220# Ideally, this macro would not require enumeration of solvers, but the
221# effort required to avoid it is just not justified at present. One enumeration
222# is hidden in AC_OSI_CANONICAL. The other is visible, the AM_CONDITIONAL
223# list at the end.                                                             
224
225# In an ideal world this macro would do absolutely nothing if Cbc is not
226# present, but autotools is not an ideal world and we have to satisfy its
227# requirements. In particular, the AM_CONDITIONAL macros need to execute or
228# automake will complain. Really the only thing we need to suppress is the
229# check that the default solver exists. All the rest is irrelevant when Cbc
230# isn't present (hence OsiCbc will be configured but not actually compiled).
231
232# Process the with-osicbc-default-solver option.
233
234AC_ARG_WITH([osicbc-default-solver],
235  AS_HELP_STRING([--with-osicbc-default-solver],
236     [specify underlying solver for OsiCbc (default clp)]),
237     [osicbc_with_solver=$withval],
238     [osicbc_with_solver=clp])
239
240case "${osicbc_with_solver}" in
241  @<:@Cc@:>@@<:@Ll@:>@@<:@Pp@:>@*)
242    osi_lc_solver=clp ;           
243    osi_mc_solver=Clp ;           
244    osi_uc_solver=CLP ;           
245    osi_exists_solver=${coin_has_clp-"unavailable"}
246    ;;                                             
247  @<:@Dd@:>@@<:@Yy@:>@@<:@Ll@:>@@<:@Pp@:>@*)       
248    osi_lc_solver=dylp ;                           
249    osi_mc_solver=Dylp                             
250    osi_uc_solver=DYLP                             
251    osi_exists_solver=${coin_has_dylp-"unavailable"}
252    ;;                                             
253  @<:@Cc@:>@@<:@Pp@:>@@<:@Xx@:>@*)                 
254    osi_lc_solver=cpx ;                             
255    osi_mc_solver=Cpx                               
256    osi_uc_solver=CPX                               
257    osi_exists_solver=${coin_has_cpx-"unavailable"}
258    ;;
259  @<:@Gg@:>@@<:@Ll@:>@@<:@Pp@:>@@<:@Kk@:>@*)       
260    osi_lc_solver=glpk ;                           
261    osi_mc_solver=Glpk                             
262    osi_uc_solver=GLPK                             
263    osi_exists_solver=${coin_has_glpk-"unavailable"}
264    ;;
265  @<:@Gg@:>@@<:@Rr@:>@@<:@Bb@:>@*)
266    osi_lc_solver=grb ;
267    osi_mc_solver=Grb ;           
268    osi_uc_solver=GRB ;           
269    osi_exists_solver=${coin_has_grb-"unavailable"}
270    ;;                                             
271  @<:@Mm@:>@@<:@Ss@:>@@<:@Kk@:>@*)
272    osi_lc_solver=msk ;
273    osi_mc_solver=Msk
274    osi_uc_solver=MSK
275    osi_exists_solver=${coin_has_msk-"unavailable"}
276    ;;
277  @<:@Ss@:>@@<:@Pp@:>@@<:@Xx@:>@*)
278    osi_lc_solver=spx ;
279    osi_mc_solver=Spx
280    osi_uc_solver=SPX
281    osi_exists_solver=${coin_has_spx-"unavailable"}
282    ;;
283  @<:@Ss@:>@@<:@Yy@:>@@<:@Mm@:>@*)
284    osi_lc_solver=sym ;
285    osi_mc_solver=Sym
286    osi_uc_solver=SYM
287    osi_exists_solver=${coin_has_sym-"unavailable"}
288    ;;
289  @<:@Vv@:>@@<:@Oo@:>@@<:@Ll@:>@*)
290    osi_lc_solver=vol ;
291    osi_mc_solver=Vol
292    osi_uc_solver=VOL
293    osi_exists_solver=${coin_has_vol-"unavailable"}
294    ;;
295  @<:@Xx@:>@@<:@Pp@:>@@<:@Rr@:>@*)
296    osi_lc_solver=xpr ;
297    osi_mc_solver=Xpr
298    osi_uc_solver=XPR
299    osi_exists_solver=${coin_has_xpr-"unavailable"}
300    ;;
301  *)
302    osi_lc_solver=clp ;
303    osi_mc_solver=Clp ;
304    osi_uc_solver=CLP ;
305    osi_exists_solver=${coin_has_clp-"unavailable"}
306    AC_MSG_WARN([Unrecognised solver $1; defaulting to $osi_lc_solver.])
307    ;;
308esac
309
310# Check that the requested solver is available.
311if test $osi_exists_solver = no; then
312  AC_MSG_ERROR([selected default solver $osicbc_with_solver is unavailable.
313  Please select an available solver using the --with-osicbc-default-solver option.])
314fi
315
316# State the result.
317AC_MSG_NOTICE([OsiCbc default solver is $osi_lc_solver])
318
319# And set the configuration variables.
320AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER],
321  [Osi${osi_mc_solver}SolverInterface],
322  [define to the name of the default solver interface class, e.g., OsiClpSolverInterface])
323AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER_HPP],
324  ["Osi${osi_mc_solver}SolverInterface.hpp"],
325  [define to the name of the .hpp file for the default solver interface class, e.g., "OsiClpSolverInterface.hpp" (include quotes)])
326if test $osi_mc_solver = "Clp"; then
327  AC_DEFINE([OSICBC_DFLT_SOLVER_CLP],[1],[define this symbol if clp is the default solver])
328fi
329
330# Last but not least, we need automake conditionals.
331AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CLP],[test $osi_mc_solver = Clp])
332AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CPX],[test $osi_mc_solver = Cpx])
333AM_CONDITIONAL([OSICBC_DFLT_SOLVER_DYLP],[test $osi_mc_solver = Dylp])
334AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GLPK],[test $osi_mc_solver = Glpk])
335AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GRB],[test $osi_mc_solver = Grb])
336AM_CONDITIONAL([OSICBC_DFLT_SOLVER_MSK],[test $osi_mc_solver = Msk])
337AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SPX],[test $osi_mc_solver = Spx])
338AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SYM],[test $osi_mc_solver = Sym])
339AM_CONDITIONAL([OSICBC_DFLT_SOLVER_VOL],[test $osi_mc_solver = Vol])
340AM_CONDITIONAL([OSICBC_DFLT_SOLVER_XPR],[test $osi_mc_solver = Xpr])
341
342##############################################################################
343#                   VPATH links for example input files                      #
344##############################################################################
345
346# In case this is a VPATH configuration we need to make sure that the
347# input files for the examples are available in the VPATH directory.
348
349AC_COIN_VPATH_LINK(examples/sudoku_sample.csv)
350AC_COIN_VPATH_LINK(examples/quad.mps)
351AC_COIN_VPATH_LINK(examples/quad2.mps)
352
353#############################################################################
354#                  Check for doxygen                                        #
355#############################################################################
356
357AC_COIN_DOXYGEN(CoinUtils Osi Clp DyLP Cgl Vol)
358
359##############################################################################
360#                   Finishing up by writing all the output                   #
361##############################################################################
362
363# Here list all the files that configure should create (except for the
364# configuration header file)
365AC_CONFIG_FILES([Makefile
366                 examples/Makefile
367                 src/Makefile
368                 src/OsiCbc/Makefile
369                 test/Makefile
370                 cbc.pc cbc-uninstalled.pc
371                 osi-cbc.pc osi-cbc-uninstalled.pc])
372AC_CONFIG_FILES([doxydoc/doxygen.conf])
373
374# Here put the location and name of the configuration header file
375AC_CONFIG_HEADER([src/config.h src/config_cbc.h])
376
377# Finally, we let configure write all the output...
378AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.