source: trunk/configure.ac @ 472

Last change on this file since 472 was 471, checked in by kulshres, 6 years ago

merge branch 'master' of 'gitclone' into 'svn'

The following commits were merged:

commit 6e104d84715fd2ba2926f8c99f3ebe51a7d49f4a
Author: Kshitij Kulshreshtha <kshitij@…>
Date: Wed Feb 19 18:58:40 2014 +0100

get make test to work again

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

commit a937e606f3e0e1c2172affffc4d42455cafc89c3
Author: Kshitij Kulshreshtha <kshitij@…>
Date: Wed Feb 19 18:50:01 2014 +0100

simplify linking with colpack

based on the conversation with Jean Utke, we don't need to store
COLPACK_CFLAGS/COLPACK_LIBS etc. Once the check passes in configure
everything is already set up.

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

commit 9e63d3b2f653139a1a7bfe8fa1963c93e9640b62
Author: Kshitij Kulshreshtha <kshitij@…>
Date: Wed Feb 19 18:22:45 2014 +0100

don't use stubs library for real compilation

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

commit cb1deda1f278fc9150ab5a11eecef15f8f76cb7b
Author: Kshitij Kulshreshtha <kshitij@…>
Date: Wed Feb 19 18:13:27 2014 +0100

change LDFLAGS for configure

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

commit 8a02c2d81b286b0869ec7ff207c2238001c29fe3
Author: Kshitij Kulshreshtha <kshitij@…>
Date: Mon Feb 17 19:33:54 2014 +0100

try to deal with non -fPIC mpi libraries

don't use mpicc in the linking step for lib@adolclib@.so
shared libraries cannot be linked with static libraries
mpicc/mpicxx is required to link any user programmes anyway.

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

commit 76e70c141f223e36035492c5742075110449bbd9
Author: Kshitij Kulshreshtha <kshitij@…>
Date: Mon Feb 17 14:19:06 2014 +0100

allow user to call the resulting library whatever they want

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

  • Property svn:keywords set to Author Date Id Revision
