source: ThirdParty/ASL/branches/BSPsplit/configure.ac @ 1454

Last change on this file since 1454 was 1454, checked in by stefan, 10 years ago

add .pc files for ASL, HSL, and FilterSQP

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 5.9 KB
Line 
1# Copyright (C) 2007, 2009 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Common Public License.
4
5## $Id: configure.ac 1454 2009-11-29 18:27:05Z stefan $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8# Revised: Lou Hafer                   SFU    2007-09-15
9
10#############################################################################
11#                       Names and other basic things                        #
12#############################################################################
13
14AC_PREREQ(2.59)
15
16AC_INIT([ThirdPartyASL],[1.0trunk],[http://projects.coin-or.org/BuildTools/newticket])
17
18AC_COPYRIGHT([
19Copyright 2006, 2007, 2009 International Business Machines and others.
20All Rights Reserved.
21This file is part of the open source package Coin which is distributed
22under the Common Public License.])
23
24# List one file in the package so that the configure script can test
25# whether the package is actually there
26AC_CONFIG_SRCDIR(solvers/asl.h)
27
28# Where should everything be installed by default?  Here, we want it
29# to be installed directly in 'bin', 'lib', 'include' subdirectories
30# of the directory where configure is run.  The default would be
31# /usr/local.
32AC_PREFIX_DEFAULT([`pwd`])
33
34#############################################################################
35#                         Standard build tool stuff                         #
36#############################################################################
37
38# Get the system type
39AC_CANONICAL_BUILD
40
41# A bit of initial setup.
42AC_COIN_PROJECTDIR_INIT
43
44# Turn off warnings and pedantic mode since they could make trouble on some
45# platforms, and we can't fix issues in third-party code.
46coin_skip_warn_cflags=yes
47
48# Check if user wants to produce debugging code
49AC_COIN_DEBUG_COMPILE(ASL)
50
51# We need egrep and ln -s somewhere
52AC_PROG_EGREP
53AC_PROG_LN_S
54
55# Get the name of the C compiler and compiler flags
56AC_COIN_PROG_CC
57
58# Initialize automake and libtool
59AC_COIN_INIT_AUTO_TOOLS
60
61#############################################################################
62#                          AMPL SOLVER LIBRARY                              #
63#############################################################################
64
65# Determine the name of the ASL library
66
67# Set a substitutable variable with the library name, and determine the compilation style.
68AC_SUBST(AMPLSOLVER_A)
69case "$CC" in
70  cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
71    AMPLSOLVER_A=amplsolv.lib
72    msvc_compile=yes
73    ;;
74  *)
75    AMPLSOLVER_A=amplsolver.a
76    msvc_compile=no
77    ;;
78esac
79AC_MSG_NOTICE([Configuring ASL to build $AMPLSOLVER_A.])
80
81# Determine flags to be passed on the command line to (n)make. The main
82# activity is to groom CFLAGS and set up ASLMAKEFLAGS to pass CFLAGS on the
83# (n)make command line.
84# NON_STDIO no longer appears in any source file; removed all mention.
85# No_Control87 seems to be specific to DEC Alpha. Try leaving it undefined.
86
87if test -z "$ASLMAKEFLAGS" ; then
88  asladdcflags=
89  case $build in
90    *-linux*)
91      case $CC in
92        pgcc* | */pgcc* | xlc* | */xlc* | blrts_xlc* | */blrts_xlc*)
93          asladdcflags="$asladdcflags -DNO_fpu_control";;
94      esac
95      ;;
96  esac
97
98# Various feature checks. Force the language to be C while we do this to avoid
99# issues with C++ (re)declarations.
100  AC_LANG_PUSH(C)
101
102# The critical function for NO_RUSAGE is getrusage(). Use a standard test.
103
104  AC_MSG_CHECKING([for getrusage])
105  AC_LINK_IFELSE(
106    [AC_LANG_PROGRAM([[]],[[getrusage()]])],
107    [AC_MSG_RESULT([yes])],
108    [asladdcflags="$asladdcflags -DNO_RUSAGE"
109     AC_MSG_RESULT([no])])
110
111# Check for long long; we need to define NO_LONG_LONG if it's not present.  ASL
112# makefile.u and makefile.vc both deal with this, in their own way.
113# Unfortunately, when trying to build with cl under cygwin, the makefile.vc
114# solution, comptry.bat, fails. To safely discard comptry.bat, we need to do
115# this check. It's hardly likely that long long is missing on any modern
116# system, but it's easy to check.
117
118  AC_CHECK_TYPE([long long],[],
119    [asladdcflags="$asladdcflags -DNO_LONG_LONG"],[])
120
121# Back to whatever language we were in.
122  AC_LANG_POP(C)
123
124# On BlueGene disable dynamic library loading
125  if test x"$enable_bg" = xyes; then
126    asladdcflags="$asladdcflags -DNO_FUNCADD"
127  fi
128
129# Groom CFLAGS before we merge it with asladdcflags.
130# Remove -Werror if present, to make sure we are not interrupting compilation
131# of ASL because of warning messages. The cl equivalent is -WX.
132  bla=
133  if test x$msvc_compile = xyes ; then
134    warnToErr="-WX"
135  else
136    warnToErr="-Werror"
137  fi
138  for i in $CFLAGS; do
139    if test "$i" != "$warnToErr"; then
140      bla="$bla $i"
141    fi
142  done
143  ASLMAKEFLAGS="CFLAGS=\"$bla $asladdcflags\""
144
145# Somehow, the flags specified here cause ASL to segfault on the AIX
146# compiler, so take them out.
147  case $CC in
148    xlc* | */xlc* | mpxlc* | */mpxlc*)
149      ASLMAKEFLAGS=`echo $ASLMAKEFLAGS | sed -e 's/-qtune=auto//g' -e 's/-qarch=auto//g' -e 's/-qcache=auto//g' -e 's/-qhot//g' -e sed 's/-O3/-O/g'`
150      ;;
151    pgcc* | */pgcc*)
152      ASLMAKEFLAGS=`echo $ASLMAKEFLAGS | sed -e 's/-fast/-O1/g'`
153      ;;
154  esac
155
156# Limit GNU make to one thread. But remember that if we're building with
157# cl, ultimately we're going to use nmake, which knows nothing of this.
158  if test x$msvc_compile = xno ; then
159    rm -rf conftest.mak
160    ($am_make -v > conftest.grp) 2>&5
161    if $EGREP GNU conftest.grp >&5 ; then
162      ASLMAKEFLAGS="-j 1 $ASLMAKEFLAGS"
163    fi
164    rm -f conftest.grp
165  fi
166fi
167# End if-then to construct ASLMAKEFLAGS. Announce the result.
168
169AC_MSG_NOTICE([Command line flags for (n)make \"$ASLMAKEFLAGS\".])
170AC_ARG_VAR(ASLMAKEFLAGS, [Compilation flags necessary for compiling the AMPL solver library])
171
172# Set automake conditional and generate the output files.
173
174AM_CONDITIONAL(MSVC_COMPILE, test x$msvc_compile = xyes)
175
176AC_CONFIG_FILES([Makefile asl_addlibs.txt])
177AC_CONFIG_FILES([compile_MS_ASL],[chmod a+x compile_MS_ASL])
178AC_CONFIG_FILES([compile_Unix_ASL],[chmod a+x compile_Unix_ASL])
179AC_CONFIG_FILES([asl.pc asl-uninstalled.pc])
180
181AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.