source: trunk/configure.ac @ 385

Last change on this file since 385 was 385, checked in by kulshres, 7 years ago

cleanup the ColPack? checking messages

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

  • Property svn:keywords set to Author Date Id Revision
File size: 20.0 KB
Line 
1##############################################################################
2# configure.ac -- Process this file with autoconf to produce configure
3# Revision: $Id: configure.ac 385 2012-12-18 12:33:02Z kulshres $
4#
5# Copyright (C) Andrea Walther, Andreas Kowarz
6#               
7# contains patches from the COIN OR libtool
8#
9##############################################################################
10define([ADOLC_VER], [2])
11define([ADOLC_SUB], [3])
12define([ADOLC_LVL], [0])
13
14AC_PREREQ(2.67)
15AC_INIT(adolc,
16        ADOLC_VER.ADOLC_SUB.ADOLC_LVL-trunk,
17        [adol-c@list.coin-or.org])
18config_flags="$*"
19AC_REVISION($Revision: 385 $)
20AC_CONFIG_SRCDIR([ADOL-C/src/adouble.cpp])
21AC_CONFIG_AUX_DIR(autoconf)
22AC_CONFIG_HEADERS([ADOL-C/src/config.h])
23AC_PREFIX_DEFAULT(${HOME}/adolc_base)
24AM_INIT_AUTOMAKE([1.11 dist-bzip2 foreign])
25AM_SILENT_RULES([yes])
26
27if test "x$CFLAGS" == x ; then
28    ac_shell_cflags="not_set"
29else
30    ac_shell_cflags="$CFLAGS"
31fi
32if test "x$CXXFLAGS" == x ; then
33    ac_shell_cxxflags="not_set"
34else
35    ac_shell_cxxflags="$CXXFLAGS"
36fi
37libdir_set_on_cmd="no"
38for i in $config_flags ; do
39    case $i in
40    -libdir | --libdir | --libdi | --libd | -libdir=* | --libdir=* | --libdi=* | --libd=*)
41            libdir_set_on_cmd="yes"
42            break
43            ;;
44    esac
45done
46
47# checks for programs
48AC_PROG_CXX
49AC_PROG_CC
50AC_PROG_CPP
51AC_PROG_INSTALL
52AC_PROG_LN_S
53AC_PROG_MAKE_SET
54AC_LIBTOOL_WIN32_DLL
55AC_PROG_LIBTOOL
56
57AC_CHECK_SIZEOF([void *])
58if test "x$ac_cv_sizeof_void_p" = "x8" ; then
59   _lib=lib64
60else
61   _lib=lib
62fi
63if test "x$libdir_set_on_cmd" = "xno" ; then
64   libdir='${exec_prefix}/${_lib}'
65   AC_SUBST(_lib)
66   AC_SUBST(libdir)
67fi
68
69# checks for header files
70AC_HEADER_STDC
71AC_HEADER_TIME
72AC_HEADER_STDBOOL
73AC_CHECK_HEADERS([stddef.h stdlib.h stdio.h string.h unistd.h sys/timeb.h])
74
75# checks for types
76AC_C_CONST
77AC_C_INLINE
78AC_TYPE_SIZE_T
79AC_STRUCT_TM
80
81# Checks for library functions
82AC_FUNC_MALLOC
83AC_FUNC_REALLOC
84
85# Checks for libraries and fuctions
86AC_SEARCH_LIBS([pow], [m])
87AC_CHECK_FUNCS([floor fmax fmin ftime pow sqrt strchr strtol trunc])
88
89# substitutions
90AC_SUBST(ac_aux_dir)
91
92# ADOL-C configuration
93AC_DEFINE(ADOLC_VERSION,ADOLC_VER,[ADOL-C Version])
94AC_DEFINE(ADOLC_SUBVERSION,ADOLC_SUB,[ADOL-C Subversion])
95AC_DEFINE(ADOLC_PATCHLEVEL,ADOLC_LVL,[ADOL-C Patchlevel])
96ADOLC_VERSION=ADOLC_VER
97ADOLC_SUBVERSION=ADOLC_SUB
98ADOLC_PATCHLEVEL=ADOLC_LVL
99AC_SUBST(ADOLC_VERSION)
100AC_SUBST(ADOLC_SUBVERSION)
101AC_SUBST(ADOLC_PATCHLEVEL)
102
103AC_MSG_CHECKING(whether to use calloc or malloc for memory allocation)
104AC_ARG_ENABLE(use-calloc,[AS_HELP_STRING([--disable-use-calloc],
105  [disable use of calloc and use malloc instead for memory allocation [default=calloc is used]])],
106  [use_calloc=$enableval],[use_calloc=yes])
107
108if test x$use_calloc = xyes ; then
109AC_MSG_RESULT(calloc)
110AC_DEFINE(ADOLC_USE_CALLOC,1,[Use calloc instead of malloc for memory allocation])
111else
112AC_MSG_RESULT(malloc)
113fi
114
115AC_MSG_CHECKING(whether to enable atrig/erf functions)
116AC_ARG_ENABLE(atrig-erf,[AS_HELP_STRING([--enable-atrig-erf],
117  [enable atrig and erf functions in ADOL-C [default=no]])],
118  [use_atrig_erf=$enableval],[use_atrig_erf=no])
119AC_MSG_RESULT($use_atrig_erf)
120
121if test x$use_atrig_erf = xyes ; then
122  ATRIG_ERF_FALSE="// "
123  ATRIG_ERF_TRUE=""
124else
125  ATRIG_ERF_FALSE=""
126  ATRIG_ERF_TRUE="// "
127fi
128AC_SUBST(ATRIG_ERF_FALSE)
129AC_SUBST(ATRIG_ERF_TRUE)
130
131AC_MSG_CHECKING(whether to use 32-bit or 64-bit locations)
132AC_ARG_ENABLE(ulong,[AS_HELP_STRING([--enable-ulong],
133  [enable 64-bit locations (only available on 64-bit systems) [default=32-bit]])],
134  [use_ulong=$enableval],[use_ulong=no])
135
136if test x$use_ulong = xyes -a 0$ac_cv_sizeof_void_p -ge 8 ; then
137  UINT_TYPE=uint64_t
138  AC_MSG_RESULT(64-bit)
139else
140  UINT_TYPE=uint32_t
141  AC_MSG_RESULT(32-bit)
142fi
143AC_SUBST(UINT_TYPE)
144
145AC_MSG_CHECKING(whether to use single or double precision)
146AC_ARG_ENABLE(double,[AS_HELP_STRING([--disable-double],
147  [disable double precision arithmetic [default=enabled]])],
148  [use_double=$enableval],[use_double=yes])
149
150if test x$use_double = xno ; then
151  REAL_TYPE=float
152else
153  REAL_TYPE=double
154fi
155AC_MSG_RESULT($REAL_TYPE)
156AC_SUBST(REAL_TYPE)
157
158AC_MSG_CHECKING(whether to enable advanced branching operations)
159AC_ARG_ENABLE(advanced-branching, [AS_HELP_STRING([--enable-advanced-branching],
160  [enable advanced branching operations to reduce retaping [default=no].
161The boolean valued comparison operators with two adouble arguments will
162not return boolean results but the active results may be used to automatically
163switch branches in conjunction with condassign or advector (see manual).])],
164  [use_advbranch=$enableval],[use_advbranch=no])
165AC_MSG_RESULT($use_advbranch)
166
167if test x$use_advbranch = xyes ; then
168  ADVBRANCH_TRUE=""
169  ADVBRANCH_FALSE="// "
170else
171  ADVBRANCH_TRUE="// "
172  ADVBRANCH_FALSE=""
173fi
174AC_SUBST(ADVBRANCH_TRUE)
175AC_SUBST(ADVBRANCH_FALSE)
176
177AC_MSG_CHECKING(whether to use ADOL-C debug mode)
178AC_ARG_ENABLE(debug,
179              [
180AS_HELP_STRING([--enable-debug],[enable ADOL-C debug mode [default=no]])],
181  [
182  adolc_debug=$enableval
183   AC_MSG_RESULT($adolc_debug)
184   ],
185  [
186   adolc_debug=no
187   AC_MSG_RESULT(no)
188   ])
189
190AC_MSG_CHECKING(whether to use ADOL-C hard debug mode)
191AC_ARG_ENABLE(harddebug,
192              [
193AS_HELP_STRING([--enable-harddebug],[enable ADOL-C hard debug mode
194 [default=no]])],
195  [
196   adolc_harddebug=$enableval
197   AC_MSG_RESULT($adolc_harddebug)
198   ],
199  [
200   adolc_harddebug=no
201   AC_MSG_RESULT(no)
202   ])
203
204if test x$adolc_harddebug == xyes ; then
205adolc_debug=yes
206AC_DEFINE(ADOLC_HARDDEBUG,1,[ADOL-C hard debug mode])
207fi
208
209if test x$adolc_debug == xyes ; then
210AC_DEFINE(ADOLC_DEBUG,1,[ADOL-C debug mode])
211fi
212
213AC_MSG_CHECKING(whether the default adouble constructor should initialize the value to 0)
214AC_ARG_ENABLE(stdczero,
215              [
216AS_HELP_STRING([--disable-stdczero],[adouble default constructor does not initialze the value to zero
217(improves performance but yields incorrect results for implicit array initializations, see manual) [default=enabled]])],
218  [
219  adolc_stdczero=no
220  AC_MSG_RESULT(no)
221  ],
222  [
223  adolc_stdczero=yes
224  AC_MSG_RESULT(yes)
225  ])
226
227if test x$adolc_stdczero == xyes; then
228AC_DEFINE(ADOLC_ADOUBLE_STDCZERO,1,[ADOL-C adouble zeroing mode])
229fi
230
231AC_MSG_CHECKING(whether errno is thread save)
232AC_ARG_ENABLE(tserrno,
233              [
234AS_HELP_STRING([--enable-tserrno],[use errno as thread number cache [default=no]])],
235  [
236  adolc_tserrno=$enableval
237  AC_MSG_RESULT($adolc_tserrno)
238   ],
239  [
240  adolc_tserrno=no
241  AC_MSG_RESULT(no)
242  ])
243
244if test x$adolc_tserrno == xyes ; then
245AC_DEFINE(ADOLC_THREADSAVE_ERRNO,1,[ADOL-C thread save errno mode])
246fi
247
248AC_MSG_CHECKING(which flag to use to enable OpenMP)
249AC_ARG_WITH(openmp-flag,
250            [AS_HELP_STRING([--with-openmp-flag=FLAG],
251                            [use FLAG to enable OpenMP at compile time [default=none]])],
252            [ac_adolc_openmpflag=$withval
253             AC_MSG_RESULT($ac_adolc_openmpflag)],
254            [ac_adolc_openmpflag=""
255             AC_MSG_RESULT(none)])
256
257
258# ADOL-C Sparse facility
259AC_MSG_CHECKING(whether to build sparse drivers)
260AC_ARG_ENABLE(sparse,
261            [
262AS_HELP_STRING([--enable-sparse],[build sparse drivers [default=disabled]])],
263            [sparse=$enableval
264             AC_MSG_RESULT($sparse)],
265            [sparse="no"
266             AC_MSG_RESULT(no)])
267
268AC_ARG_WITH(colpack,
269        [
270AS_HELP_STRING([--with-colpack=DIR],[path to the colpack library and headers [default=system libraries]])],
271[
272colpack=$withval
273COLPACK_CFLAGS="$ac_adolc_openmpflag -I$colpack/include"
274COLPACK_LIBDIR="$colpack/${_lib}"
275COLPACK_LIBS="$ac_adolc_openmpflag -L$COLPACK_LIBDIR -lColPack"
276],
277[
278COLPACK_CFLAGS="$ac_adolc_openmpflag"
279COLPACK_LIBDIR=""
280COLPACK_LIBS="-lColPack"
281])
282
283AC_LANG_PUSH([C++])
284save_CPPFLAGS="$CPPFLAGS"
285save_LIBS="$LIBS"
286CPPFLAGS="$CPPFLAGS $COLPACK_CFLAGS"
287LIBS="$COLPACK_LIBS $LIBS"
288AC_CHECK_HEADER([ColPack/ColPackHeaders.h],[have_colpackheaders=yes],[have_colpackheaders=no])
289if test x$have_colpackheaders = xyes ; then
290   AC_MSG_CHECKING(for libColPack in $COLPACK_LIBDIR)
291   AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <ColPack/ColPackHeaders.h>],
292                        [ColPack::GraphColoring g])],
293                       [have_colpack=yes],
294                       [have_colpack=no])
295   AC_MSG_RESULT($have_colpack)
296else
297    have_colpack=no
298fi
299CPPFLAGS="$save_CPPFLAGS"
300LIBS="$save_LIBS"
301AC_LANG_POP([C++])
302
303AM_CONDITIONAL(HAVE_LIBCOLPACK,[test x$have_colpack = xyes])
304if test x$have_colpack = xyes; then
305   sparse=yes
306   echo "will build sparse drivers as linking with -lColPack succeeded"
307fi
308AM_CONDITIONAL(SPARSE,[test x${sparse} = xyes])
309
310if test x$sparse = xyes && test x$have_colpack = xyes; then
311        AC_DEFINE(HAVE_LIBCOLPACK,[1],[Define 1 if ColPack is available])
312else
313        COLPACK_CFLAGS=""
314        COLPACK_LIBS=""
315fi
316AC_SUBST(COLPACK_CFLAGS)
317AC_SUBST(COLPACK_LIBS)
318
319# ADOL-C Examples
320AC_MSG_CHECKING(whether to build documented examples)
321AC_ARG_ENABLE(docexa,
322            [
323AS_HELP_STRING([--enable-docexa],[build documented examples [default=disabled]])],
324            [docexa=$enableval
325             AC_MSG_RESULT(yes)],
326            [docexa="no"
327             AC_MSG_RESULT(no)])
328AM_CONDITIONAL(DOCEXA,[test x${docexa} = xyes])
329
330AC_MSG_CHECKING(whether to build additional examples)
331AC_ARG_ENABLE(addexa,
332            [AS_HELP_STRING([--enable-addexa],
333                            [build additional examples [default=disabled]])],
334            [addexa=$enableval
335             AC_MSG_RESULT(yes)],
336            [addexa="no"
337             AC_MSG_RESULT(no)])
338AM_CONDITIONAL(ADDEXA,[test x${addexa} = xyes])
339
340AC_MSG_CHECKING(whether to build parallel example)
341AC_ARG_ENABLE(parexa,
342            [AS_HELP_STRING([--enable-parexa],
343                            [build parallel example [default=disabled], if enabled -with-openmp-flag=FLAG required])],
344            [parexa=$enableval
345             AC_MSG_RESULT(yes)],
346            [parexa="no"
347             AC_MSG_RESULT(no)])
348AM_CONDITIONAL(PAREXA,[test x${parexa} = xyes])
349
350# ADOL-C Compilation flags
351AC_MSG_CHECKING(which CFLAGS to use)
352AC_ARG_WITH(cflags,
353            [AS_HELP_STRING([--with-cflags=FLAGS],
354                            [use CFLAGS=FLAGS (default: -O2)])],
355            [ac_adolc_cflags="$withval"
356             if test x${adolc_debug} == xyes ||
357                test x${adolc_harddebug} == xyes ; then
358                ac_adolc_cflags="$ac_adolc_cflags -g -O0"
359             fi
360             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
361             AC_SUBST(ac_adolc_cflags)
362             AC_MSG_RESULT($ac_adolc_cflags)],
363            [if test "$ac_shell_cflags" = "not_set"; then
364                ac_adolc_cflags="-O2"
365                if test x${adolc_debug} == xyes ||
366                   test x${adolc_harddebug} == xyes ; then
367                   ac_adolc_cflags="-g -O3 -Wall -ansi"
368                fi
369             else
370                ac_adolc_cflags="$CFLAGS"
371             fi
372             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
373
374             AC_SUBST(ac_adolc_cflags)
375             AC_MSG_RESULT($ac_adolc_cflags)])
376
377AC_MSG_CHECKING(which CXXFLAGS to use)
378AC_ARG_WITH(cxxflags,
379            [AS_HELP_STRING([--with-cxxflags=FLAGS],
380                            [use CXXFLAGS=FLAGS (default: -O2)])],
381            [ac_adolc_cxxflags="$withval"
382             if test x${adolc_debug} == xyes ||
383                test x${adolc_harddebug} == xyes ; then
384                ac_adolc_cxxflags="$ac_adolc_cxxflags -g -O0"
385             fi
386             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
387             AC_SUBST(ac_adolc_cxxflags)
388             AC_MSG_RESULT($ac_adolc_cxxflags)],
389            [if test "$ac_shell_cxxflags" = "not_set"; then
390                ac_adolc_cxxflags="-O2"
391                if test x${adolc_debug} == xyes ||
392                   test x${adolc_harddebug} == xyes ; then
393                   ac_adolc_cxxflags="-g -O0 -Wall"
394                fi
395             else
396                ac_adolc_cxxflags="$CXXFLAGS"
397             fi
398             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
399            AC_SUBST(ac_adolc_cxxflags)
400             AC_MSG_RESULT($ac_adolc_cxxflags)])
401
402###########################################################################
403#                      COIN_PATCH_LIBTOOL_CYGWIN                          #
404###########################################################################
405
406# Patches to libtool for cygwin. Lots for cl, a few for GCC.
407# For cl:
408# - cygpath is not correctly quoted in fix_srcfile_path
409# - paths generated for .lib files is not run through cygpath -w
410
411#
412# REQUIRED FOR COMPILATION WITH CYGWIN !!!
413#
414 
415
416AC_DEFUN([AC_COIN_PATCH_LIBTOOL_CYGWIN],
417[ case "$CXX" in
418    cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
419      AC_MSG_NOTICE(Applying patches to libtool for cl compiler)
420      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
421          -e 's|fix_srcfile_path=\"\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
422          -e 's%compile_deplibs=\"\$dir/\$old_library \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$old_library | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
423          -e 's%compile_deplibs=\"\$dir/\$linklib \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$linklib | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
424          -e 's%lib /OUT:%lib -OUT:%' \
425          -e "s%cygpath -w%$CYGPATH_W%" \
426          -e 's%$AR x \\$f_ex_an_ar_oldlib%bla=\\`lib -nologo -list \\$f_ex_an_ar_oldlib | xargs echo '"$mydos2unix"'\\`; echo \\$bla; for i in \\$bla; do lib -nologo -extract:\\$i \\$f_ex_an_ar_oldlib; done%' \
427          -e 's/$AR t/lib -nologo -list/' \
428          -e 's%f_ex_an_ar_oldlib="\($?*1*\)"%f_ex_an_ar_oldlib='\`"$CYGPATH_W"' \1`%' \
429          -e 's%^archive_cmds=.*%archive_cmds="\\$CC -o \\$lib \\$libobjs \\$compiler_flags \\\\\\`echo \\\\\\"\\$deplibs\\\\\\" | \\$SED -e '"\'"'s/ -lc\\$//'"\'"'\\\\\\` -link -dll~linknames="%' \
430          -e 's%old_archive_cmds="lib -OUT:\\$oldlib\\$oldobjs\\$old_deplibs"%old_archive_cmds="if test -r \\$oldlib; then bla=\\"\\$oldlib\\"; else bla=; fi; lib -OUT:\\$oldlib \\\\\\$bla\\$oldobjs\\$old_deplibs"%' \
431      libtool > conftest.bla
432
433      mv conftest.bla libtool
434      chmod 755 libtool
435      ;;
436    *)
437      AC_MSG_NOTICE(Applying patches to libtool for GNU compiler)
438      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
439          -e 's|"lib /OUT:\\$oldlib\\$oldobjs\\$old_deplibs"|"\\$AR \\$AR_FLAGS \\$oldlib\\$oldobjs\\$old_deplibs~\\$RANLIB \\$oldlib"|' \
440          -e 's|libext="lib"|libext="a"|' \
441      libtool > conftest.bla
442
443      mv conftest.bla libtool
444      chmod 755 libtool
445      ;;
446  esac ]) # COIN_PATCH_LIBTOOL_CYGWIN
447 
448
449# output
450AC_CONFIG_FILES(Makefile
451                ADOL-C/Makefile
452                ADOL-C/include/Makefile
453                ADOL-C/include/adolc/Makefile
454                ADOL-C/include/adolc/adolc_settings.h
455                ADOL-C/include/adolc/drivers/Makefile
456                ADOL-C/include/adolc/sparse/Makefile
457                ADOL-C/include/adolc/tapedoc/Makefile
458                ADOL-C/src/Makefile
459                ADOL-C/src/drivers/Makefile
460                ADOL-C/src/sparse/Makefile
461                ADOL-C/src/tapedoc/Makefile
462                ADOL-C/doc/version.tex
463                ADOL-C/examples/Makefile
464                ADOL-C/examples/additional_examples/Makefile
465                ADOL-C/examples/additional_examples/clock/Makefile
466                ADOL-C/examples/additional_examples/checkpointing/Makefile
467                ADOL-C/examples/additional_examples/ext_diff_func/Makefile
468                ADOL-C/examples/additional_examples/fixpoint_exam/Makefile
469                ADOL-C/examples/additional_examples/hessmat/Makefile
470                ADOL-C/examples/additional_examples/lufact/Makefile
471                ADOL-C/examples/additional_examples/openmp_exam/Makefile
472                ADOL-C/examples/additional_examples/scal/Makefile
473                ADOL-C/examples/additional_examples/speelpenning/Makefile
474                ADOL-C/examples/additional_examples/taylor/Makefile
475                ADOL-C/examples/additional_examples/detexam/Makefile
476                ADOL-C/examples/additional_examples/helm/Makefile
477                ADOL-C/examples/additional_examples/lighthouse/Makefile
478                ADOL-C/examples/additional_examples/ode/Makefile
479                ADOL-C/examples/additional_examples/sparse/Makefile
480                ADOL-C/examples/additional_examples/tapesave/Makefile
481                ADOL-C/examples/additional_examples/pow/Makefile
482                ADOL-C/examples/additional_examples/timing/Makefile
483                ADOL-C/test/Makefile
484                MSVisualStudio/v10/sparse/config.h
485                MSVisualStudio/v10/nosparse/config.h
486                MSVisualStudio/v10/x64/sparse/config.h
487                MSVisualStudio/v10/x64/nosparse/config.h
488                adolc.spec
489)
490
491AC_OUTPUT
492
493#call libtool for cygwin
494AC_COIN_PATCH_LIBTOOL_CYGWIN
495warn=false
496# echo configuration
497echo \
498"
499-----------------------------------------------------------------------------
500Configuration:
501
502  C compiler:                         ${CC}
503  C++ compiler:                       ${CXX}
504  Linker:                             ${LD}
505  Source code location:               `pwd`
506  Install path:                       ${prefix}
507 
508  CFLAGS:                             ${ac_adolc_cflags}
509  CXXFLAGS:                           ${ac_adolc_cxxflags}
510
511  Use ADOL-C debug mode:              ${adolc_debug}
512  Use ADOL-C hard debug mode:         ${adolc_harddebug}
513  Zero value in adouble default ctor: ${adolc_stdczero}"
514
515if [[ "x${ac_adolc_openmpflag}" != "x" ]] ; then
516    echo \
517"  Access thread number via errno:     ${adolc_tserrno}"
518fi
519
520echo \
521"  Use ADOL-C safe extern mode:        ${adolc_safe_extern}
522
523  Build sparse drivers:               ${sparse}
524  Build with ColPack:                 ${have_colpack}"
525if test x$sparse = xyes && test x$have_colpack = xno; then
526    echo -e \
527"  \033@<:@1;31mCompressed sparse structures will not be available
528  Only sparsity patterns can be computed\033@<:@0m"
529    warn=true
530fi
531echo
532
533echo \
534"  Build documented examples:          ${docexa}
535  Build additional examples:          ${addexa}
536
537  See ADOL-C/src/config.h for further configuration information.
538-----------------------------------------------------------------------------"
539
540# check for make install problems resulting from missing write permission
541pdir=${prefix}
542writable=true
543while test "x${pdir}" != "x/" ; do
544    if test -e ${pdir} && test ! -w ${pdir}; then
545        writable=false
546        break
547    elif test ! -e ${pdir} ; then
548        pdir=`dirname ${pdir}`
549    else
550        break
551    fi
552done
553if test "x${pdir}" == "x/" ; then
554    writable=false
555fi
556if ! ${writable} ; then
557    echo -e \
558"  \033@<:@1;31mPrefix ${prefix} not writable
559  please run ./configure --prefix=DIR
560  with a writable directory path otherwise administrator privilages
561  will be required to run \`make install'\033@<:@0m"
562    warn=true
563fi
564
565case ${prefix} in
566   ${HOME}|${HOME}/*)
567if $warn ; then
568    for (( i=5; i>0; i-- )); do
569        echo -ne "\rPlease read the above messages carefully, continuing in ${i} seconds"
570        sleep 1
571    done
572    echo -e "\rPlease read the above messages carefully                                 "
573fi
574echo \
575"
576*****************************************************************************
577
578  To successfully compile and run programs using the ADOL-C shared library do
579  the following things:
580     compiling:
581        * add \"-I${prefix}/include\" to your compiler call
582     linking:
583        * add \"-L${prefix}/${_lib} -ladolc\" to your linker call
584        * extend your linker call by \"-Wl,--rpath -Wl,${prefix}/${_lib}\"
585          (if you wish to skip the point \"executing\")
586     executing (do one of the following things):
587        * add ${prefix}/${_lib} to your LD_LIBRARY_PATH variable
588        * ask your system administrator for adding ${prefix}/${_lib} to
589          the global file containing library search paths (/etc/ld.so.conf)
590
591     (or use the static library by replacing
592        \"-L${prefix}/${_lib} -ladolc\" with
593        \"${prefix}/${_lib}/libadolc.a\" when linking)
594
595  See README for instructions on how to change to a nonlocal installation!
596
597*****************************************************************************
598"
599;;
600esac
Note: See TracBrowser for help on using the repository browser.