File size: 21.2 KB
Line 
1##############################################################################
2# configure.ac -- Process this file with autoconf to produce configure
3# Revision: $Id: configure.ac 471 2014-02-19 18:11:34Z kulshres $
4#
5# Copyright (C) Andrea Walther, Andreas Kowarz
6#               
7# contains patches from the COIN OR libtool
8#
9##############################################################################
10define([ADOLC_VER], [2])
11define([ADOLC_SUB], [4])
12define([ADOLC_LVL], [0])
13
14AC_PREREQ(2.67)
15AC_INIT(adolc,
16        ADOLC_VER.ADOLC_SUB.ADOLC_LVL-trunk,
17        [adol-c@list.coin-or.org])
18config_flags="$*"
19AC_REVISION($Revision: 471 $)
20AC_CONFIG_SRCDIR([ADOL-C/src/adouble.cpp])
21AC_CONFIG_AUX_DIR([autoconf])
22AC_CONFIG_MACRO_DIR([autoconf])
23AC_CONFIG_HEADERS([ADOL-C/src/config.h])
24AC_PREFIX_DEFAULT(${HOME}/adolc_base)
25AM_INIT_AUTOMAKE([1.11 dist-bzip2 foreign])
26AM_MAINTAINER_MODE([disable])
27AM_SILENT_RULES([yes])
28
29
30adolclib=adolc
31
32if test "x$CFLAGS" == x ; then
33    ac_shell_cflags="not_set"
34else
35    ac_shell_cflags="$CFLAGS"
36fi
37if test "x$CXXFLAGS" == x ; then
38    ac_shell_cxxflags="not_set"
39else
40    ac_shell_cxxflags="$CXXFLAGS"
41fi
42libdir_set_on_cmd="no"
43for i in $config_flags ; do
44    case $i in
45    -libdir | --libdir | --libdi | --libd | -libdir=* | --libdir=* | --libdi=* | --libd=*)
46            libdir_set_on_cmd="yes"
47            break
48            ;;
49    esac
50done
51
52AC_MSG_CHECKING(whether to build ADOL-C with adjoinable MPI (AMPI) support)
53AC_ARG_ENABLE(ampi,
54              [AS_HELP_STRING([--enable-ampi],[build ADOL-C with adjoinable MPI (AMPI) support [default=disabled]])],
55              [adolc_ampi_support=$enableval],[adolc_ampi_support=no])
56AC_MSG_RESULT($adolc_ampi_support)
57AM_CONDITIONAL(BUILD_ADOLC_AMPI_SUPPORT,[test x${adolc_ampi_support} = xyes])
58if test x"${adolc_ampi_support}" = xyes ; then
59AC_DEFINE(ADOLC_AMPI_SUPPORT,1,[defined if adjoinable MPI support is to be compiled in])
60fi
61
62# checks for programs
63AC_PROG_CXX
64AC_PROG_CC
65AC_PROG_CPP
66AC_PROG_INSTALL
67AC_PROG_LN_S
68AC_PROG_MAKE_SET
69AC_LIBTOOL_WIN32_DLL
70AC_PROG_LIBTOOL
71
72MPI_CONF_PRE
73
74AC_CHECK_SIZEOF([void *])
75if test "x$ac_cv_sizeof_void_p" = "x8" ; then
76   _lib=lib64
77else
78   _lib=lib
79fi
80if test "x$libdir_set_on_cmd" = "xno" ; then
81   libdir='${exec_prefix}/${_lib}'
82   AC_SUBST(_lib)
83   AC_SUBST(libdir)
84fi
85
86# check for builtin
87ACX_C_BUILTIN_EXPECT
88
89# checks for header files
90AC_HEADER_STDC
91AC_HEADER_TIME
92AC_HEADER_STDBOOL
93AC_CHECK_HEADERS([stddef.h stdlib.h stdio.h string.h unistd.h sys/timeb.h])
94
95# checks for types
96AC_C_CONST
97AC_C_INLINE
98AC_TYPE_SIZE_T
99AC_STRUCT_TM
100
101# Checks for library functions
102AC_FUNC_MALLOC
103AC_FUNC_REALLOC
104if test x$ac_cv_func_malloc_0_nonnull != xyes ; then
105AC_DEFINE_UNQUOTED([calloc],[rpl_calloc],[Define to rpl_calloc if the replacement function should be used.])
106fi
107# Checks for libraries and fuctions
108AC_SEARCH_LIBS([pow], [m])
109AC_CHECK_FUNCS([floor fmax fmin ftime pow sqrt strchr strtol trunc])
110
111# substitutions
112AC_SUBST(ac_aux_dir)
113
114# ADOL-C configuration
115AC_DEFINE(ADOLC_VERSION,ADOLC_VER,[ADOL-C Version])
116AC_DEFINE(ADOLC_SUBVERSION,ADOLC_SUB,[ADOL-C Subversion])
117AC_DEFINE(ADOLC_PATCHLEVEL,ADOLC_LVL,[ADOL-C Patchlevel])
118ADOLC_VERSION=ADOLC_VER
119ADOLC_SUBVERSION=ADOLC_SUB
120ADOLC_PATCHLEVEL=ADOLC_LVL
121AC_SUBST(ADOLC_VERSION)
122AC_SUBST(ADOLC_SUBVERSION)
123AC_SUBST(ADOLC_PATCHLEVEL)
124
125AC_MSG_CHECKING(whether to use calloc or malloc for memory allocation)
126AC_ARG_ENABLE(use-calloc,[AS_HELP_STRING([--disable-use-calloc],
127  [disable use of calloc and use malloc instead for memory allocation [default=calloc is used]])],
128  [use_calloc=$enableval],[use_calloc=yes])
129
130if test x$use_calloc = xyes ; then
131AC_MSG_RESULT(calloc)
132AC_DEFINE(ADOLC_USE_CALLOC,1,[Use calloc instead of malloc for memory allocation])
133else
134AC_MSG_RESULT(malloc)
135fi
136
137AC_MSG_CHECKING(whether to enable atrig/erf functions)
138AC_ARG_ENABLE(atrig-erf,[AS_HELP_STRING([--enable-atrig-erf],
139  [enable atrig and erf functions in ADOL-C [default=no]])],
140  [use_atrig_erf=$enableval],[use_atrig_erf=no])
141AC_MSG_RESULT($use_atrig_erf)
142
143if test x$use_atrig_erf = xyes ; then
144  ATRIG_ERF="#define ATRIG_ERF 1"
145else
146  ATRIG_ERF="#undef ATRIG_ERF"
147fi
148AC_SUBST(ATRIG_ERF)
149
150AC_MSG_CHECKING(whether to use 32-bit or 64-bit locations)
151AC_ARG_ENABLE(ulong,[AS_HELP_STRING([--enable-ulong],
152  [enable 64-bit locations (only available on 64-bit systems) [default=32-bit]])],
153  [use_ulong=$enableval],[use_ulong=no])
154
155if test x$use_ulong = xyes -a 0$ac_cv_sizeof_void_p -ge 8 ; then
156  UINT_TYPE=uint64_t
157  AC_MSG_RESULT(64-bit)
158else
159  UINT_TYPE=uint32_t
160  AC_MSG_RESULT(32-bit)
161fi
162AC_SUBST(UINT_TYPE)
163
164AC_MSG_CHECKING(whether to use single or double precision)
165AC_ARG_ENABLE(double,[AS_HELP_STRING([--disable-double],
166  [disable double precision arithmetic [untested, default=double is enabled]])],
167  [use_double=$enableval],[use_double=yes])
168
169if test x$use_double = xno ; then
170  REAL_TYPE=float
171  echo
172  echo -n "using ${REAL_TYPE} is not well tested, please report bugs if you find any..."
173else
174  REAL_TYPE=double
175fi
176AC_MSG_RESULT($REAL_TYPE)
177AC_SUBST(REAL_TYPE)
178
179AC_MSG_CHECKING(whether to enable advanced branching operations)
180AC_ARG_ENABLE(advanced-branching, [AS_HELP_STRING([--enable-advanced-branching],
181  [enable advanced branching operations to reduce retaping [default=no].
182The boolean valued comparison operators with two adouble arguments will
183not return boolean results but the active results may be used to automatically
184switch branches in conjunction with condassign or advector (see manual).])],
185  [use_advbranch=$enableval],[use_advbranch=no])
186AC_MSG_RESULT($use_advbranch)
187
188if test x$use_advbranch = xyes ; then
189  ADVBRANCH="#define ADOLC_ADVANCED_BRANCHING 1"
190else
191  ADVBRANCH="#undef ADOLC_ADVANCED_BRANCHING"
192fi
193AC_SUBST(ADVBRANCH)
194AC_SUBST(ADVBRANCH)
195
196AC_MSG_CHECKING(whether to use ADOL-C debug mode)
197AC_ARG_ENABLE(debug,
198              [
199AS_HELP_STRING([--enable-debug],[enable ADOL-C debug mode [default=no]])],
200  [
201  adolc_debug=$enableval
202   AC_MSG_RESULT($adolc_debug)
203   ],
204  [
205   adolc_debug=no
206   AC_MSG_RESULT(no)
207   ])
208
209AC_MSG_CHECKING(whether to use ADOL-C hard debug mode)
210AC_ARG_ENABLE(harddebug,
211              [
212AS_HELP_STRING([--enable-harddebug],[enable ADOL-C hard debug mode
213 [default=no]])],
214  [
215   adolc_harddebug=$enableval
216   AC_MSG_RESULT($adolc_harddebug)
217   ],
218  [
219   adolc_harddebug=no
220   AC_MSG_RESULT(no)
221   ])
222
223if test x$adolc_harddebug == xyes ; then
224adolc_debug=yes
225AC_DEFINE(ADOLC_HARDDEBUG,1,[ADOL-C hard debug mode])
226fi
227
228if test x$adolc_debug == xyes ; then
229AC_DEFINE(ADOLC_DEBUG,1,[ADOL-C debug mode])
230fi
231
232AC_MSG_CHECKING(whether the default adouble constructor should initialize the value to 0)
233AC_ARG_ENABLE(stdczero,
234              [
235AS_HELP_STRING([--disable-stdczero],[adouble default constructor does not initialze the value to zero
236(improves performance but yields incorrect results for implicit array initializations, see manual) [default=enabled]])],
237  [
238  adolc_stdczero=no
239  AC_MSG_RESULT(no)
240  ],
241  [
242  adolc_stdczero=yes
243  AC_MSG_RESULT(yes)
244  ])
245
246if test x$adolc_stdczero == xyes; then
247AC_DEFINE(ADOLC_ADOUBLE_STDCZERO,1,[ADOL-C adouble zeroing mode])
248fi
249
250AC_MSG_CHECKING(wether the adouble varaibles have a late initialize option for functions like malloc/realloc)
251AC_ARG_ENABLE(lateinit,
252              [
253AS_HELP_STRING([--enable-lateinit],[adouble constructors need to be called. With malloc or realloc that is not the case. With this option the adouble can do an late initialization.) [default=disabled]])],
254  [
255  adolc_late_init=yes
256  AC_MSG_RESULT(yes)
257  ],
258  [
259  adolc_late_init=no
260  AC_MSG_RESULT(no)
261  ])
262
263if test x$adolc_late_init == xyes; then
264AC_DEFINE(ADOLC_ADOUBLE_LATEINIT,1,[ADOL-C adouble late initialization mode])
265fi
266
267AC_MSG_CHECKING(whether errno is thread save)
268AC_ARG_ENABLE(tserrno,
269              [
270AS_HELP_STRING([--enable-tserrno],[use errno as thread number cache [default=no]])],
271  [
272  adolc_tserrno=$enableval
273  AC_MSG_RESULT($adolc_tserrno)
274   ],
275  [
276  adolc_tserrno=no
277  AC_MSG_RESULT(no)
278  ])
279
280if test x$adolc_tserrno == xyes ; then
281AC_DEFINE(ADOLC_THREADSAVE_ERRNO,1,[ADOL-C thread save errno mode])
282fi
283
284AC_MSG_CHECKING(which flag to use to enable OpenMP)
285AC_ARG_WITH(openmp-flag,
286            [AS_HELP_STRING([--with-openmp-flag=FLAG],
287                            [use FLAG to enable OpenMP at compile time [default=none]])],
288            [ac_adolc_openmpflag=$withval
289             AC_MSG_RESULT($ac_adolc_openmpflag)],
290            [ac_adolc_openmpflag=""
291             AC_MSG_RESULT(none)])
292
293
294# ADOL-C Sparse facility
295AC_MSG_CHECKING(whether to build sparse drivers)
296AC_ARG_ENABLE(sparse,
297            [
298AS_HELP_STRING([--enable-sparse],[build sparse drivers [default=disabled]])],
299            [sparse=$enableval
300             AC_MSG_RESULT($sparse)],
301            [sparse="no"
302             AC_MSG_RESULT(no)])
303
304COLPACK_CONF
305
306AM_CONDITIONAL(SPARSE,[test x${sparse} = xyes])
307
308if test x$sparse = xyes ; then
309   AC_DEFINE(SPARSE,[1],[Define 1 if sparse derivative propagation is to be enabled])
310fi
311
312# ADOL-C Examples
313AC_MSG_CHECKING(whether to build documented examples)
314AC_ARG_ENABLE(docexa,
315            [
316AS_HELP_STRING([--enable-docexa],[build documented examples [default=disabled]])],
317            [docexa=$enableval
318             AC_MSG_RESULT(yes)],
319            [docexa="no"
320             AC_MSG_RESULT(no)])
321AM_CONDITIONAL(DOCEXA,[test x${docexa} = xyes])
322
323AC_MSG_CHECKING(whether to build additional examples)
324AC_ARG_ENABLE(addexa,
325            [AS_HELP_STRING([--enable-addexa],
326                            [build additional examples [default=disabled]])],
327            [addexa=$enableval
328             AC_MSG_RESULT(yes)],
329            [addexa="no"
330             AC_MSG_RESULT(no)])
331AM_CONDITIONAL(ADDEXA,[test x${addexa} = xyes])
332
333AC_MSG_CHECKING(whether to build parallel example)
334AC_ARG_ENABLE(parexa,
335            [AS_HELP_STRING([--enable-parexa],
336                            [build parallel example [default=disabled], if enabled -with-openmp-flag=FLAG required])],
337            [parexa=$enableval
338             AC_MSG_RESULT(yes)],
339            [parexa="no"
340             AC_MSG_RESULT(no)])
341AM_CONDITIONAL(PAREXA,[test x${parexa} = xyes])
342
343# ADOL-C Compilation flags
344AC_MSG_CHECKING(which CFLAGS to use)
345AC_ARG_WITH(cflags,
346            [AS_HELP_STRING([--with-cflags=FLAGS],
347                            [use CFLAGS=FLAGS (default: -O2)])],
348            [ac_adolc_cflags="$withval"
349             if test x${adolc_debug} == xyes ||
350                test x${adolc_harddebug} == xyes ; then
351                ac_adolc_cflags="$ac_adolc_cflags -g -O0"
352             fi
353             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
354             AC_SUBST(ac_adolc_cflags)
355             AC_MSG_RESULT($ac_adolc_cflags)],
356            [if test "$ac_shell_cflags" = "not_set"; then
357                ac_adolc_cflags="-O2"
358                if test x${adolc_debug} == xyes ||
359                   test x${adolc_harddebug} == xyes ; then
360                   ac_adolc_cflags="-g -O0 -Wall -ansi"
361                fi
362             else
363                ac_adolc_cflags="$CFLAGS"
364             fi
365             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
366
367             AC_SUBST(ac_adolc_cflags)
368             AC_MSG_RESULT($ac_adolc_cflags)])
369
370AC_MSG_CHECKING(which CXXFLAGS to use)
371AC_ARG_WITH(cxxflags,
372            [AS_HELP_STRING([--with-cxxflags=FLAGS],
373                            [use CXXFLAGS=FLAGS (default: -O2)])],
374            [ac_adolc_cxxflags="$withval"
375             if test x${adolc_debug} == xyes ||
376                test x${adolc_harddebug} == xyes ; then
377                ac_adolc_cxxflags="$ac_adolc_cxxflags -g -O0"
378             fi
379             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
380             AC_SUBST(ac_adolc_cxxflags)
381             AC_MSG_RESULT($ac_adolc_cxxflags)],
382            [if test "$ac_shell_cxxflags" = "not_set"; then
383                ac_adolc_cxxflags="-O2"
384                if test x${adolc_debug} == xyes ||
385                   test x${adolc_harddebug} == xyes ; then
386                   ac_adolc_cxxflags="-g -O0 -Wall"
387                fi
388             else
389                ac_adolc_cxxflags="$CXXFLAGS"
390             fi
391             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
392            AC_SUBST(ac_adolc_cxxflags)
393            AC_MSG_RESULT($ac_adolc_cxxflags)])
394
395MPI_CONF_POST
396AMPI_CONF
397
398AC_ARG_WITH(soname,
399            [AS_HELP_STRING([--with-soname=NAME],
400              [user can choose what to call his library here [default: if ampi enabled then adolc_ampi otherwise adolc]])],
401      [adolclib=$withval])
402
403AC_SUBST(adolclib)
404
405AC_MSG_CHECKING(whether tape_doc should compute values as it prints the tape contents)
406AC_ARG_ENABLE(tapedoc_values,
407              [
408                AS_HELP_STRING([--disable-tapedoc-values],
409                               [should the tape_doc routine compute the values as it interprets and prints the tape contents [default=enabled]])],
410  [
411  tapedoc_values=no
412  ],
413  [
414  tapedoc_values=yes
415  ])
416AC_MSG_RESULT($tapedoc_values)
417
418if test x$tapedoc_values == xyes; then
419AC_DEFINE(ADOLC_TAPE_DOC_VALUES,1,[ADOL-C tape_doc routine computes values])
420fi
421
422###########################################################################
423#                      COIN_PATCH_LIBTOOL_CYGWIN                          #
424###########################################################################
425
426# Patches to libtool for cygwin. Lots for cl, a few for GCC.
427# For cl:
428# - cygpath is not correctly quoted in fix_srcfile_path
429# - paths generated for .lib files is not run through cygpath -w
430
431#
432# REQUIRED FOR COMPILATION WITH CYGWIN !!!
433#
434 
435
436AC_DEFUN([AC_COIN_PATCH_LIBTOOL_CYGWIN],
437[ case "$CXX" in
438    clang* | */clang*)
439        # do nothing but don't want to accidentally match the 'cl' patterns below
440        ;;
441    cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
442      AC_MSG_NOTICE(Applying patches to libtool for cl compiler)
443      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
444          -e 's|fix_srcfile_path=\"\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
445          -e 's%compile_deplibs=\"\$dir/\$old_library \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$old_library | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
446          -e 's%compile_deplibs=\"\$dir/\$linklib \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$linklib | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
447          -e 's%lib /OUT:%lib -OUT:%' \
448          -e "s%cygpath -w%$CYGPATH_W%" \
449          -e 's%$AR x \\$f_ex_an_ar_oldlib%bla=\\`lib -nologo -list \\$f_ex_an_ar_oldlib | xargs echo '"$mydos2unix"'\\`; echo \\$bla; for i in \\$bla; do lib -nologo -extract:\\$i \\$f_ex_an_ar_oldlib; done%' \
450          -e 's/$AR t/lib -nologo -list/' \
451          -e 's%f_ex_an_ar_oldlib="\($?*1*\)"%f_ex_an_ar_oldlib='\`"$CYGPATH_W"' \1`%' \
452          -e 's%^archive_cmds=.*%archive_cmds="\\$CC -o \\$lib \\$libobjs \\$compiler_flags \\\\\\`echo \\\\\\"\\$deplibs\\\\\\" | \\$SED -e '"\'"'s/ -lc\\$//'"\'"'\\\\\\` -link -dll~linknames="%' \
453          -e 's%old_archive_cmds="lib -OUT:\\$oldlib\\$oldobjs\\$old_deplibs"%old_archive_cmds="if test -r \\$oldlib; then bla=\\"\\$oldlib\\"; else bla=; fi; lib -OUT:\\$oldlib \\\\\\$bla\\$oldobjs\\$old_deplibs"%' \
454      libtool > conftest.bla
455
456      mv conftest.bla libtool
457      chmod 755 libtool
458      ;;
459    *)
460      AC_MSG_NOTICE(Applying patches to libtool for GNU compiler)
461      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
462          -e 's|"lib /OUT:\\$oldlib\\$oldobjs\\$old_deplibs"|"\\$AR \\$AR_FLAGS \\$oldlib\\$oldobjs\\$old_deplibs~\\$RANLIB \\$oldlib"|' \
463          -e 's|libext="lib"|libext="a"|' \
464      libtool > conftest.bla
465
466      mv conftest.bla libtool
467      chmod 755 libtool
468      ;;
469  esac ]) # COIN_PATCH_LIBTOOL_CYGWIN
470 
471
472# output
473AC_CONFIG_FILES(Makefile
474                ADOL-C/Makefile
475                ADOL-C/include/Makefile
476                ADOL-C/include/adolc/Makefile
477                ADOL-C/include/adolc/adolc_settings.h
478                ADOL-C/include/adolc/drivers/Makefile
479                ADOL-C/include/adolc/sparse/Makefile
480                ADOL-C/include/adolc/tapedoc/Makefile
481                ADOL-C/src/Makefile
482                ADOL-C/src/drivers/Makefile
483                ADOL-C/src/sparse/Makefile
484                ADOL-C/src/tapedoc/Makefile
485                ADOL-C/doc/version.tex
486                ADOL-C/examples/Makefile
487                ADOL-C/examples/additional_examples/Makefile
488                ADOL-C/examples/additional_examples/cuda/Makefile
489                ADOL-C/examples/additional_examples/clock/Makefile
490                ADOL-C/examples/additional_examples/checkpointing/Makefile
491                ADOL-C/examples/additional_examples/ext_diff_func/Makefile
492                ADOL-C/examples/additional_examples/fixpoint_exam/Makefile
493                ADOL-C/examples/additional_examples/hessmat/Makefile
494                ADOL-C/examples/additional_examples/lufact/Makefile
495                ADOL-C/examples/additional_examples/openmp_exam/Makefile
496                ADOL-C/examples/additional_examples/scal/Makefile
497                ADOL-C/examples/additional_examples/speelpenning/Makefile
498                ADOL-C/examples/additional_examples/taylor/Makefile
499                ADOL-C/examples/additional_examples/detexam/Makefile
500                ADOL-C/examples/additional_examples/helm/Makefile
501                ADOL-C/examples/additional_examples/lighthouse/Makefile
502                ADOL-C/examples/additional_examples/ode/Makefile
503                ADOL-C/examples/additional_examples/sparse/Makefile
504                ADOL-C/examples/additional_examples/tapesave/Makefile
505                ADOL-C/examples/additional_examples/pow/Makefile
506                ADOL-C/examples/additional_examples/timing/Makefile
507                ADOL-C/test/Makefile
508                MSVisualStudio/v10/sparse/config.h
509                MSVisualStudio/v10/nosparse/config.h
510                MSVisualStudio/v10/x64/sparse/config.h
511                MSVisualStudio/v10/x64/nosparse/config.h
512                adolc.spec
513)
514
515AC_OUTPUT
516
517#call libtool for cygwin
518AC_COIN_PATCH_LIBTOOL_CYGWIN
519warn=false
520# echo configuration
521echo \
522"
523-----------------------------------------------------------------------------
524Configuration:
525
526  C compiler:                         ${CC}
527  C++ compiler:                       ${CXX}
528  Linker:                             ${LD}
529  Source code location:               `pwd`
530  Install path:                       ${prefix}
531 
532  CFLAGS:                             ${ac_adolc_cflags}
533  CXXFLAGS:                           ${ac_adolc_cxxflags}
534
535  Use ADOL-C debug mode:              ${adolc_debug}
536  Use ADOL-C hard debug mode:         ${adolc_harddebug}
537  Zero value in adouble default ctor: ${adolc_stdczero}"
538
539if [[ "x${ac_adolc_openmpflag}" != "x" ]] ; then
540    echo \
541"  Access thread number via errno:     ${adolc_tserrno}"
542fi
543
544echo \
545"  Use ADOL-C safe extern mode:        ${adolc_safe_extern}
546  Use ADOL-C late init mode:          ${adolc_late_init}
547
548  Build sparse drivers:               ${sparse}
549  Build with adjoinable MPI support:  ${adolc_ampi_support}
550  Build with ColPack:                 ${have_colpack}"
551if test x$sparse = xyes && test x$have_colpack = xno; then
552    echo -e \
553"  \033@<:@1;31mCompressed sparse structures will not be available
554  Only sparsity patterns can be computed\033@<:@0m"
555    warn=true
556fi
557echo
558
559echo \
560"  Build documented examples:          ${docexa}
561  Build additional examples:          ${addexa}
562  tape_doc routine computes values:   ${tapedoc_values}
563
564  See ADOL-C/src/config.h for further configuration information.
565-----------------------------------------------------------------------------"
566
567# check for make install problems resulting from missing write permission
568pdir=${prefix}
569writable=true
570while test "x${pdir}" != "x/" ; do
571    if test -e ${pdir} && test ! -w ${pdir}; then
572        writable=false
573        break
574    elif test ! -e ${pdir} ; then
575        pdir=`dirname ${pdir}`
576    else
577        break
578    fi
579done
580if test "x${pdir}" == "x/" ; then
581    writable=false
582fi
583if ! ${writable} ; then
584    echo -e \
585"  \033@<:@1;31mPrefix ${prefix} not writable
586  please run ./configure --prefix=DIR
587  with a writable directory path otherwise administrator privilages
588  will be required to run \`make install'\033@<:@0m"
589    warn=true
590fi
591
592case ${prefix} in
593   ${HOME}|${HOME}/*)
594if $warn ; then
595    for (( i=5; i>0; i-- )); do
596        echo -ne "\rPlease read the above messages carefully, continuing in ${i} seconds"
597        sleep 1
598    done
599    echo -e "\rPlease read the above messages carefully                                 "
600fi
601echo \
602"
603*****************************************************************************
604
605  To successfully compile and run programs using the ADOL-C shared library do
606  the following things:
607     compiling:
608        * add \"-I${prefix}/include\" to your compiler call
609     linking:
610        * add \"-L${libdir} -l$adolclib\" to your linker call
611        * extend your linker call by \"-Wl,--rpath -Wl,${libdir}\"
612          (if you wish to skip the point \"executing\")
613     executing (do one of the following things):
614        * add ${libdir} to your LD_LIBRARY_PATH variable
615        * ask your system administrator for adding ${libdir} to
616          the global file containing library search paths (/etc/ld.so.conf)
617
618     (or use the static library by replacing
619        \"-L${libdir} -l$adolclib\" with
620        \"${libdir}/lib$adolclib.a\" when linking)
621
622  See README for instructions on how to change to a nonlocal installation!
623
624*****************************************************************************
625"
626;;
627esac
Note: See TracBrowser for help on using the repository browser.