source: stable/2.7/Cbc/configure.ac @ 1728

Last change on this file since 1728 was 1728, checked in by stefan, 8 years ago

restoring Cbc/stable/2.7

  • Property svn:keywords set to Author Date Id Revision
File size: 14.0 KB
Line 
1# Copyright (C) 2006, 2007 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Eclipse Public License.
4
5## $Id: configure.ac 1728 2011-09-20 12:41:22Z stefan $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8
9#############################################################################
10#                       Names and other basic things                        #
11#############################################################################
12
13AC_PREREQ(2.59)
14
15AC_INIT([Cbc],[2.7],[cbc@lists.coin-or.org])
16
17AC_COPYRIGHT([
18Copyright 2006 International Business Machines and others.
19All Rights Reserved.
20This file is part of the open source package Coin which is distributed
21under the Eclipse Public License.])
22
23# List one file in the package so that the configure script can test
24# whether the package is actually there
25AC_CONFIG_SRCDIR(src/CbcTree.hpp)
26
27# Where should everything be installed by default?  Here, we want it
28# to be installed directly in 'bin', 'lib', 'include' subdirectories
29# of the directory where configure is run.  The default would be
30# /usr/local.
31AC_PREFIX_DEFAULT([`pwd`])
32
33#############################################################################
34#                         Standard build tool stuff                         #
35#############################################################################
36
37# Get the system type
38AC_CANONICAL_BUILD
39
40# If this project depends on external projects, the Externals file in
41# the source root directory contains definition of where to find those
42# externals.  The following macro ensures that those externals are
43# retrieved by svn if they are not there yet.
44AC_COIN_PROJECTDIR_INIT(Cbc)
45
46# Check if user wants to produce debugging code
47AC_COIN_DEBUG_COMPILE(Cbc)
48
49# Get the name of the C++ compiler and appropriate compiler options
50AC_COIN_PROG_CXX
51
52# Initialize automake and libtool
53AC_COIN_INIT_AUTO_TOOLS
54
55#############################################################################
56#                            COIN-OR components                             #
57#############################################################################
58
59AC_COIN_CHECK_PACKAGE(CoinDepend, [cgl osi coinutils], [CbcLib CbcGeneric])
60if test $coin_has_coindepend != yes ; then
61  AC_MSG_ERROR([One or more required packages CoinUtils, Osi, and Cgl are not available.])
62fi
63
64# Clp and OsiClp are inseparable here.
65
66AC_COIN_CHECK_PACKAGE(Clp, [osi-clp], [CbcLib CbcGeneric])
67if test $coin_has_clp != yes ; then
68  AC_MSG_ERROR("Required package Clp unavailable.")
69fi
70
71# The rest are not required for linking against Cbc
72
73AC_COIN_CHECK_PACKAGE(OsiTests, [osi-unittests])
74AC_COIN_CHECK_PACKAGE(Sample,   [coindatasample])
75AC_COIN_CHECK_PACKAGE(Netlib,   [coindatanetlib])
76AC_COIN_CHECK_PACKAGE(Miplib3,  [coindatamiplib3])
77
78# Cbc really should make these tests; right now it assumes far too much about
79# its environment. Needed for cbc-generic.
80
81AC_COIN_CHECK_CXX_CHEADER(math)
82AC_COIN_CHECK_CXX_CHEADER(float)
83AC_COIN_CHECK_CXX_CHEADER(ieeefp)
84
85AC_COIN_CHECK_GNU_READLINE(CbcLib CbcGeneric)
86
87#############################################################################
88#                    LP solvers other than CLP                              #
89#############################################################################
90
91# Check which other LP solvers are available, some of them become a dependency of CbcGeneric
92AC_COIN_CHECK_PACKAGE(DyLP, [osi-dylp],   [CbcGeneric])
93AC_COIN_CHECK_PACKAGE(Vol,  [osi-vol])
94AC_COIN_CHECK_PACKAGE(Cpx,  [osi-cplex],  [CbcLib CbcGeneric])
95AC_COIN_CHECK_PACKAGE(Glpk, [osi-glpk],   [CbcGeneric])
96AC_COIN_CHECK_PACKAGE(Grb,  [osi-gurobi])
97AC_COIN_CHECK_PACKAGE(Msk,  [osi-mosek],  [CbcGeneric])
98AC_COIN_CHECK_PACKAGE(Spx,  [osi-soplex], [CbcGeneric])
99AC_COIN_CHECK_PACKAGE(Xpr,  [osi-xpress])
100
101#############################################################################
102#                       Other third party software                          #
103#############################################################################
104
105# Ampl Solver library
106AC_COIN_CHECK_PACKAGE(ASL, [coinasl])
107
108#############################################################################
109#                       CbcGeneric configuration                            #
110#############################################################################
111
112# Are we building cbc-generic? Default is no (false).
113
114AC_ARG_WITH([cbc-generic],
115  AS_HELP_STRING([--with-cbc-generic],
116                 [specify whether to build cbc-generic (default: no)]),
117  [case $withval in
118    yes) cbc_with_cbc_generic=true ;;
119      *) cbc_with_cbc_generic=false ;;
120   esac],
121  [cbc_with_cbc_generic=false])
122if test x"$cbc_with_cbc_generic" = xyes ; then
123  AC_MSG_NOTICE([building cbc-generic])
124fi
125AM_CONDITIONAL(CBC_BUILD_CBC_GENERIC,
126               test x"$cbc_with_cbc_generic" = xtrue)
127
128# Set the default solver for cbc-generic. In theory, any OsiXXX should work.
129# In practice, only the three listed below have had any testing.
130
131AC_MSG_CHECKING(for cbc-generic default solver)
132AC_ARG_WITH([cbc-generic-solver],
133            AC_HELP_STRING([--with-cbc-generic-solver],
134                           [specify default solver for cbc-generic in lower
135                            case letters (if not given, clp is assumed)]),
136            [cbc_default_solver=$withval],
137            [cbc_default_solver=clp])
138AC_MSG_RESULT($cbc_default_solver)
139
140# FIXME what about cplex and mosek here?
141case $cbc_default_solver in
142    clp)
143      ;;
144   dylp)
145      ;;
146   glpk)
147      ;;
148 soplex)
149      ;;
150      *)
151      AC_MSG_WARN([Unrecognised solver $cbc_default_solver chosen as cbc-generic default solver.])
152      ;;
153esac
154AC_DEFINE_UNQUOTED([CBC_DEFAULT_SOLVER],"$cbc_default_solver",
155  [Define to the name of the default solver to be used in cbc-generic in small letters])
156
157
158#############################################################################
159#                       Cbc parallel configuration                          #
160#############################################################################
161
162# First we define a new option, --enable-cbc-parallel
163
164AC_ARG_ENABLE([cbc-parallel],
165[AC_HELP_STRING([--enable-cbc-parallel],
166                [enables compilation of the SMP version of Cbc])])
167
168if test "$enable_cbc_parallel" = yes; then
169  # Define the preprocessor macro
170  AC_DEFINE([CBC_THREAD],[1],[Define to 1 if the SMP version of Cbc should be compiled])
171  AC_CHECK_LIB([rt],[clock_gettime],
172               [CBCLIB_LIBS="-lrt $CBCLIB_LIBS"
173                CBCLIB_PCLIBS="-lrt $CBCLIB_PCLIBS"
174                AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Define if clock_gettime and rt library is available])
175               ],
176               [AC_MSG_WARN([--enable-cbc-parallel selected, but -lrt unavailable; using gettimeofday instead of clock_gettime])])
177  AC_CHECK_LIB([pthread],[pthread_create],
178               [CBCLIB_LIBS="-lpthread $CBCLIB_LIBS"
179                CBCLIB_PCLIBS="-lpthread $CBCLIB_PCLIBS"
180               ],
181               [AC_MSG_ERROR([--enable-cbc-parallel selected, but -lpthreads unavailable])])
182fi
183
184##############################################################################
185#                            OsiCbc configuration                            #
186##############################################################################
187
188# Handles configuration of the underlying default solver in OsiCbc. The issue
189# is that OsiCbc defines a default solver, used when the client does not     
190# specify a solver in the constructor. The default solver must, therefore,   
191# be present in the build. This macro checks that this is true, and sets the
192# compile-time symbols OSICBC_DFLT_SOLVER, OSICBC_CLP_DFLT_SOLVER, and
193# OSICBC_DFLT_SOLVER_HPP that control the build. The parameter default_solver
194# should normally be clp, unless you're working on some other solver.
195
196# Ideally, this macro would not require enumeration of solvers, but the
197# effort required to avoid it is just not justified at present. One enumeration
198# is hidden in AC_OSI_CANONICAL. The other is visible, the AM_CONDITIONAL
199# list at the end.                                                             
200
201# In an ideal world this macro would do absolutely nothing if Cbc is not
202# present, but autotools is not an ideal world and we have to satisfy its
203# requirements. In particular, the AM_CONDITIONAL macros need to execute or
204# automake will complain. Really the only thing we need to suppress is the
205# check that the default solver exists. All the rest is irrelevant when Cbc
206# isn't present (hence OsiCbc will be configured but not actually compiled).
207
208# Process the with-osicbc-default-solver option.
209
210AC_ARG_WITH([osicbc-default-solver],
211  AS_HELP_STRING([--with-osicbc-default-solver],
212     [specify underlying solver for OsiCbc (default clp)]),
213     [osicbc_with_solver=$withval],
214     [osicbc_with_solver=clp])
215
216case "${osicbc_with_solver}" in
217  @<:@Cc@:>@@<:@Ll@:>@@<:@Pp@:>@*)
218    osi_lc_solver=clp ;           
219    osi_mc_solver=Clp ;           
220    osi_uc_solver=CLP ;           
221    osi_exists_solver=${coin_has_clp-"unavailable"}
222    ;;                                             
223  @<:@Dd@:>@@<:@Yy@:>@@<:@Ll@:>@@<:@Pp@:>@*)       
224    osi_lc_solver=dylp ;                           
225    osi_mc_solver=Dylp                             
226    osi_uc_solver=DYLP                             
227    osi_exists_solver=${coin_has_dylp-"unavailable"}
228    ;;                                             
229  @<:@Cc@:>@@<:@Pp@:>@@<:@Xx@:>@*)                 
230    osi_lc_solver=cpx ;                             
231    osi_mc_solver=Cpx                               
232    osi_uc_solver=CPX                               
233    osi_exists_solver=${coin_has_cpx-"unavailable"}
234    ;;
235  @<:@Gg@:>@@<:@Ll@:>@@<:@Pp@:>@@<:@Kk@:>@*)       
236    osi_lc_solver=glpk ;                           
237    osi_mc_solver=Glpk                             
238    osi_uc_solver=GLPK                             
239    osi_exists_solver=${coin_has_glpk-"unavailable"}
240    ;;
241  @<:@Gg@:>@@<:@Rr@:>@@<:@Bb@:>@*)
242    osi_lc_solver=grb ;
243    osi_mc_solver=Grb ;           
244    osi_uc_solver=GRB ;           
245    osi_exists_solver=${coin_has_grb-"unavailable"}
246    ;;                                             
247  @<:@Mm@:>@@<:@Ss@:>@@<:@Kk@:>@*)
248    osi_lc_solver=msk ;
249    osi_mc_solver=Msk
250    osi_uc_solver=MSK
251    osi_exists_solver=${coin_has_msk-"unavailable"}
252    ;;
253  @<:@Ss@:>@@<:@Pp@:>@@<:@Xx@:>@*)
254    osi_lc_solver=spx ;
255    osi_mc_solver=Spx
256    osi_uc_solver=SPX
257    osi_exists_solver=${coin_has_spx-"unavailable"}
258    ;;
259  @<:@Ss@:>@@<:@Yy@:>@@<:@Mm@:>@*)
260    osi_lc_solver=sym ;
261    osi_mc_solver=Sym
262    osi_uc_solver=SYM
263    osi_exists_solver=${coin_has_sym-"unavailable"}
264    ;;
265  @<:@Vv@:>@@<:@Oo@:>@@<:@Ll@:>@*)
266    osi_lc_solver=vol ;
267    osi_mc_solver=Vol
268    osi_uc_solver=VOL
269    osi_exists_solver=${coin_has_vol-"unavailable"}
270    ;;
271  @<:@Xx@:>@@<:@Pp@:>@@<:@Rr@:>@*)
272    osi_lc_solver=xpr ;
273    osi_mc_solver=Xpr
274    osi_uc_solver=XPR
275    osi_exists_solver=${coin_has_xpr-"unavailable"}
276    ;;
277  *)
278    osi_lc_solver=clp ;
279    osi_mc_solver=Clp ;
280    osi_uc_solver=CLP ;
281    osi_exists_solver=${coin_has_clp-"unavailable"}
282    AC_MSG_WARN([Unrecognised solver $1; defaulting to $osi_lc_solver.])
283    ;;
284esac
285
286# Check that the requested solver is available.
287if test $osi_exists_solver = no; then
288  AC_MSG_ERROR([selected default solver $osicbc_with_solver is unavailable.
289  Please select an available solver using the --with-osicbc-default-solver option.])
290fi
291
292# State the result.
293AC_MSG_NOTICE([OsiCbc default solver is $osi_lc_solver])
294
295# And set the configuration variables.
296AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER],
297  [Osi${osi_mc_solver}SolverInterface],
298  [define to the name of the default solver interface class, e.g., OsiClpSolverInterface])
299AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER_HPP],
300  ["Osi${osi_mc_solver}SolverInterface.hpp"],
301  [define to the name of the .hpp file for the default solver interface class, e.g., "OsiClpSolverInterface.hpp" (include quotes)])
302if test $osi_mc_solver = "Clp"; then
303  AC_DEFINE([OSICBC_DFLT_SOLVER_CLP],[1],[define this symbol if clp is the default solver])
304fi
305
306# Last but not least, we need automake conditionals.
307AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CLP],[test $osi_mc_solver = Clp])
308AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CPX],[test $osi_mc_solver = Cpx])
309AM_CONDITIONAL([OSICBC_DFLT_SOLVER_DYLP],[test $osi_mc_solver = Dylp])
310AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GLPK],[test $osi_mc_solver = Glpk])
311AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GRB],[test $osi_mc_solver = Grb])
312AM_CONDITIONAL([OSICBC_DFLT_SOLVER_MSK],[test $osi_mc_solver = Msk])
313AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SPX],[test $osi_mc_solver = Spx])
314AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SYM],[test $osi_mc_solver = Sym])
315AM_CONDITIONAL([OSICBC_DFLT_SOLVER_VOL],[test $osi_mc_solver = Vol])
316AM_CONDITIONAL([OSICBC_DFLT_SOLVER_XPR],[test $osi_mc_solver = Xpr])
317
318##############################################################################
319#                   VPATH links for example input files                      #
320##############################################################################
321
322# In case this is a VPATH configuration we need to make sure that the
323# input files for the examples are available in the VPATH directory.
324
325AC_COIN_VPATH_LINK(examples/sudoku_sample.csv)
326AC_COIN_VPATH_LINK(examples/quad.mps)
327AC_COIN_VPATH_LINK(examples/quad2.mps)
328
329#############################################################################
330#                  Check for doxygen                                        #
331#############################################################################
332
333AC_COIN_DOXYGEN(CoinUtils Osi Clp DyLP Cgl Vol)
334
335##############################################################################
336#                   Finishing up by writing all the output                   #
337##############################################################################
338
339# Here list all the files that configure should create (except for the
340# configuration header file)
341AC_CONFIG_FILES([Makefile
342                 examples/Makefile
343                 src/Makefile
344                 src/OsiCbc/Makefile
345                 test/Makefile
346                 cbc.pc cbc-uninstalled.pc
347                 osi-cbc.pc osi-cbc-uninstalled.pc])
348AC_CONFIG_FILES([doxydoc/doxygen.conf])
349
350# Here put the location and name of the configuration header file
351AC_CONFIG_HEADER([src/config.h src/config_cbc.h])
352
353# Finally, we let configure write all the output...
354AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.