source: releases/2.7.1/Cbc/configure.ac @ 1995

Last change on this file since 1995 was 1699, checked in by tkr, 8 years ago

temporarily committing release candidate

  • Property svn:keywords set to Author Date Id Revision
File size: 14.0 KB
Line 
1# Copyright (C) 2006, 2007 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Eclipse Public License.
4
5## $Id: configure.ac 1699 2011-07-22 16:02:22Z tkr $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8
9#############################################################################
10#                       Names and other basic things                        #
11#############################################################################
12
13AC_PREREQ(2.59)
14
15AC_INIT([Cbc],[2.7.1],[cbc@lists.coin-or.org])
16
17AC_COPYRIGHT([
18Copyright 2006 International Business Machines and others.
19All Rights Reserved.
20This file is part of the open source package Coin which is distributed
21under the Eclipse Public License.])
22
23# List one file in the package so that the configure script can test
24# whether the package is actually there
25AC_CONFIG_SRCDIR(src/CbcTree.hpp)
26
27# Where should everything be installed by default?  Here, we want it
28# to be installed directly in 'bin', 'lib', 'include' subdirectories
29# of the directory where configure is run.  The default would be
30# /usr/local.
31AC_PREFIX_DEFAULT([`pwd`])
32
33#############################################################################
34#                         Standard build tool stuff                         #
35#############################################################################
36
37# Get the system type
38AC_CANONICAL_BUILD
39
40# If this project depends on external projects, the Externals file in
41# the source root directory contains definition of where to find those
42# externals.  The following macro ensures that those externals are
43# retrieved by svn if they are not there yet.
44AC_COIN_PROJECTDIR_INIT(Cbc,10:1:7)
45
46# Check if user wants to produce debugging code
47AC_COIN_DEBUG_COMPILE(Cbc)
48
49# Get the name of the C++ compiler and appropriate compiler options
50AC_COIN_PROG_CXX
51
52# Initialize automake and libtool
53AC_COIN_INIT_AUTO_TOOLS
54
55#############################################################################
56#                            COIN-OR components                             #
57#############################################################################
58
59AC_COIN_CHECK_PACKAGE(CoinDepend, [cgl osi coinutils], [CbcLib CbcGeneric])
60if test $coin_has_coindepend != yes ; then
61  AC_MSG_ERROR([One or more required packages CoinUtils, Osi, and Cgl are not available.])
62fi
63
64# Clp and OsiClp are inseparable here.
65
66AC_COIN_CHECK_PACKAGE(Clp, [osi-clp], [CbcLib CbcGeneric])
67if test $coin_has_clp != yes ; then
68  AC_MSG_ERROR("Required package Clp unavailable.")
69fi
70
71# The rest are not required for linking against Cbc
72
73AC_COIN_CHECK_PACKAGE(OsiTests, [osi-unittests])
74AC_COIN_CHECK_PACKAGE(Sample,   [coindatasample])
75AC_COIN_CHECK_PACKAGE(Netlib,   [coindatanetlib])
76AC_COIN_CHECK_PACKAGE(Miplib3,  [coindatamiplib3])
77
78# Cbc really should make these tests; right now it assumes far too much about
79# its environment. Needed for cbc-generic.
80
81AC_COIN_CHECK_CXX_CHEADER(math)
82AC_COIN_CHECK_CXX_CHEADER(float)
83AC_COIN_CHECK_CXX_CHEADER(ieeefp)
84
85#############################################################################
86#                    LP solvers other than CLP                              #
87#############################################################################
88
89# Check which other LP solvers are available, some of them become a dependency of CbcGeneric
90AC_COIN_CHECK_PACKAGE(DyLP, [osi-dylp],   [CbcGeneric])
91AC_COIN_CHECK_PACKAGE(Vol,  [osi-vol])
92AC_COIN_CHECK_PACKAGE(Cpx,  [osi-cplex],  [CbcLib CbcGeneric])
93AC_COIN_CHECK_PACKAGE(Glpk, [osi-glpk],   [CbcGeneric])
94AC_COIN_CHECK_PACKAGE(Grb,  [osi-gurobi])
95AC_COIN_CHECK_PACKAGE(Msk,  [osi-mosek],  [CbcGeneric])
96AC_COIN_CHECK_PACKAGE(Spx,  [osi-soplex], [CbcGeneric])
97AC_COIN_CHECK_PACKAGE(Xpr,  [osi-xpress])
98
99#############################################################################
100#                       Other third party software                          #
101#############################################################################
102
103# Ampl Solver library
104AC_COIN_CHECK_PACKAGE(ASL, [coinasl])
105
106#############################################################################
107#                       CbcGeneric configuration                            #
108#############################################################################
109
110# Are we building cbc-generic? Default is no (false).
111
112AC_ARG_WITH([cbc-generic],
113  AS_HELP_STRING([--with-cbc-generic],
114                 [specify whether to build cbc-generic (default: no)]),
115  [case $withval in
116    yes) cbc_with_cbc_generic=true ;;
117      *) cbc_with_cbc_generic=false ;;
118   esac],
119  [cbc_with_cbc_generic=false])
120if test x"$cbc_with_cbc_generic" = xyes ; then
121  AC_MSG_NOTICE([building cbc-generic])
122fi
123AM_CONDITIONAL(CBC_BUILD_CBC_GENERIC,
124               test x"$cbc_with_cbc_generic" = xtrue)
125
126# Set the default solver for cbc-generic. In theory, any OsiXXX should work.
127# In practice, only the three listed below have had any testing.
128
129AC_MSG_CHECKING(for cbc-generic default solver)
130AC_ARG_WITH([cbc-generic-solver],
131            AC_HELP_STRING([--with-cbc-generic-solver],
132                           [specify default solver for cbc-generic in lower
133                            case letters (if not given, clp is assumed)]),
134            [cbc_default_solver=$withval],
135            [cbc_default_solver=clp])
136AC_MSG_RESULT($cbc_default_solver)
137
138# FIXME what about cplex and mosek here?
139case $cbc_default_solver in
140    clp)
141      ;;
142   dylp)
143      ;;
144   glpk)
145      ;;
146 soplex)
147      ;;
148      *)
149      AC_MSG_WARN([Unrecognised solver $cbc_default_solver chosen as cbc-generic default solver.])
150      ;;
151esac
152AC_DEFINE_UNQUOTED([CBC_DEFAULT_SOLVER],"$cbc_default_solver",
153  [Define to the name of the default solver to be used in cbc-generic in small letters])
154
155
156#############################################################################
157#                       Cbc parallel configuration                          #
158#############################################################################
159
160# First we define a new option, --enable-cbc-parallel
161
162AC_ARG_ENABLE([cbc-parallel],
163[AC_HELP_STRING([--enable-cbc-parallel],
164                [enables compilation of the SMP version of Cbc])])
165
166if test "$enable_cbc_parallel" = yes; then
167  # Define the preprocessor macro
168  AC_DEFINE([CBC_THREAD],[1],[Define to 1 if the SMP version of Cbc should be compiled])
169  AC_CHECK_LIB([rt],[clock_gettime],
170               [CBCLIB_LIBS="-lrt $CBCLIB_LIBS"
171                CBCLIB_PCLIBS="-lrt $CBCLIB_PCLIBS"
172                AC_DEFINE([HAVE_CLOCK_GETTIME],[1],[Define if clock_gettime and rt library is available])
173               ],
174               [AC_MSG_WARN([--enable-cbc-parallel selected, but -lrt unavailable; using gettimeofday instead of clock_gettime])])
175  AC_CHECK_LIB([pthread],[pthread_create],
176               [CBCLIB_LIBS="-lpthread $CBCLIB_LIBS"
177                CBCLIB_PCLIBS="-lpthread $CBCLIB_PCLIBS"
178               ],
179               [AC_MSG_ERROR([--enable-cbc-parallel selected, but -lpthreads unavailable])])
180fi
181
182##############################################################################
183#                            OsiCbc configuration                            #
184##############################################################################
185
186# Handles configuration of the underlying default solver in OsiCbc. The issue
187# is that OsiCbc defines a default solver, used when the client does not     
188# specify a solver in the constructor. The default solver must, therefore,   
189# be present in the build. This macro checks that this is true, and sets the
190# compile-time symbols OSICBC_DFLT_SOLVER, OSICBC_CLP_DFLT_SOLVER, and
191# OSICBC_DFLT_SOLVER_HPP that control the build. The parameter default_solver
192# should normally be clp, unless you're working on some other solver.
193
194# Ideally, this macro would not require enumeration of solvers, but the
195# effort required to avoid it is just not justified at present. One enumeration
196# is hidden in AC_OSI_CANONICAL. The other is visible, the AM_CONDITIONAL
197# list at the end.                                                             
198
199# In an ideal world this macro would do absolutely nothing if Cbc is not
200# present, but autotools is not an ideal world and we have to satisfy its
201# requirements. In particular, the AM_CONDITIONAL macros need to execute or
202# automake will complain. Really the only thing we need to suppress is the
203# check that the default solver exists. All the rest is irrelevant when Cbc
204# isn't present (hence OsiCbc will be configured but not actually compiled).
205
206# Process the with-osicbc-default-solver option.
207
208AC_ARG_WITH([osicbc-default-solver],
209  AS_HELP_STRING([--with-osicbc-default-solver],
210     [specify underlying solver for OsiCbc (default clp)]),
211     [osicbc_with_solver=$withval],
212     [osicbc_with_solver=clp])
213
214case "${osicbc_with_solver}" in
215  @<:@Cc@:>@@<:@Ll@:>@@<:@Pp@:>@*)
216    osi_lc_solver=clp ;           
217    osi_mc_solver=Clp ;           
218    osi_uc_solver=CLP ;           
219    osi_exists_solver=${coin_has_clp-"unavailable"}
220    ;;                                             
221  @<:@Dd@:>@@<:@Yy@:>@@<:@Ll@:>@@<:@Pp@:>@*)       
222    osi_lc_solver=dylp ;                           
223    osi_mc_solver=Dylp                             
224    osi_uc_solver=DYLP                             
225    osi_exists_solver=${coin_has_dylp-"unavailable"}
226    ;;                                             
227  @<:@Cc@:>@@<:@Pp@:>@@<:@Xx@:>@*)                 
228    osi_lc_solver=cpx ;                             
229    osi_mc_solver=Cpx                               
230    osi_uc_solver=CPX                               
231    osi_exists_solver=${coin_has_cpx-"unavailable"}
232    ;;
233  @<:@Gg@:>@@<:@Ll@:>@@<:@Pp@:>@@<:@Kk@:>@*)       
234    osi_lc_solver=glpk ;                           
235    osi_mc_solver=Glpk                             
236    osi_uc_solver=GLPK                             
237    osi_exists_solver=${coin_has_glpk-"unavailable"}
238    ;;
239  @<:@Gg@:>@@<:@Rr@:>@@<:@Bb@:>@*)
240    osi_lc_solver=grb ;
241    osi_mc_solver=Grb ;           
242    osi_uc_solver=GRB ;           
243    osi_exists_solver=${coin_has_grb-"unavailable"}
244    ;;                                             
245  @<:@Mm@:>@@<:@Ss@:>@@<:@Kk@:>@*)
246    osi_lc_solver=msk ;
247    osi_mc_solver=Msk
248    osi_uc_solver=MSK
249    osi_exists_solver=${coin_has_msk-"unavailable"}
250    ;;
251  @<:@Ss@:>@@<:@Pp@:>@@<:@Xx@:>@*)
252    osi_lc_solver=spx ;
253    osi_mc_solver=Spx
254    osi_uc_solver=SPX
255    osi_exists_solver=${coin_has_spx-"unavailable"}
256    ;;
257  @<:@Ss@:>@@<:@Yy@:>@@<:@Mm@:>@*)
258    osi_lc_solver=sym ;
259    osi_mc_solver=Sym
260    osi_uc_solver=SYM
261    osi_exists_solver=${coin_has_sym-"unavailable"}
262    ;;
263  @<:@Vv@:>@@<:@Oo@:>@@<:@Ll@:>@*)
264    osi_lc_solver=vol ;
265    osi_mc_solver=Vol
266    osi_uc_solver=VOL
267    osi_exists_solver=${coin_has_vol-"unavailable"}
268    ;;
269  @<:@Xx@:>@@<:@Pp@:>@@<:@Rr@:>@*)
270    osi_lc_solver=xpr ;
271    osi_mc_solver=Xpr
272    osi_uc_solver=XPR
273    osi_exists_solver=${coin_has_xpr-"unavailable"}
274    ;;
275  *)
276    osi_lc_solver=clp ;
277    osi_mc_solver=Clp ;
278    osi_uc_solver=CLP ;
279    osi_exists_solver=${coin_has_clp-"unavailable"}
280    AC_MSG_WARN([Unrecognised solver $1; defaulting to $osi_lc_solver.])
281    ;;
282esac
283
284# Check that the requested solver is available.
285if test $osi_exists_solver = no; then
286  AC_MSG_ERROR([selected default solver $osicbc_with_solver is unavailable.
287  Please select an available solver using the --with-osicbc-default-solver option.])
288fi
289
290# State the result.
291AC_MSG_NOTICE([OsiCbc default solver is $osi_lc_solver])
292
293# And set the configuration variables.
294AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER],
295  [Osi${osi_mc_solver}SolverInterface],
296  [define to the name of the default solver interface class, e.g., OsiClpSolverInterface])
297AC_DEFINE_UNQUOTED([OSICBC_DFLT_SOLVER_HPP],
298  ["Osi${osi_mc_solver}SolverInterface.hpp"],
299  [define to the name of the .hpp file for the default solver interface class, e.g., "OsiClpSolverInterface.hpp" (include quotes)])
300if test $osi_mc_solver = "Clp"; then
301  AC_DEFINE([OSICBC_DFLT_SOLVER_CLP],[1],[define this symbol if clp is the default solver])
302fi
303
304# Last but not least, we need automake conditionals.
305AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CLP],[test $osi_mc_solver = Clp])
306AM_CONDITIONAL([OSICBC_DFLT_SOLVER_CPX],[test $osi_mc_solver = Cpx])
307AM_CONDITIONAL([OSICBC_DFLT_SOLVER_DYLP],[test $osi_mc_solver = Dylp])
308AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GLPK],[test $osi_mc_solver = Glpk])
309AM_CONDITIONAL([OSICBC_DFLT_SOLVER_GRB],[test $osi_mc_solver = Grb])
310AM_CONDITIONAL([OSICBC_DFLT_SOLVER_MSK],[test $osi_mc_solver = Msk])
311AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SPX],[test $osi_mc_solver = Spx])
312AM_CONDITIONAL([OSICBC_DFLT_SOLVER_SYM],[test $osi_mc_solver = Sym])
313AM_CONDITIONAL([OSICBC_DFLT_SOLVER_VOL],[test $osi_mc_solver = Vol])
314AM_CONDITIONAL([OSICBC_DFLT_SOLVER_XPR],[test $osi_mc_solver = Xpr])
315
316##############################################################################
317#                   VPATH links for example input files                      #
318##############################################################################
319
320# In case this is a VPATH configuration we need to make sure that the
321# input files for the examples are available in the VPATH directory.
322
323AC_COIN_VPATH_LINK(examples/sudoku_sample.csv)
324AC_COIN_VPATH_LINK(examples/quad.mps)
325AC_COIN_VPATH_LINK(examples/quad2.mps)
326
327#############################################################################
328#                  Check for doxygen                                        #
329#############################################################################
330
331AC_COIN_DOXYGEN(CoinUtils Osi Clp DyLP Cgl Vol)
332
333##############################################################################
334#                   Finishing up by writing all the output                   #
335##############################################################################
336
337# Here list all the files that configure should create (except for the
338# configuration header file)
339AC_CONFIG_FILES([Makefile
340                 examples/Makefile
341                 src/Makefile
342                 src/OsiCbc/Makefile
343                 test/Makefile
344                 cbc.pc cbc-uninstalled.pc
345                 osi-cbc.pc osi-cbc-uninstalled.pc])
346AC_CONFIG_FILES([doxydoc/doxygen.conf])
347
348# Here put the location and name of the configuration header file
349AC_CONFIG_HEADER([src/config.h src/config_cbc.h])
350
351# Finally, we let configure write all the output...
352AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.