source: ThirdParty/ASL/branches/BSPsplit/configure.ac @ 1461

Last change on this file since 1461 was 1461, checked in by stefan, 11 years ago

run amplsolver lib path through cygpath_w before putting it into .pc file

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 6.4 KB
Line 
1# Copyright (C) 2007, 2009 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Common Public License.
4
5## $Id: configure.ac 1461 2010-01-01 12:15:27Z stefan $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8# Revised: Lou Hafer                   SFU    2007-09-15
9
10#############################################################################
11#                       Names and other basic things                        #
12#############################################################################
13
14AC_PREREQ(2.59)
15
16AC_INIT([ThirdPartyASL],[1.0trunk],[http://projects.coin-or.org/BuildTools/newticket])
17
18AC_COPYRIGHT([
19Copyright 2006, 2007, 2009 International Business Machines and others.
20All Rights Reserved.
21This file is part of the open source package Coin which is distributed
22under the Common Public License.])
23
24# List one file in the package so that the configure script can test
25# whether the package is actually there
26AC_CONFIG_SRCDIR(solvers/asl.h)
27
28# Where should everything be installed by default?  Here, we want it
29# to be installed directly in 'bin', 'lib', 'include' subdirectories
30# of the directory where configure is run.  The default would be
31# /usr/local.
32AC_PREFIX_DEFAULT([`pwd`])
33
34#############################################################################
35#                         Standard build tool stuff                         #
36#############################################################################
37
38# Get the system type
39AC_CANONICAL_BUILD
40
41# A bit of initial setup.
42AC_COIN_PROJECTDIR_INIT
43
44# Turn off warnings and pedantic mode since they could make trouble on some
45# platforms, and we can't fix issues in third-party code.
46coin_skip_warn_cflags=yes
47
48# Check if user wants to produce debugging code
49AC_COIN_DEBUG_COMPILE(ASL)
50
51# We need egrep and ln -s somewhere
52AC_PROG_EGREP
53AC_PROG_LN_S
54
55# Get the name of the C compiler and compiler flags
56AC_COIN_PROG_CC
57
58# Initialize automake and libtool
59AC_COIN_INIT_AUTO_TOOLS
60
61#############################################################################
62#                          AMPL SOLVER LIBRARY                              #
63#############################################################################
64
65# Determine the name of the ASL library
66
67# Set a substitutable variable with the library name, and determine the compilation style.
68AC_SUBST(AMPLSOLVER_A)
69case "$CC" in
70  cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
71    AMPLSOLVER_A=amplsolv.lib
72    msvc_compile=yes
73    ;;
74  *)
75    AMPLSOLVER_A=amplsolver.a
76    msvc_compile=no
77    ;;
78esac
79AC_MSG_NOTICE([Configuring ASL to build $AMPLSOLVER_A.])
80
81# Set substitutable variables with the absolute path to the library name
82# translate to windows style if necessary, but use slashes instead of backslashes
83ABSPATH_AMPLSOLVER_INSTALLED=`${CYGPATH_W} ${prefix}/lib/ThirdParty/${AMPLSOLVER_A} | sed -e 's/\\\\/\\//g'`
84curdir=`pwd`
85ABSPATH_AMPLSOLVER_UNINSTALLED=`${CYGPATH_W} ${curdir}/${AMPLSOLVER_A} | sed -e 's/\\\\/\\//g'`
86AC_SUBST(ABSPATH_AMPLSOLVER_INSTALLED)
87AC_SUBST(ABSPATH_AMPLSOLVER_UNINSTALLED)
88
89# Determine flags to be passed on the command line to (n)make. The main
90# activity is to groom CFLAGS and set up ASLMAKEFLAGS to pass CFLAGS on the
91# (n)make command line.
92# NON_STDIO no longer appears in any source file; removed all mention.
93# No_Control87 seems to be specific to DEC Alpha. Try leaving it undefined.
94
95if test -z "$ASLMAKEFLAGS" ; then
96  asladdcflags=
97  case $build in
98    *-linux*)
99      case $CC in
100        pgcc* | */pgcc* | xlc* | */xlc* | blrts_xlc* | */blrts_xlc*)
101          asladdcflags="$asladdcflags -DNO_fpu_control";;
102      esac
103      ;;
104  esac
105
106# Various feature checks. Force the language to be C while we do this to avoid
107# issues with C++ (re)declarations.
108  AC_LANG_PUSH(C)
109
110# The critical function for NO_RUSAGE is getrusage(). Use a standard test.
111
112  AC_MSG_CHECKING([for getrusage])
113  AC_LINK_IFELSE(
114    [AC_LANG_PROGRAM([[]],[[getrusage()]])],
115    [AC_MSG_RESULT([yes])],
116    [asladdcflags="$asladdcflags -DNO_RUSAGE"
117     AC_MSG_RESULT([no])])
118
119# Check for long long; we need to define NO_LONG_LONG if it's not present.  ASL
120# makefile.u and makefile.vc both deal with this, in their own way.
121# Unfortunately, when trying to build with cl under cygwin, the makefile.vc
122# solution, comptry.bat, fails. To safely discard comptry.bat, we need to do
123# this check. It's hardly likely that long long is missing on any modern
124# system, but it's easy to check.
125
126  AC_CHECK_TYPE([long long],[],
127    [asladdcflags="$asladdcflags -DNO_LONG_LONG"],[])
128
129# Back to whatever language we were in.
130  AC_LANG_POP(C)
131
132# On BlueGene disable dynamic library loading
133  if test x"$enable_bg" = xyes; then
134    asladdcflags="$asladdcflags -DNO_FUNCADD"
135  fi
136
137# Groom CFLAGS before we merge it with asladdcflags.
138# Remove -Werror if present, to make sure we are not interrupting compilation
139# of ASL because of warning messages. The cl equivalent is -WX.
140  bla=
141  if test x$msvc_compile = xyes ; then
142    warnToErr="-WX"
143  else
144    warnToErr="-Werror"
145  fi
146  for i in $CFLAGS; do
147    if test "$i" != "$warnToErr"; then
148      bla="$bla $i"
149    fi
150  done
151  ASLMAKEFLAGS="CFLAGS=\"$bla $asladdcflags\""
152
153# Somehow, the flags specified here cause ASL to segfault on the AIX
154# compiler, so take them out.
155  case $CC in
156    xlc* | */xlc* | mpxlc* | */mpxlc*)
157      ASLMAKEFLAGS=`echo $ASLMAKEFLAGS | sed -e 's/-qtune=auto//g' -e 's/-qarch=auto//g' -e 's/-qcache=auto//g' -e 's/-qhot//g' -e sed 's/-O3/-O/g'`
158      ;;
159    pgcc* | */pgcc*)
160      ASLMAKEFLAGS=`echo $ASLMAKEFLAGS | sed -e 's/-fast/-O1/g'`
161      ;;
162  esac
163
164# Limit GNU make to one thread. But remember that if we're building with
165# cl, ultimately we're going to use nmake, which knows nothing of this.
166  if test x$msvc_compile = xno ; then
167    rm -rf conftest.mak
168    ($am_make -v > conftest.grp) 2>&5
169    if $EGREP GNU conftest.grp >&5 ; then
170      ASLMAKEFLAGS="-j 1 $ASLMAKEFLAGS"
171    fi
172    rm -f conftest.grp
173  fi
174fi
175# End if-then to construct ASLMAKEFLAGS. Announce the result.
176
177AC_MSG_NOTICE([Command line flags for (n)make \"$ASLMAKEFLAGS\".])
178AC_ARG_VAR(ASLMAKEFLAGS, [Compilation flags necessary for compiling the AMPL solver library])
179
180# Set automake conditional and generate the output files.
181
182AM_CONDITIONAL(MSVC_COMPILE, test x$msvc_compile = xyes)
183
184AC_CONFIG_FILES([Makefile asl_addlibs.txt])
185AC_CONFIG_FILES([compile_MS_ASL],[chmod a+x compile_MS_ASL])
186AC_CONFIG_FILES([compile_Unix_ASL],[chmod a+x compile_Unix_ASL])
187AC_CONFIG_FILES([asl.pc asl-uninstalled.pc])
188
189AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.