source: stable/2.10/Cbc/configure.ac @ 2511

Last change on this file since 2511 was 2511, checked in by stefan, 4 months ago

temporarily committing release candidate

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 15.7 KB
Line 
1# Copyright (C) 2006, 2007 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Eclipse Public License.
4
5## $Id: configure.ac 2511 2019-02-23 01:36:42Z stefan $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8
9#############################################################################
10#                       Names and other basic things                        #
11#############################################################################
12
13AC_PREREQ(2.59)
14
15AC_INIT([Cbc],[2.10.0],[cbc@lists.coin-or.org])
16
17AC_COPYRIGHT([
18Copyright 2006 International Business Machines and others.
19All Rights Reserved.
20This file is part of the open source package Coin which is distributed
21under the Eclipse Public License.])
22
23# List one file in the package so that the configure script can test
24# whether the package is actually there
25AC_CONFIG_SRCDIR(src/CbcTree.hpp)
26
27# Where should everything be installed by default?  Here, we want it
28# to be installed directly in 'bin', 'lib', 'include' subdirectories
29# of the directory where configure is run.  The default would be
30# /usr/local.
31AC_PREFIX_DEFAULT([`pwd`])
32
33#############################################################################
34#                         Standard build tool stuff                         #
35#############################################################################
36
37# Get the system type
38AC_CANONICAL_BUILD
39
40# If this project depends on external projects, the Externals file in
41# the source root directory contains definition of where to find those
42# externals.  The following macro ensures that those externals are
43# retrieved by svn if they are not there yet.
44AC_COIN_PROJECTDIR_INIT(Cbc,13:0:10)
45
46# Check if user wants to produce debugging code
47AC_COIN_DEBUG_COMPILE(Cbc)
48
49# Get the name of the C++ compiler and appropriate compiler options
50AC_COIN_PROG_CXX
51
52# Initialize automake and libtool
53AC_COIN_INIT_AUTO_TOOLS
54
55#############################################################################
56#                            COIN-OR components                             #
57#############################################################################
58
59AC_COIN_CHECK_PACKAGE(CoinDepend, [cgl osi coinutils], [CbcLib CbcGeneric])
60if test $coin_has_coindepend != yes ; then
61  AC_MSG_ERROR([One or more required packages CoinUtils, Osi, and Cgl are not available.])
62fi
63
64# Clp and OsiClp are inseparable here.
65
66AC_COIN_CHECK_PACKAGE(Clp, [osi-clp], [CbcLib CbcGeneric])
67if test $coin_has_clp != yes ; then
68  AC_MSG_ERROR("Required package Clp unavailable.")
69fi
70
71# The rest are not required for linking against Cbc
72
73AC_COIN_CHECK_PACKAGE(OsiTests, [osi-unittests])
74AC_COIN_CHECK_PACKAGE(Sample,   [coindatasample])
75AC_COIN_CHECK_PACKAGE(Netlib,   [coindatanetlib])
76AC_COIN_CHECK_PACKAGE(Miplib3,  [coindatamiplib3])
77
78# Cbc really should make these tests; right now it assumes far too much about
79# its environment. Needed for cbc-generic.
80
81AC_COIN_CHECK_CXX_CHEADER(math)
82AC_COIN_CHECK_CXX_CHEADER(float)
83AC_COIN_CHECK_CXX_CHEADER(ieeefp)
84
85AC_COIN_CHECK_GNU_READLINE(CbcLib CbcGeneric)
86
87#############################################################################
88#                    LP solvers other than CLP                              #
89#############################################################################
90
91# Check which other LP solvers are available, some of them become a dependency of CbcGeneric
92AC_COIN_CHECK_PACKAGE(DyLP, [osi-dylp],   [CbcGeneric])
93AC_COIN_CHECK_PACKAGE(Vol,  [osi-vol])
94AC_COIN_CHECK_PACKAGE(Cpx,  [osi-cplex],  [CbcLib CbcGeneric])
95AC_COIN_CHECK_PACKAGE(Glpk, [osi-glpk],   [CbcGeneric])
96AC_COIN_CHECK_PACKAGE(Grb,  [osi-gurobi])
97AC_COIN_CHECK_PACKAGE(Highs,[osi-highs],  [CbcGeneric])
98AC_COIN_CHECK_PACKAGE(Msk,  [osi-mosek],  [CbcGeneric])
99AC_COIN_CHECK_PACKAGE(Spx,  [osi-soplex], [CbcGeneric])
100AC_COIN_CHECK_PACKAGE(Xpr,  [osi-xpress])
101
102#############################################################################
103#                       Other third party software                          #
104#############################################################################
105
106# Ampl Solver library
107AC_COIN_CHECK_PACKAGE(ASL, [coinasl], [CbcLib CbcGeneric])
108
109# MUMPS
110AC_COIN_CHECK_PACKAGE(Mumps, [coinmumps])
111
112# Nauty library (for symmetry detection)
113AC_LANG_PUSH(C)
114AC_COIN_CHECK_USER_LIBRARY([Nauty],[NTY],[nauty.h],[nauty],,[CbcLib CbcGeneric])
115AC_LANG_POP(C)
116
117#############################################################################
118#                       CbcGeneric configuration                            #
119#############################################################################
120
121# Are we building cbc-generic? Default is no (false).
122
123AC_ARG_WITH([cbc-generic],
124  AS_HELP_STRING([--with-cbc-generic],
125                 [specify whether to build cbc-generic (default: no)]),
126  [case $withval in
127    yes) cbc_with_cbc_generic=true ;;
128      *) cbc_with_cbc_generic=false ;;
129   esac],
130  [cbc_with_cbc_generic=false])
131if test x"$cbc_with_cbc_generic" = xyes ; then
132  AC_MSG_NOTICE([building cbc-generic])
133fi
134AM_CONDITIONAL(CBC_BUILD_CBC_GENERIC,
135               test x"$cbc_with_cbc_generic" = xtrue)
136
137# Set the default solver for cbc-generic. In theory, any OsiXXX should work.
138# In practice, only the three listed below have had any testing.
139
140AC_MSG_CHECKING(for cbc-generic default solver)
141AC_ARG_WITH([cbc-generic-solver],
142            AC_HELP_STRING([--with-cbc-generic-solver],
143                           [specify default solver for cbc-generic in lower
144                            case letters (if not given, clp is assumed)]),
145            [cbc_default_solver=$withval],
146            [cbc_default_solver=clp])
147AC_MSG_RESULT($cbc_default_solver)
148
149# FIXME what about cplex and mosek here?
150case $cbc_default_solver in
151    clp)
152      ;;
153   dylp)
154      ;;
155   glpk)
156      ;;
157  highs)
158      ;;
159 soplex)
160      ;;
161      *)
162      AC_MSG_WARN([Unrecognised solver $cbc_default_solver chosen as cbc-generic default solver.])
163      ;;
164esac
165AC_DEFINE_UNQUOTED([CBC_DEFAULT_SOLVER],"$cbc_default_solver",
166  [Define to the name of the default solver to be used in cbc-generic in small letters])
167
168
169#############################################################################
170#                       Cbc parallel configuration                          #
171#############################################################################
172
173# First we define a new option, --enable-cbc-parallel
174
175AC_ARG_ENABLE([cbc-parallel],
176[AC_HELP_STRING([--enable-cbc-parallel],
177                [enables compilation of the SMP version of Cbc])])
178
179if test "$enable_cbc_parallel" = yes; then
180  # Define the preprocessor macro
181  AC_DEFINE([CBC_THREAD],[1],[Define to 1 if the SMP version of Cbc should be compiled])
182  if test $coin_cxx_is_cl = true ;
183  then
184    # TODO we should check whether the library works and pthread.h is indeed there
185    AC_ARG_WITH(pthreadsw32-lib,
186                AC_HELP_STRING([--with-pthreadsw32-lib],
187                               [specify the name of the pthreads win32 library (for cl/icl builds only)]),
188                [CBCLIB_LIBS="$withval $CBCLIB_LIBS"
189                 CBCLIB_PCLIBS="$withval $CBCLIB_PCLIBS"],
190                [AC_MSG_WARN([--enable-cbc-parallel selected, but --with-pthreadsw32-lib not given])
191                 CBCLIB_LIBS="pthreadVCE2.lib $CBCLIB_LIBS"])
192   
193    AC_ARG_WITH(pthreadsw32-incdir,
194                AC_HELP_STRING([--with-pthreadsw32-incdir],
195                               [specify the path of the pthreads win32 header file (for cl/icl builds only)]),
196                [CXXFLAGS="$CXXFLAGS -I$withval"],
197                [AC_MSG_WARN([--enable-cbc-parallel selected, but --with-pthreadsw32-incdir not given])])
198  else
199    AC_CHECK_LIB([rt],[clock_gettime],
200                 [CBCLIB_LIBS="-lrt $CBCLIB_LIBS"
201                  CBCLIB_PCLIBS="-lrt $CBCLIB_PCLIBS"
202                  AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Define if clock_gettime and rt library is available])
203                 ],
204                 [AC_MSG_WARN([--enable-cbc-parallel selected, but -lrt unavailable; using gettimeofday instead of clock_gettime])])
205    AC_CHECK_LIB([pthread],[pthread_create],
206                 [CBCLIB_LIBS="-lpthread $CBCLIB_LIBS"
207                  CBCLIB_PCLIBS="-lpthread $CBCLIB_PCLIBS"
208                 ],
209                 [AC_MSG_ERROR([--enable-cbc-parallel selected, but -lpthreads unavailable])])
210  fi
211  AC_MSG_NOTICE([Cbc multithreading enabled]);
212fi
213
214##############################################################################
215#                            OsiCbc configuration                            #
216##############################################################################
217
218# Handles configuration of the underlying default solver in OsiCbc. The issue
219# is that OsiCbc defines a default solver, used when the client does not     
220# specify a solver in the constructor. The default solver must, therefore,   
221# be present in the build. This macro checks that this is true, and sets the
222# compile-time symbols OSICBC_DFLT_SOLVER, OSICBC_CLP_DFLT_SOLVER, and
223# OSICBC_DFLT_SOLVER_HPP that control the build. The parameter default_solver
224# should normally be clp, unless you're working on some other solver.
225
226# Ideally, this macro would not require enumeration of solvers, but the
227# effort required to avoid it is just not justified at present. One enumeration
228# is hidden in AC_OSI_CANONICAL. The other is visible, the AM_CONDITIONAL
229# list at the end.                                                             
230
231# In an ideal world this macro would do absolutely nothing if Cbc is not
232# present, but autotools is not an ideal world and we have to satisfy its
233# requirements. In particular, the AM_CONDITIONAL macros need to execute or
234# automake will complain. Really the only thing we need to suppress is the
235# check that the default solver exists. All the rest is irrelevant when Cbc
236# isn't present (hence OsiCbc will be configured but not actually compiled).
237
238# Process the with-osicbc-default-solver option.
239
240AC_ARG_WITH([osicbc-default-solver],
241  AS_HELP_STRING([--with-osicbc-default-solver],
242     [specify underlying solver for OsiCbc (default clp)]),
243     [osicbc_with_solver=$withval],
244     [osicbc_with_solver=clp])
245
246case "${osicbc_with_solver}" in
247  @<:@Cc@:>@@<:@Ll@:>@@<:@Pp@:>@*)
248    osi_lc_solver=clp ;           
249    osi_mc_solver=Clp ;           
250    osi_uc_solver=CLP ;           
251    osi_exists_solver=${coin_has_clp-"unavailable"}
252    ;;                                             
253  @<:@Dd@:>@@<:@Yy@:>@@<:@Ll@:>@@<:@Pp@:>@*)       
254    osi_lc_solver=dylp ;                           
255    osi_mc_solver=Dylp                             
256    osi_uc_solver=DYLP                             
257    osi_exists_solver=${coin_has_dylp-"unavailable"}
258    ;;                                             
259  @<:@Cc@:>@@<:@Pp@:>@@<:@Xx@:>@*)                 
260    osi_lc_solver=cpx ;                             
261    osi_mc_solver=Cpx                               
262    osi_uc_solver=CPX                               
263    osi_exists_solver=${coin_has_cpx-"unavailable"}
264    ;;
265  @<:@Gg@:>@@<:@Ll@:>@@<:@Pp@:>@@<:@Kk@:>@*)       
266    osi_lc_solver=glpk ;                           
267    osi_mc_solver=Glpk                             
268    osi_uc_solver=GLPK                             
269    osi_exists_solver=${coin_has_glpk-"unavailable"}
270    ;;
271  @<:@Gg@:>@@<:@Rr@:>@@<:@Bb@:>@*)
272    osi_lc_solver=grb ;
273    osi_mc_solver=Grb ;           
274    osi_uc_solver=GRB ;           
275    osi_exists_solver=${coin_has_grb-"unavailable"}
276    ;;                                             
277  @<:@H@:>@@<:@i@:>@@<:@g@:>@@<:@h@:>@@<:@s@:>@*)       
278    osi_lc_solver=highs ;                           
279    osi_mc_solver=HiGHS ;                           
280    osi_uc_solver=HIGHS ;                             
281    osi_exists_solver=${coin_has_highs-"unavailable"}
282    ;;
283  @<:@Mm@:>@@<:@Ss@:>@@<:@Kk@:>@*)
284    osi_lc_solver=msk ;
285    osi_mc_solver=Msk
286    osi_uc_solver=MSK
287    osi_exists_solver=${coin_has_msk-"unavailable"}
288    ;;
289  @<:@Ss@:>@@<:@Pp@:>@@<:@Xx@:>@*)
290    osi_lc_solver=spx ;
291    osi_mc_solver=Spx
292    osi_uc_solver=SPX
293    osi_exists_solver=${coin_has_spx-"unavailable"}
294    ;;
295  @<:@Ss@:>@@<:@Yy@:>@@<:@Mm@:>@*)
296    osi_lc_solver=sym ;
297    osi_mc_solver=Sym
298    osi_uc_solver=SYM
299    osi_exists_solver=${coin_has_sym-"unavailable"}
300    ;;
301  @<:@Vv@:>@@<:@Oo@:>@@<:@Ll@:>@*)
302    osi_lc_solver=vol ;
303    osi_mc_solver=Vol
304    osi_uc_solver=VOL
305    osi_exists_solver=${coin_has_vol-"unavailable"}
306    ;;
307  @<:@Xx@:>@@<:@Pp@:>@@<:@Rr@:>@*)
308    osi_lc_solver=xpr ;
309    osi_mc_solver=Xpr
310    osi_uc_solver=XPR
311    osi_exists_solver=${coin_has_xpr-"unavailable"}
312    ;;
313  *)
314    osi_lc_solver=clp ;
315    osi_mc_solver=Clp ;
316    osi_uc_solver=CLP ;
317    osi_exists_solver=${coin_has_clp-"unavailable"}
318    AC_MSG_WARN([Unrecognised solver $1; defaulting to $osi_lc_solver.])
319    ;;
320esac
321
322# Check that the requested solver is available.
323if test $osi_exists_solver = no; then
324  AC_MSG_ERROR([selected default solver $osicbc_with_solver is unavailable.
325  Please select an available solver using the --with-osicbc-default-solver option.])
326fi
327
328# State the result.
329AC_MSG_NOTICE([OsiCbc default solver is $osi_lc_solver])
330
331# And set the configuration variables.
332AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER],
333  [Osi${osi_mc_solver}SolverInterface],
334  [define to the name of the default solver interface class, e.g., OsiClpSolverInterface])
335AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER_HPP],
336  ["Osi${osi_mc_solver}SolverInterface.hpp"],
337  [define to the name of the .hpp file for the default solver interface class, e.g., "OsiClpSolverInterface.hpp" (include quotes)])
338if test $osi_mc_solver = "Clp"; then
339  AC_DEFINE([OSICBC_DFLT_SOLVER_CLP],[1],[define this symbol if clp is the default solver])
340fi
341
342# Last but not least, we need automake conditionals.
343AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CLP],[test $osi_mc_solver = Clp])
344AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CPX],[test $osi_mc_solver = Cpx])
345AM_CONDITIONAL([OSICBC_DFLT_SOLVER_DYLP],[test $osi_mc_solver = Dylp])
346AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GLPK],[test $osi_mc_solver = Glpk])
347AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GRB],[test $osi_mc_solver = Grb])
348AM_CONDITIONAL([OSICBC_DFLT_SOLVER_HIGHS],[test $osi_mc_solver = HiGHS])
349AM_CONDITIONAL([OSICBC_DFLT_SOLVER_MSK],[test $osi_mc_solver = Msk])
350AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SPX],[test $osi_mc_solver = Spx])
351AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SYM],[test $osi_mc_solver = Sym])
352AM_CONDITIONAL([OSICBC_DFLT_SOLVER_VOL],[test $osi_mc_solver = Vol])
353AM_CONDITIONAL([OSICBC_DFLT_SOLVER_XPR],[test $osi_mc_solver = Xpr])
354
355##############################################################################
356#                   VPATH links for example input files                      #
357##############################################################################
358
359# In case this is a VPATH configuration we need to make sure that the
360# input files for the examples are available in the VPATH directory.
361
362AC_COIN_VPATH_LINK(examples/sudoku_sample.csv)
363AC_COIN_VPATH_LINK(examples/quad.mps)
364AC_COIN_VPATH_LINK(examples/quad2.mps)
365
366#############################################################################
367#                  Check for doxygen                                        #
368#############################################################################
369
370AC_COIN_DOXYGEN(CoinUtils Osi Clp DyLP Cgl Vol)
371
372##############################################################################
373#                   Finishing up by writing all the output                   #
374##############################################################################
375
376# Here list all the files that configure should create (except for the
377# configuration header file)
378AC_CONFIG_FILES([Makefile
379                 examples/Makefile
380                 src/Makefile
381                 src/OsiCbc/Makefile
382                 test/Makefile
383                 cbc.pc cbc-uninstalled.pc
384                 osi-cbc.pc osi-cbc-uninstalled.pc])
385AC_CONFIG_FILES([doxydoc/doxygen.conf])
386
387# Here put the location and name of the configuration header file
388AC_CONFIG_HEADER([src/config.h src/config_cbc.h])
389
390# Finally, we let configure write all the output...
391AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.