source: ThirdParty/ASL/branches/BSPsplit/configure.ac @ 1446

Last change on this file since 1446 was 1446, checked in by stefan, 10 years ago

stop using COIN_HAS_PROJECT; some cleanup; use MODULE_BLAS in Mumps

  • Property svn:eol-style set to native
  • Property svn:keywords set to Author Date Id Revision
File size: 6.2 KB
Line 
1# Copyright (C) 2007, 2009 International Business Machines.
2# All Rights Reserved.
3# This file is distributed under the Common Public License.
4
5## $Id: configure.ac 1446 2009-11-22 18:47:29Z stefan $
6
7# Author:  Andreas Waechter            IBM    2006-04-13
8# Revised: Lou Hafer                   SFU    2007-09-15
9
10#############################################################################
11#                       Names and other basic things                        #
12#############################################################################
13
14AC_PREREQ(2.59)
15
16AC_INIT([ThirdPartyASL],[1.0trunk],[http://projects.coin-or.org/BuildTools/newticket])
17
18AC_COPYRIGHT([
19Copyright 2006, 2007, 2009 International Business Machines and others.
20All Rights Reserved.
21This file is part of the open source package Coin which is distributed
22under the Common Public License.])
23
24# List one file in the package so that the configure script can test
25# whether the package is actually there
26AC_CONFIG_SRCDIR(solvers/asl.h)
27
28# Where should everything be installed by default?  Here, we want it
29# to be installed directly in 'bin', 'lib', 'include' subdirectories
30# of the directory where configure is run.  The default would be
31# /usr/local.
32AC_PREFIX_DEFAULT([`pwd`])
33
34#############################################################################
35#                         Standard build tool stuff                         #
36#############################################################################
37
38# Get the system type
39AC_CANONICAL_BUILD
40
41# A bit of initial setup.
42AC_COIN_PROJECTDIR_INIT
43
44# Turn off warnings and pedantic mode since they could make trouble on some
45# platforms, and we can't fix issues in third-party code.
46coin_skip_warn_cflags=yes
47
48# Check if user wants to produce debugging code
49AC_COIN_DEBUG_COMPILE(ASL)
50
51# We need egrep and ln -s somewhere
52AC_PROG_EGREP
53AC_PROG_LN_S
54
55# Get the name of the C compiler and compiler flags
56AC_COIN_PROG_CC
57
58# Initialize automake and libtool
59AC_COIN_INIT_AUTO_TOOLS
60
61# See what we're actually going to do for ASL. This will define ampllib.
62#AC_COIN_HAS_ASL
63
64# Determine the name of the ASL library
65case "$CC" in
66  cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
67    ampllib=amplsolv.lib ;;
68  *)
69    ampllib=amplsolver.a ;;
70esac
71
72
73#############################################################################
74#                          AMPL SOLVER LIBRARY                              #
75#############################################################################
76
77if test x$skip_further_test != xyes; then
78
79# Set a substitutable variable with the library name, and determine the
80# compilation style.
81
82  AC_SUBST(AMPLSOLVER_A)
83  AMPLSOLVER_A=$ampllib
84  case "$CC" in
85    cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
86      msvc_compile=yes ;;
87    *)
88      msvc_compile=no ;;
89  esac
90  AC_MSG_NOTICE([Configuring ASL to build $AMPLSOLVER_A.])
91
92# Determine flags to be passed on the command line to (n)make. The main
93# activity is to groom CFLAGS and set up ASLMAKEFLAGS to pass CFLAGS on the
94# (n)make command line.
95# NON_STDIO no longer appears in any source file; removed all mention.
96# No_Control87 seems to be specific to DEC Alpha. Try leaving it undefined.
97
98  if test -z "$ASLMAKEFLAGS" ; then
99    asladdcflags=
100    case $build in
101      *-linux*)
102        case $CC in
103          pgcc* | */pgcc* | xlc* | */xlc* | blrts_xlc* | */blrts_xlc*)
104            asladdcflags="$asladdcflags -DNO_fpu_control";;
105        esac
106        ;;
107    esac
108
109# Various feature checks. Force the language to be C while we do this to avoid
110# issues with C++ (re)declarations.
111
112    AC_LANG_PUSH(C)
113
114# The critical function for NO_RUSAGE is getrusage(). Use a standard test.
115
116    AC_MSG_CHECKING([for getrusage])
117    AC_LINK_IFELSE(
118      [AC_LANG_PROGRAM([[]],[[getrusage()]])],
119      [AC_MSG_RESULT([yes])],
120      [asladdcflags="$asladdcflags -DNO_RUSAGE"
121       AC_MSG_RESULT([no])])
122
123# Check for long long; we need to define NO_LONG_LONG if it's not present.  ASL
124# makefile.u and makefile.vc both deal with this, in their own way.
125# Unfortunately, when trying to build with cl under cygwin, the makefile.vc
126# solution, comptry.bat, fails. To safely discard comptry.bat, we need to do
127# this check. It's hardly likely that long long is missing on any modern
128# system, but it's easy to check.
129
130    AC_CHECK_TYPE([long long],[],
131      [asladdcflags="$asladdcflags -DNO_LONG_LONG"],[])
132
133# Back to whatever language we were in.
134
135    AC_LANG_POP(C)
136
137# On BlueGene disable dynamic library loading
138
139    if test x"$enable_bg" = xyes; then
140      asladdcflags="$asladdcflags -DNO_FUNCADD"
141    fi
142
143# Groom CFLAGS before we merge it with asladdcflags.
144# Remove -Werror if present, to make sure we are not interrupting compilation
145# of ASL because of warning messages. The cl equivalent is -WX.
146
147    bla=
148    if test x$msvc_compile = xyes ; then
149      warnToErr="-WX"
150    else
151      warnToErr="-Werror"
152    fi
153    for i in $CFLAGS; do
154      if test "$i" != "$warnToErr"; then
155        bla="$bla $i"
156      fi
157    done
158    ASLMAKEFLAGS="CFLAGS=\"$bla $asladdcflags\""
159
160# Somehow, the flags specified here cause ASL to segfault on the AIX
161# compiler, so take them out.
162
163    case $CC in
164      xlc* | */xlc* | mpxlc* | */mpxlc*)
165        ASLMAKEFLAGS=`echo $ASLMAKEFLAGS | sed -e 's/-qtune=auto//g' -e 's/-qarch=auto//g' -e 's/-qcache=auto//g' -e 's/-qhot//g' -e sed 's/-O3/-O/g'`
166        ;;
167      pgcc* | */pgcc*)
168        ASLMAKEFLAGS=`echo $ASLMAKEFLAGS | sed -e 's/-fast/-O1/g'`
169        ;;
170    esac
171
172# Limit GNU make to one thread. But remember that if we're building with
173# cl, ultimately we're going to use nmake, which knows nothing of this.
174
175    if test x$msvc_compile = xno ; then
176      rm -rf conftest.mak
177      ($am_make -v > conftest.grp) 2>&5
178      if $EGREP GNU conftest.grp >&5 ; then
179        ASLMAKEFLAGS="-j 1 $ASLMAKEFLAGS"
180      fi
181      rm -f conftest.grp
182    fi
183  fi
184
185# End if-then to construct ASLMAKEFLAGS. Announce the result.
186
187  AC_MSG_NOTICE([Command line flags for (n)make \"$ASLMAKEFLAGS\".])
188  AC_ARG_VAR(ASLMAKEFLAGS,
189        [Compilation flags necessary for compiling the AMPL solver library])
190
191fi
192
193# Set automake conditional and generate the output files.
194
195AM_CONDITIONAL(MSVC_COMPILE, test x$msvc_compile = xyes)
196
197AC_CONFIG_FILES([Makefile asl_addlibs.txt])
198AC_CONFIG_FILES([compile_MS_ASL],[chmod a+x compile_MS_ASL])
199AC_CONFIG_FILES([compile_Unix_ASL],[chmod a+x compile_Unix_ASL])
200
201AC_COIN_FINALIZE
Note: See TracBrowser for help on using the repository browser.