source: trunk/configure.ac @ 695

Last change on this file since 695 was 695, checked in by kulshres, 3 years ago

bump version, we're about to release 2.6.1

  • Property svn:keywords set to Author Date Id Revision
File size: 22.3 KB
Line 
1##############################################################################
2# configure.ac -- Process this file with autoconf to produce configure
3# Revision: $Id: configure.ac 695 2016-04-15 09:01:32Z kulshres $
4#
5# Copyright (C) Andrea Walther, Andreas Kowarz
6#               
7# contains patches from the COIN OR libtool
8#
9##############################################################################
10define([ADOLC_VER], [2])
11define([ADOLC_SUB], [6])
12define([ADOLC_LVL], [2])
13
14AC_PREREQ(2.67)
15AC_INIT(adolc,
16        ADOLC_VER.ADOLC_SUB.ADOLC_LVL-trunk,
17        [adol-c@list.coin-or.org])
18config_flags="$*"
19AC_REVISION($Revision: 695 $)
20AC_CONFIG_SRCDIR([ADOL-C/src/adouble.cpp])
21AC_CONFIG_AUX_DIR([autoconf])
22AC_CONFIG_MACRO_DIR([autoconf])
23AC_CONFIG_HEADERS([ADOL-C/src/config.h])
24AC_PREFIX_DEFAULT(${HOME}/adolc_base)
25AM_INIT_AUTOMAKE([1.11 dist-bzip2 foreign subdir-objects])
26AM_MAINTAINER_MODE([disable])
27AM_SILENT_RULES([yes])
28
29
30adolclib=adolc
31
32if test "x$CFLAGS" == x ; then
33    ac_shell_cflags="not_set"
34else
35    ac_shell_cflags="$CFLAGS"
36fi
37if test "x$CXXFLAGS" == x ; then
38    ac_shell_cxxflags="not_set"
39else
40    ac_shell_cxxflags="$CXXFLAGS"
41fi
42libdir_set_on_cmd="no"
43for i in $config_flags ; do
44    case $i in
45    -libdir | --libdir | --libdi | --libd | -libdir=* | --libdir=* | --libdi=* | --libd=*)
46            libdir_set_on_cmd="yes"
47            break
48            ;;
49    esac
50done
51
52AM_CONDITIONAL(DARWIN, [test "x${host_os#darwin}" != "x${host_os}"])
53
54AC_MSG_CHECKING(whether to build ADOL-C with adjoinable MPI (AMPI) support)
55AC_ARG_ENABLE(ampi,
56              [AS_HELP_STRING([--enable-ampi],[build ADOL-C with adjoinable MPI (AMPI) support [default=disabled]])],
57              [adolc_ampi_support=$enableval],[adolc_ampi_support=no])
58AC_MSG_RESULT($adolc_ampi_support)
59AM_CONDITIONAL(BUILD_ADOLC_AMPI_SUPPORT,[test x${adolc_ampi_support} = xyes])
60if test x"${adolc_ampi_support}" = xyes ; then
61AC_DEFINE(ADOLC_AMPI_SUPPORT,1,[defined if adjoinable MPI support is to be compiled in])
62fi
63
64LT_PREREQ([2.2.6])
65# checks for programs
66AC_PROG_CXX
67AX_CXX_COMPILE_STDCXX_11(noext,mandatory)
68AC_PROG_CC
69AC_PROG_CC_C_O
70AC_PROG_CC_C99
71AC_PROG_CPP
72AC_PROG_INSTALL
73AC_PROG_LN_S
74AC_PROG_MAKE_SET
75LT_INIT([disable-static win32-dll dlopen])
76
77MPI_CONF_PRE
78
79AC_CHECK_SIZEOF([void *])
80if test "x$ac_cv_sizeof_void_p" = "x8" ; then
81   _lib=lib64
82else
83   _lib=lib
84fi
85if test "x$libdir_set_on_cmd" = "xno" ; then
86   libdir='${exec_prefix}'/"${_lib}"
87   AC_SUBST(_lib)
88   AC_SUBST(libdir)
89fi
90
91# check for builtin
92ACX_C_BUILTIN_EXPECT
93
94# checks for header files
95AC_HEADER_STDC
96AC_HEADER_TIME
97AC_HEADER_STDBOOL
98AC_CHECK_HEADERS([stddef.h stdlib.h stdio.h string.h unistd.h sys/timeb.h])
99
100# checks for types
101AC_C_CONST
102AC_C_INLINE
103AC_TYPE_SIZE_T
104AC_STRUCT_TM
105
106
107# Checks for libraries and fuctions
108AC_SEARCH_LIBS([pow], [m])
109AC_CHECK_FUNCS([floor fmax fmin ftime pow sqrt strchr strtol trunc])
110
111AX_BOOST_BASE([1.54],[boost_new=yes],[boost_new=no])
112if test x$boost_new = xyes ; then
113CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
114AC_LANG_PUSH([C++])
115AC_CHECK_HEADERS([boost/pool/pool_alloc.hpp])
116AC_LANG_POP([C++])
117AX_BOOST_SYSTEM
118LDFLAGS="$LDFLAGS $BOOST_LDFLAGS $BOOST_SYSTEM_LIB"
119fi
120
121if test "x$want_boost" = xyes -a "x$boost_new" = xyes -a "x$ac_cv_header_boost_pool_pool_alloc_hpp" = xyes -a "x$link_system" = xyes ; then
122    using_boost_pool=yes
123else
124    using_boost_pool=no
125fi
126
127# substitutions
128AC_SUBST(ac_aux_dir)
129
130# ADOL-C configuration
131AC_DEFINE(ADOLC_VERSION,ADOLC_VER,[ADOL-C Version])
132AC_DEFINE(ADOLC_SUBVERSION,ADOLC_SUB,[ADOL-C Subversion])
133AC_DEFINE(ADOLC_PATCHLEVEL,ADOLC_LVL,[ADOL-C Patchlevel])
134ADOLC_VERSION=ADOLC_VER
135ADOLC_SUBVERSION=ADOLC_SUB
136ADOLC_PATCHLEVEL=ADOLC_LVL
137AC_SUBST(ADOLC_VERSION)
138AC_SUBST(ADOLC_SUBVERSION)
139AC_SUBST(ADOLC_PATCHLEVEL)
140
141# Checks for library functions
142AC_FUNC_MALLOC
143AC_FUNC_REALLOC
144if test x$ac_cv_func_malloc_0_nonnull != xyes ; then
145AC_DEFINE_UNQUOTED([calloc],[rpl_calloc],[Define to rpl_calloc if the replacement function should be used.])
146fi
147
148AC_MSG_CHECKING(whether to use calloc or malloc for memory allocation)
149AC_ARG_ENABLE(use-calloc,[AS_HELP_STRING([--disable-use-calloc],
150  [disable use of calloc and use malloc instead for memory allocation [default=calloc is used]])],
151  [use_calloc=$enableval],[use_calloc=yes])
152
153if test x$use_calloc = xyes ; then
154AC_MSG_RESULT(calloc)
155AC_DEFINE(ADOLC_USE_CALLOC,1,[Use calloc instead of malloc for memory allocation])
156else
157AC_MSG_RESULT(malloc)
158fi
159
160AC_MSG_CHECKING(whether to enable atrig/erf functions)
161AC_ARG_ENABLE(atrig-erf,[AS_HELP_STRING([--enable-atrig-erf],
162  [enable atrig and erf functions in ADOL-C [default=no]])],
163  [use_atrig_erf=$enableval],[use_atrig_erf=no])
164AC_MSG_RESULT($use_atrig_erf)
165
166if test x$use_atrig_erf = xyes ; then
167  ATRIG_ERF="#define ATRIG_ERF 1"
168else
169  ATRIG_ERF="#undef ATRIG_ERF"
170fi
171AC_SUBST(ATRIG_ERF)
172
173AC_MSG_CHECKING(whether to use 32-bit or 64-bit locations)
174AC_ARG_ENABLE(ulong,[AS_HELP_STRING([--enable-ulong],
175  [enable 64-bit locations (only available on 64-bit systems) [default=32-bit]])],
176  [use_ulong=$enableval],[use_ulong=no])
177
178if test x$use_ulong = xyes -a 0$ac_cv_sizeof_void_p -ge 8 ; then
179  UINT_TYPE=uint64_t
180  AC_MSG_RESULT(64-bit)
181else
182  UINT_TYPE=uint32_t
183  AC_MSG_RESULT(32-bit)
184fi
185AC_SUBST(UINT_TYPE)
186
187AC_MSG_CHECKING(whether to use single or double precision)
188AC_ARG_ENABLE(double,[AS_HELP_STRING([--disable-double],
189  [disable double precision arithmetic [untested, default=double is enabled]])],
190  [use_double=$enableval],[use_double=yes])
191
192if test x$use_double = xno ; then
193  REAL_TYPE=float
194  echo
195  echo -n "using ${REAL_TYPE} is not well tested, please report bugs if you find any..."
196else
197  REAL_TYPE=double
198fi
199AC_MSG_RESULT($REAL_TYPE)
200AC_SUBST(REAL_TYPE)
201
202AC_MSG_CHECKING(whether to enable advanced branching operations)
203AC_ARG_ENABLE(advanced-branching, [AS_HELP_STRING([--enable-advanced-branching],
204  [enable advanced branching operations to reduce retaping [default=no].
205The boolean valued comparison operators with two adouble arguments will
206not return boolean results but the active results may be used to automatically
207switch branches in conjunction with condassign or advector (see manual).])],
208  [use_advbranch=$enableval],[use_advbranch=no])
209AC_MSG_RESULT($use_advbranch)
210
211if test x$use_advbranch = xyes ; then
212  ADVBRANCH="#define ADOLC_ADVANCED_BRANCHING 1"
213else
214  ADVBRANCH="#undef ADOLC_ADVANCED_BRANCHING"
215fi
216AC_SUBST(ADVBRANCH)
217AC_SUBST(ADVBRANCH)
218
219AC_MSG_CHECKING(whether to use ADOL-C debug mode)
220AC_ARG_ENABLE(debug,
221              [
222AS_HELP_STRING([--enable-debug],[enable ADOL-C debug mode [default=no]])],
223  [
224  adolc_debug=$enableval
225   AC_MSG_RESULT($adolc_debug)
226   ],
227  [
228   adolc_debug=no
229   AC_MSG_RESULT(no)
230   ])
231
232AC_MSG_CHECKING(whether to use ADOL-C hard debug mode)
233AC_ARG_ENABLE(harddebug,
234              [
235AS_HELP_STRING([--enable-harddebug],[enable ADOL-C hard debug mode
236 [default=no]])],
237  [
238   adolc_harddebug=$enableval
239   AC_MSG_RESULT($adolc_harddebug)
240   ],
241  [
242   adolc_harddebug=no
243   AC_MSG_RESULT(no)
244   ])
245
246if test x$adolc_harddebug == xyes ; then
247adolc_debug=yes
248AC_DEFINE(ADOLC_HARDDEBUG,1,[ADOL-C hard debug mode])
249fi
250
251if test x$adolc_debug == xyes ; then
252AC_DEFINE(ADOLC_DEBUG,1,[ADOL-C debug mode])
253fi
254
255AC_MSG_CHECKING(whether the default adouble constructor should initialize the value to 0)
256AC_ARG_ENABLE(stdczero,
257              [
258AS_HELP_STRING([--disable-stdczero],[adouble default constructor does not initialize the value to zero
259(improves performance but yields incorrect results for implicit array initializations, see manual) [default=enabled]])],
260  [
261  adolc_stdczero=no
262  AC_MSG_RESULT(no)
263  ],
264  [
265  adolc_stdczero=yes
266  AC_MSG_RESULT(yes)
267  ])
268
269if test x$adolc_stdczero == xyes; then
270AC_DEFINE(ADOLC_ADOUBLE_STDCZERO,1,[ADOL-C adouble zeroing mode])
271fi
272
273AC_MSG_CHECKING(whether the adouble variables have a late initialize option for functions like malloc/realloc)
274AC_ARG_ENABLE(lateinit,
275              [
276AS_HELP_STRING([--enable-lateinit],[adouble constructors need to be called. With malloc or realloc that is not the case. With this option the adouble can do a late initialization.) [default=disabled]])],
277  [
278  adolc_late_init=yes
279  AC_MSG_RESULT(yes)
280  ],
281  [
282  adolc_late_init=no
283  AC_MSG_RESULT(no)
284  ])
285
286if test x$adolc_late_init == xyes; then
287AC_DEFINE(ADOLC_ADOUBLE_LATEINIT,1,[ADOL-C adouble late initialization mode])
288fi
289
290AC_MSG_CHECKING(whether errno is thread save)
291AC_ARG_ENABLE(tserrno,
292              [
293AS_HELP_STRING([--enable-tserrno],[use errno as thread number cache [default=no]])],
294  [
295  adolc_tserrno=$enableval
296  AC_MSG_RESULT($adolc_tserrno)
297   ],
298  [
299  adolc_tserrno=no
300  AC_MSG_RESULT(no)
301  ])
302
303if test x$adolc_tserrno == xyes ; then
304AC_DEFINE(ADOLC_THREADSAVE_ERRNO,1,[ADOL-C thread save errno mode])
305fi
306
307AC_MSG_CHECKING(which flag to use to enable OpenMP)
308AC_ARG_WITH(openmp-flag,
309            [AS_HELP_STRING([--with-openmp-flag=FLAG],
310                            [use FLAG to enable OpenMP at compile time [default=none]])],
311            [ac_adolc_openmpflag=$withval
312             AC_MSG_RESULT($ac_adolc_openmpflag)],
313            [ac_adolc_openmpflag=""
314             AC_MSG_RESULT(none)])
315
316if test "x$using_boost_pool" = xyes -a "x$ac_adolc_openmpflag" = x ; then
317   AC_DEFINE(BOOST_POOL_NO_MT,1,[Boost pool should not assume multithreading])
318fi
319
320# ADOL-C Sparse facility
321AC_MSG_CHECKING(whether to build sparse drivers)
322AC_ARG_ENABLE(sparse,
323            [
324AS_HELP_STRING([--enable-sparse],[build sparse drivers [default=disabled]])],
325            [sparse=$enableval
326             AC_MSG_RESULT($sparse)],
327            [sparse="no"
328             AC_MSG_RESULT(no)])
329
330COLPACK_CONF
331
332AM_CONDITIONAL(SPARSE,[test x${sparse} = xyes])
333
334if test x$sparse = xyes ; then
335   AC_DEFINE(SPARSE,[1],[Define 1 if sparse derivative propagation is to be enabled])
336fi
337
338# ADOL-C Examples
339AC_MSG_CHECKING(whether to build documented examples)
340AC_ARG_ENABLE(docexa,
341            [
342AS_HELP_STRING([--enable-docexa],[build documented examples [default=disabled]])],
343            [docexa=$enableval
344             AC_MSG_RESULT(yes)],
345            [docexa="no"
346             AC_MSG_RESULT(no)])
347AM_CONDITIONAL(DOCEXA,[test x${docexa} = xyes])
348
349AC_MSG_CHECKING(whether to build additional examples)
350AC_ARG_ENABLE(addexa,
351            [AS_HELP_STRING([--enable-addexa],
352                            [build additional examples [default=disabled]])],
353            [addexa=$enableval
354             AC_MSG_RESULT(yes)],
355            [addexa="no"
356             AC_MSG_RESULT(no)])
357AM_CONDITIONAL(ADDEXA,[test x${addexa} = xyes])
358
359AC_MSG_CHECKING(whether to build parallel example)
360AC_ARG_ENABLE(parexa,
361            [AS_HELP_STRING([--enable-parexa],
362                            [build parallel example [default=disabled], if enabled -with-openmp-flag=FLAG required])],
363            [parexa=$enableval
364             AC_MSG_RESULT(yes)],
365            [parexa="no"
366             AC_MSG_RESULT(no)])
367AM_CONDITIONAL(PAREXA,[test x${parexa} = xyes])
368
369# ADOL-C Compilation flags
370AC_MSG_CHECKING(which CFLAGS to use)
371AC_ARG_WITH(cflags,
372            [AS_HELP_STRING([--with-cflags=FLAGS],
373                            [use CFLAGS=FLAGS (default: -O2)])],
374            [ac_adolc_cflags="$withval"
375             if test x${adolc_debug} == xyes ||
376                test x${adolc_harddebug} == xyes ; then
377                ac_adolc_cflags="$ac_adolc_cflags -g -O0"
378             fi
379             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
380             AC_SUBST(ac_adolc_cflags)
381             AC_MSG_RESULT($ac_adolc_cflags)],
382            [if test "$ac_shell_cflags" = "not_set"; then
383                ac_adolc_cflags="-O2"
384                if test x${adolc_debug} == xyes ||
385                   test x${adolc_harddebug} == xyes ; then
386                   ac_adolc_cflags="-g -O0 -Wall -ansi"
387                fi
388             else
389                ac_adolc_cflags="$CFLAGS"
390             fi
391             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
392
393             AC_SUBST(ac_adolc_cflags)
394             AC_MSG_RESULT($ac_adolc_cflags)])
395
396AC_MSG_CHECKING(which CXXFLAGS to use)
397AC_ARG_WITH(cxxflags,
398            [AS_HELP_STRING([--with-cxxflags=FLAGS],
399                            [use CXXFLAGS=FLAGS (default: -O2)])],
400            [ac_adolc_cxxflags="$withval"
401             if test x${adolc_debug} == xyes ||
402                test x${adolc_harddebug} == xyes ; then
403                ac_adolc_cxxflags="$ac_adolc_cxxflags -g -O0"
404             fi
405             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
406             AC_SUBST(ac_adolc_cxxflags)
407             AC_MSG_RESULT($ac_adolc_cxxflags)],
408            [if test "$ac_shell_cxxflags" = "not_set"; then
409                ac_adolc_cxxflags="-O2"
410                if test x${adolc_debug} == xyes ||
411                   test x${adolc_harddebug} == xyes ; then
412                   ac_adolc_cxxflags="-g -O0 -Wall"
413                fi
414             else
415                ac_adolc_cxxflags="$CXXFLAGS"
416             fi
417             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
418            AC_SUBST(ac_adolc_cxxflags)
419            AC_MSG_RESULT($ac_adolc_cxxflags)])
420
421MPI_CONF_POST
422AMPI_CONF
423
424AC_ARG_WITH(soname,
425            [AS_HELP_STRING([--with-soname=NAME],
426              [user can choose what to call his library here [default: if ampi enabled then adolc_ampi otherwise adolc]])],
427      [adolclib=$withval])
428
429AC_SUBST(adolclib)
430
431AC_MSG_CHECKING(whether tape_doc should compute values as it prints the tape contents)
432AC_ARG_ENABLE(tapedoc_values,
433              [
434                AS_HELP_STRING([--disable-tapedoc-values],
435                               [should the tape_doc routine compute the values as it interprets and prints the tape contents [default=enabled]])],
436  [
437  tapedoc_values=no
438  ],
439  [
440  tapedoc_values=yes
441  ])
442AC_MSG_RESULT($tapedoc_values)
443
444if test x$tapedoc_values == xyes; then
445AC_DEFINE(ADOLC_TAPE_DOC_VALUES,1,[ADOL-C tape_doc routine computes values])
446fi
447
448###########################################################################
449#                      COIN_PATCH_LIBTOOL_CYGWIN                          #
450###########################################################################
451
452# Patches to libtool for cygwin. Lots for cl, a few for GCC.
453# For cl:
454# - cygpath is not correctly quoted in fix_srcfile_path
455# - paths generated for .lib files is not run through cygpath -w
456
457#
458# REQUIRED FOR COMPILATION WITH CYGWIN !!!
459#
460 
461
462AC_DEFUN([AC_COIN_PATCH_LIBTOOL_CYGWIN],
463[ case "$CXX" in
464    clang* | */clang*)
465        # do nothing but don't want to accidentally match the 'cl' patterns below
466        ;;
467    cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
468      AC_MSG_NOTICE(Applying patches to libtool for cl compiler)
469      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
470          -e 's|fix_srcfile_path=\"\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
471          -e 's%compile_deplibs=\"\$dir/\$old_library \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$old_library | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
472          -e 's%compile_deplibs=\"\$dir/\$linklib \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$linklib | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
473          -e 's%lib /OUT:%lib -OUT:%' \
474          -e "s%cygpath -w%$CYGPATH_W%" \
475          -e 's%$AR x \\$f_ex_an_ar_oldlib%bla=\\`lib -nologo -list \\$f_ex_an_ar_oldlib | xargs echo '"$mydos2unix"'\\`; echo \\$bla; for i in \\$bla; do lib -nologo -extract:\\$i \\$f_ex_an_ar_oldlib; done%' \
476          -e 's/$AR t/lib -nologo -list/' \
477          -e 's%f_ex_an_ar_oldlib="\($?*1*\)"%f_ex_an_ar_oldlib='\`"$CYGPATH_W"' \1`%' \
478          -e 's%^archive_cmds=.*%archive_cmds="\\$CC -o \\$lib \\$libobjs \\$compiler_flags \\\\\\`echo \\\\\\"\\$deplibs\\\\\\" | \\$SED -e '"\'"'s/ -lc\\$//'"\'"'\\\\\\` -link -dll~linknames="%' \
479          -e 's%old_archive_cmds="lib -OUT:\\$oldlib\\$oldobjs\\$old_deplibs"%old_archive_cmds="if test -r \\$oldlib; then bla=\\"\\$oldlib\\"; else bla=; fi; lib -OUT:\\$oldlib \\\\\\$bla\\$oldobjs\\$old_deplibs"%' \
480      libtool > conftest.bla
481
482      mv conftest.bla libtool
483      chmod 755 libtool
484      ;;
485    *)
486      AC_MSG_NOTICE(Applying patches to libtool for GNU compiler)
487      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
488          -e 's|"lib /OUT:\\$oldlib\\$oldobjs\\$old_deplibs"|"\\$AR \\$AR_FLAGS \\$oldlib\\$oldobjs\\$old_deplibs~\\$RANLIB \\$oldlib"|' \
489          -e 's|libext="lib"|libext="a"|' \
490      libtool > conftest.bla
491
492      mv conftest.bla libtool
493      chmod 755 libtool
494      ;;
495  esac ]) # COIN_PATCH_LIBTOOL_CYGWIN
496 
497
498# output
499AC_CONFIG_FILES(Makefile
500                ADOL-C/Makefile
501                ADOL-C/include/Makefile
502                ADOL-C/include/adolc/Makefile
503                ADOL-C/include/adolc/internal/adolc_settings.h
504                ADOL-C/include/adolc/drivers/Makefile
505                ADOL-C/include/adolc/internal/Makefile
506                ADOL-C/include/adolc/lie/Makefile
507                ADOL-C/include/adolc/sparse/Makefile
508                ADOL-C/include/adolc/tapedoc/Makefile
509                ADOL-C/src/Makefile
510                ADOL-C/src/drivers/Makefile
511                ADOL-C/src/lie/Makefile
512                ADOL-C/src/sparse/Makefile
513                ADOL-C/src/tapedoc/Makefile
514                ADOL-C/doc/version.tex
515                ADOL-C/examples/Makefile
516                ADOL-C/examples/additional_examples/Makefile
517                ADOL-C/examples/additional_examples/cuda/Makefile
518                ADOL-C/examples/additional_examples/clock/Makefile
519                ADOL-C/examples/additional_examples/checkpointing/Makefile
520                ADOL-C/examples/additional_examples/ext_diff_func/Makefile
521                ADOL-C/examples/additional_examples/fixpoint_exam/Makefile
522                ADOL-C/examples/additional_examples/hessmat/Makefile
523                ADOL-C/examples/additional_examples/lie/Makefile
524                ADOL-C/examples/additional_examples/lufact/Makefile
525                ADOL-C/examples/additional_examples/openmp_exam/Makefile
526                ADOL-C/examples/additional_examples/scal/Makefile
527                ADOL-C/examples/additional_examples/speelpenning/Makefile
528                ADOL-C/examples/additional_examples/taylor/Makefile
529                ADOL-C/examples/additional_examples/detexam/Makefile
530                ADOL-C/examples/additional_examples/helm/Makefile
531                ADOL-C/examples/additional_examples/lighthouse/Makefile
532                ADOL-C/examples/additional_examples/ode/Makefile
533                ADOL-C/examples/additional_examples/sparse/Makefile
534                ADOL-C/examples/additional_examples/tapesave/Makefile
535                ADOL-C/examples/additional_examples/pow/Makefile
536                ADOL-C/examples/additional_examples/timing/Makefile
537                ADOL-C/examples/additional_examples/param/Makefile
538                ADOL-C/test/Makefile
539                MSVisualStudio/v14/sparse/config.h
540                MSVisualStudio/v14/nosparse/config.h
541                MSVisualStudio/v14/x64/sparse/config.h
542                MSVisualStudio/v14/x64/nosparse/config.h
543                adolc.spec
544                adolclib.pc
545)
546
547AC_OUTPUT
548
549#call libtool for cygwin
550AC_COIN_PATCH_LIBTOOL_CYGWIN
551warn=false
552# echo configuration
553echo \
554"
555-----------------------------------------------------------------------------
556Configuration:
557
558  C compiler:                         ${CC}
559  C++ compiler:                       ${CXX}
560  Linker:                             ${LD}
561  Source code location:               `pwd`
562  Install path:                       ${prefix}
563 
564  CFLAGS:                             ${ac_adolc_cflags}
565  CXXFLAGS:                           ${ac_adolc_cxxflags}
566
567  Use Boost pool allocator:           ${using_boost_pool}
568  Use ADOL-C debug mode:              ${adolc_debug}
569  Use ADOL-C hard debug mode:         ${adolc_harddebug}
570  Zero value in adouble default ctor: ${adolc_stdczero}"
571
572if [[ "x${ac_adolc_openmpflag}" != "x" ]] ; then
573    echo \
574"  Access thread number via errno:     ${adolc_tserrno}"
575fi
576
577echo \
578"  Use ADOL-C safe extern mode:        ${adolc_safe_extern}
579  Use ADOL-C late init mode:          ${adolc_late_init}
580
581  Build sparse drivers:               ${sparse}
582  Build with adjoinable MPI support:  ${adolc_ampi_support}
583  Build with ColPack:                 ${have_colpack}"
584if test x$sparse = xyes && test x$have_colpack = xno; then
585    echo -e \
586"  \033@<:@1;31mCompressed sparse structures will not be available
587  Only sparsity patterns can be computed\033@<:@0m"
588    warn=true
589fi
590echo
591
592echo \
593"  Build documented examples:          ${docexa}
594  Build additional examples:          ${addexa}
595  tape_doc routine computes values:   ${tapedoc_values}
596
597  See ADOL-C/src/config.h for further configuration information.
598-----------------------------------------------------------------------------"
599
600# check for make install problems resulting from missing write permission
601pdir=${prefix}
602writable=true
603while test "x${pdir}" != "x/" ; do
604    if test -e ${pdir} && test ! -w ${pdir}; then
605        writable=false
606        break
607    elif test ! -e ${pdir} ; then
608        pdir=`dirname ${pdir}`
609    else
610        break
611    fi
612done
613if test "x${pdir}" == "x/" ; then
614    writable=false
615fi
616if ! ${writable} ; then
617    echo -e \
618"  \033@<:@1;31mPrefix ${prefix} not writable
619  please run ./configure --prefix=DIR
620  with a writable directory path otherwise administrator privileges
621  will be required to run \`make install'\033@<:@0m"
622    warn=true
623fi
624
625case ${prefix} in
626   ${HOME}|${HOME}/*)
627if $warn ; then
628    for (( i=5; i>0; i-- )); do
629        echo -ne "\rPlease read the above messages carefully, continuing in ${i} seconds"
630        sleep 1
631    done
632    echo -e "\rPlease read the above messages carefully                                 "
633fi
634echo \
635"
636*****************************************************************************
637
638  To successfully compile and run programs using the ADOL-C shared library do
639  the following things:
640     compiling:
641        * add \"-I${prefix}/include\" to your compiler call
642     linking:
643        * add \"-L${libdir} -l$adolclib\" to your linker call
644        * extend your linker call by \"-Wl,--rpath -Wl,${libdir}\"
645          (if you wish to skip the point \"executing\")
646     executing (do one of the following things):
647        * add ${libdir} to your LD_LIBRARY_PATH variable
648        * ask your system administrator for adding ${libdir} to
649          the global file containing library search paths (/etc/ld.so.conf)
650
651     (or use the static library by replacing
652        \"-L${libdir} -l$adolclib\" with
653        \"${libdir}/lib$adolclib.a\" when linking)
654
655  See README for instructions on how to change to a nonlocal installation!
656
657*****************************************************************************
658"
659;;
660esac
Note: See TracBrowser for help on using the repository browser.