source: trunk/configure.ac @ 288

Last change on this file since 288 was 288, checked in by kulshres, 9 years ago

small change in the help text of configure

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

  • Property svn:keywords set to Author Date Id Revision
File size: 19.2 KB
Line 
1##############################################################################
2# configure.ac -- Process this file with autoconf to produce configure
3# Revision: $Id: configure.ac 288 2012-01-12 10:47:46Z kulshres $
4#
5# Copyright (C) Andrea Walther, Andreas Kowarz
6#               
7# contains patches from the COIN OR libtool
8#
9##############################################################################
10define([ADOLC_VER], [2])
11define([ADOLC_SUB], [2])
12define([ADOLC_LVL], [1])
13
14AC_PREREQ(2.57)
15AC_INIT(adolc,
16        ADOLC_VER.ADOLC_SUB.ADOLC_LVL-trunk,
17        [adol-c@list.coin-or.org])
18AC_REVISION($Revision: 288 $)
19AC_CONFIG_SRCDIR([ADOL-C/src/adolc.h])
20AC_CONFIG_AUX_DIR(autoconf)
21AC_CONFIG_HEADERS([ADOL-C/src/config.h])
22AC_PREFIX_DEFAULT(${HOME}/adolc_base)
23AM_INIT_AUTOMAKE([dist-bzip2 foreign])
24
25if test "x$CFLAGS" == x ; then
26    ac_shell_cflags="not_set"
27else
28    ac_shell_cflags="$CFLAGS"
29fi
30if test "x$CXXFLAGS" == x ; then
31    ac_shell_cxxflags="not_set"
32else
33    ac_shell_cxxflags="$CXXFLAGS"
34fi
35
36# checks for programs
37AC_PROG_CXX
38AC_PROG_CC
39AC_PROG_CPP
40AC_PROG_INSTALL
41AC_PROG_LN_S
42AC_PROG_MAKE_SET
43AC_LIBTOOL_WIN32_DLL
44AC_PROG_LIBTOOL
45DOLT
46
47AC_CHECK_SIZEOF([void *])
48if test "x$ac_cv_sizeof_void_p" = "x8" ; then
49   _lib=lib64
50else
51   _lib=lib
52fi
53libdir='${prefix}/${_lib}'
54AC_SUBST(_lib)
55AC_SUBST(libdir)
56
57# checks for header files
58AC_HEADER_STDC
59AC_HEADER_TIME
60AC_HEADER_STDBOOL
61AC_CHECK_HEADERS([stddef.h stdlib.h stdio.h string.h unistd.h sys/timeb.h])
62
63# checks for types
64AC_C_CONST
65AC_C_INLINE
66AC_TYPE_SIZE_T
67AC_STRUCT_TM
68
69# Checks for library functions
70AC_FUNC_MALLOC
71AC_FUNC_REALLOC
72AC_CHECK_FUNCS([floor ftime pow sqrt strchr strtol])
73
74# substitutions
75AC_SUBST(ac_aux_dir)
76
77# Checks for libraries
78AC_CHECK_LIB([m], [pow])
79
80# ADOL-C configuration
81AC_DEFINE(ADOLC_VERSION,ADOLC_VER,[ADOL-C Version])
82AC_DEFINE(ADOLC_SUBVERSION,ADOLC_SUB,[ADOL-C Subversion])
83AC_DEFINE(ADOLC_PATCHLEVEL,ADOLC_LVL,[ADOL-C Patchlevel])
84ADOLC_VERSION=ADOLC_VER
85ADOLC_SUBVERSION=ADOLC_SUB
86ADOLC_PATCHLEVEL=ADOLC_LVL
87AC_SUBST(ADOLC_VERSION)
88AC_SUBST(ADOLC_SUBVERSION)
89AC_SUBST(ADOLC_PATCHLEVEL)
90
91AC_MSG_CHECKING(whether to use ADOL-C debug mode)
92AC_ARG_ENABLE(debug,
93              [
94AS_HELP_STRING([--enable-debug],[enable ADOL-C debug mode [default=no]])],
95  [AC_DEFINE(ADOLC_DEBUG,1,[ADOL-C debug mode])
96   AC_MSG_RESULT(yes)
97   adolc_debug="yes"],
98  [AC_MSG_RESULT(no)
99   adolc_debug="no"])
100
101AC_MSG_CHECKING(whether to use ADOL-C hard debug mode)
102AC_ARG_ENABLE(harddebug,
103              [
104AS_HELP_STRING([--enable-harddebug],[enable ADOL-C hard debug mode
105 [default=no]])],
106  [AC_DEFINE(ADOLC_HARDDEBUG,1,[ADOL-C hard debug mode])
107   AC_DEFINE(ADOLC_DEBUG,1,[ADOL-C debug mode])
108   AC_MSG_RESULT(yes)
109   adolc_harddebug="yes"],
110  [AC_MSG_RESULT(no)
111   adolc_harddebug="no"])
112
113AC_MSG_CHECKING(whether standard adouble constructor shall zero value)
114AC_ARG_ENABLE(stdczero,
115              [
116AS_HELP_STRING([--enable-stdczero],[adouble standard constructor zeros value
117(at the cost of performance) [default=no]])],
118  [AC_DEFINE(ADOLC_ADOUBLE_STDCZERO,1,[ADOL-C adouble zeroing mode])
119   AC_MSG_RESULT(yes)
120   adolc_stdczero="yes"],
121  [AC_MSG_RESULT(no)
122   adolc_stdczero="no"])
123
124AC_MSG_CHECKING(whether errno is thread save)
125AC_ARG_ENABLE(tserrno,
126              [
127AS_HELP_STRING([--enable-tserrno],[use errno as thread number cache [default=no]])],
128  [AC_DEFINE(ADOLC_THREADSAVE_ERRNO,1,[ADOL-C thread save errno mode])
129   AC_MSG_RESULT(yes)
130   adolc_tserrno="yes"],
131  [AC_MSG_RESULT(no)
132   adolc_tserrno="no"])
133
134AC_MSG_CHECKING(whether external function call forces backup of all adoubles)
135AC_ARG_ENABLE(safe_extern,
136              [
137AS_HELP_STRING([--enable-safe-extern],[backup all adoubles before calling an external function [default=no]])],
138  [AC_DEFINE(ADOLC_SAFE_EXTERN,1,[ADOL-C safe extern mode])
139   AC_MSG_RESULT(yes)
140   adolc_safe_extern="yes"],
141  [AC_MSG_RESULT(no)
142   adolc_safe_extern="no"])
143
144AC_MSG_CHECKING(which flag to use to enable OpenMP)
145AC_ARG_WITH(openmp-flag,
146            [AS_HELP_STRING([--with-openmp-flag=FLAG],
147                            [use FLAG to enable OpenMP at compile time [default=none]])],
148            [ac_adolc_openmpflag=$withval
149             msg_result=$withval
150             AC_MSG_RESULT($ac_adolc_openmpflag)],
151            [ac_adolc_openmpflag=""
152             msg_result="none"
153             AC_MSG_RESULT($ac_adolc_openmpflag)])
154
155
156# ADOL-C Sparse facility
157AC_MSG_CHECKING(whether to build sparse drivers)
158AC_ARG_ENABLE(sparse,
159            [
160AS_HELP_STRING([--enable-sparse],[build sparse drivers [default=disabled]])],
161            [sparse=$enableval
162             AC_MSG_RESULT(yes)],
163            [sparse="no"
164             AC_MSG_RESULT(no)])
165
166test "x${ac_pwd}" = x && ac_pwd=`pwd`
167abs_srcdir=`readlink -f ${ac_pwd}/${srcdir}`
168AC_ARG_WITH(colpack,
169        [
170AS_HELP_STRING([--with-colpack=DIR],[path to the colpack library and headers [default=${srcdir}/ThirdParty/ColPack]])],
171                [colpack=$withval],
172                [colpack=${abs_srcdir}/ThirdParty/ColPack])
173
174if test "x${_lib}" != xlib ; then
175   dirlist="${_lib} lib build/${_lib} build/lib"
176else
177   dirlist="${_lib} build/${_lib}"
178fi
179
180AC_LANG_PUSH([C++])
181for dir in $dirlist ; do
182    unset ac_cv_header_ColPackHeaders_h
183    COLPACK_CFLAGS="$ac_adolc_openmpflag -I$colpack/$dir/../include"
184    COLPACK_LIBDIR="$colpack/$dir"
185    COLPACK_LIBS="$ac_adolc_openmpflag -L$COLPACK_LIBDIR -lColPack -Wl,-rpath,$COLPACK_LIBDIR"
186    save_CPPFLAGS="$CPPFLAGS"
187    save_LIBS="$LIBS"
188    CPPFLAGS="$CPPFLAGS $COLPACK_CFLAGS"
189    LIBS="$COLPACK_LIBS $LIBS"
190    AC_MSG_CHECKING(for ColPack in $COLPACK_LIBDIR)
191    AC_CHECK_HEADER([ColPackHeaders.h],[have_colpackheaders=yes],[have_colpackheaders=no])
192    if test x$have_colpackheaders = xyes ; then
193        AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <ColPackHeaders.h>],
194                          [ColPack::GraphColoring g])],
195                       [have_colpack=yes
196                        AC_MSG_RESULT(linking with -lColPack succeeded)],
197                       [have_colpack=no,
198                        AC_MSG_RESULT(linking with -lColPack failed)])
199    else
200        have_colpack=no
201    fi
202    CPPFLAGS="$save_CPPFLAGS"
203    LIBS="$save_LIBS"
204    if test x$have_colpack = xyes ; then
205        break
206    fi
207done
208AC_LANG_POP([C++])
209AM_CONDITIONAL(HAVE_LIBCOLPACK,[test x$have_colpack = xyes])
210if test x$have_colpack = xyes; then
211   # test if the directories exists and what is the real path
212   # if not then we found ColPack in some standard location
213   # and these variables are useless
214   COLPACK_LIBDIR=`readlink -f $COLPACK_LIBDIR`
215   if test -n $COLPACK_LIBDIR ; then
216      colpack_incdir=`readlink -f $COLPACK_LIBDIR/../include`
217      if test -n $colpack_incdir ; then
218         COLPACK_CFLAGS="$ac_adolc_openmpflag -I$colpack_incdir"
219      else
220         COLPACK_CFLAGS=""
221      fi
222      COLPACK_LIBS="$ac_adolc_openmpflag -L$COLPACK_LIBDIR -lColPack -Wl,-rpath,$COLPACK_LIBDIR"
223   else
224      COLPACK_CFLAGS=""
225      COLPACK_LIBS=""
226   fi
227   # if the real path to ColPack is inside the ${srcdir}
228   # then we should statically link all ColPack objects inside libadolc
229   # it is likely that the srcdir is not needed anymore after make install
230   # and thus deleted thus no more ColPack to dynamically link to
231   # an external ColPack path is less likely to be removed
232   if echo $COLPACK_LIBDIR | grep -q ^${abs_srcdir} ; then
233       echo will link ColPack static as it was found in the source directory
234       test -d $COLPACK_LIBDIR/.tmp && rm -rf $COLPACK_LIBDIR/.tmp
235       mkdir -p $COLPACK_LIBDIR/.tmp/
236       mkdir -p $COLPACK_LIBDIR/.tmp/.libs
237       ( cd $COLPACK_LIBDIR/.tmp/ ; $AR x ../libColPack.a ; cp *.o .libs/
238         for i in *.o ; do j=`echo $i | sed 's/\.o/\.lo/' `
239                 cat >$j <<EOF
240# $j - a libtool object file
241# Generated by doltcompile, not libtool
242pic_object='.libs/$i'
243non_pic_object='$i'
244EOF
245        done
246        )
247       COLPACK_LIBS="$ac_adolc_openmpflag `find "$COLPACK_LIBDIR/.tmp" -name \*.lo -printf "%p "` "
248   fi
249   sparse=yes
250   echo "will build sparse drivers as linking with -lColPack succeeded"
251fi
252AM_CONDITIONAL(SPARSE,[test x${sparse} = xyes])
253
254if test x$sparse = xyes && test x$have_colpack = xyes; then
255        AC_DEFINE(HAVE_LIBCOLPACK,[1],[Define 1 if ColPack is available])
256else
257        COLPACK_CFLAGS=""
258        COLPACK_LIBS=""
259fi
260AC_SUBST(COLPACK_CFLAGS)
261AC_SUBST(COLPACK_LIBS)
262
263# ADOL-C Examples
264AC_MSG_CHECKING(whether to build documented examples)
265AC_ARG_ENABLE(docexa,
266            [
267AS_HELP_STRING([--enable-docexa],[build documented examples [default=disabled]])],
268            [docexa=$enableval
269             AC_MSG_RESULT(yes)],
270            [docexa="no"
271             AC_MSG_RESULT(no)])
272AM_CONDITIONAL(DOCEXA,[test x${docexa} = xyes])
273
274AC_MSG_CHECKING(whether to build additional examples)
275AC_ARG_ENABLE(addexa,
276            [AS_HELP_STRING([--enable-addexa],
277                            [build additional examples [default=disabled]])],
278            [addexa=$enableval
279             AC_MSG_RESULT(yes)],
280            [addexa="no"
281             AC_MSG_RESULT(no)])
282AM_CONDITIONAL(ADDEXA,[test x${addexa} = xyes])
283
284AC_MSG_CHECKING(whether to build parallel example)
285AC_ARG_ENABLE(parexa,
286            [AS_HELP_STRING([--enable-parexa],
287                            [build parallel example [default=disabled], if enabled -with-openmp-flag=FLAG required])],
288            [parexa=$enableval
289             AC_MSG_RESULT(yes)],
290            [parexa="no"
291             AC_MSG_RESULT(no)])
292AM_CONDITIONAL(PAREXA,[test x${parexa} = xyes])
293
294# ADOL-C Compilation flags
295AC_MSG_CHECKING(which CFLAGS to use)
296AC_ARG_WITH(cflags,
297            [AS_HELP_STRING([--with-cflags=FLAGS],
298                            [use CFLAGS=FLAGS (default: -O2)])],
299            [ac_adolc_cflags="$withval"
300             if test x${adolc_debug} == xyes ||
301                test x${adolc_harddebug} == xyes ; then
302                ac_adolc_cflags="$ac_adolc_cflags -g -O0"
303             fi
304             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
305             AC_SUBST(ac_adolc_cflags)
306             AC_MSG_RESULT($ac_adolc_cflags)],
307            [if test "$ac_shell_cflags" = "not_set"; then
308                ac_adolc_cflags="-O2"
309                if test x${adolc_debug} == xyes ||
310                   test x${adolc_harddebug} == xyes ; then
311                   ac_adolc_cflags="-g -O3 -Wall -ansi"
312                fi
313             else
314                ac_adolc_cflags="$CFLAGS"
315             fi
316             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
317
318             AC_SUBST(ac_adolc_cflags)
319             AC_MSG_RESULT($ac_adolc_cflags)])
320
321AC_MSG_CHECKING(which CXXFLAGS to use)
322AC_ARG_WITH(cxxflags,
323            [AS_HELP_STRING([--with-cxxflags=FLAGS],
324                            [use CXXFLAGS=FLAGS (default: -O2)])],
325            [ac_adolc_cxxflags="$withval"
326             if test x${adolc_debug} == xyes ||
327                test x${adolc_harddebug} == xyes ; then
328                ac_adolc_cxxflags="$ac_adolc_cxxflags -g -O0"
329             fi
330             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
331             AC_SUBST(ac_adolc_cxxflags)
332             AC_MSG_RESULT($ac_adolc_cxxflags)],
333            [if test "$ac_shell_cxxflags" = "not_set"; then
334                ac_adolc_cxxflags="-O2"
335                if test x${adolc_debug} == xyes ||
336                   test x${adolc_harddebug} == xyes ; then
337                   ac_adolc_cxxflags="-g -O0 -Wall"
338                fi
339             else
340                ac_adolc_cxxflags="$CXXFLAGS"
341             fi
342             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
343            AC_SUBST(ac_adolc_cxxflags)
344             AC_MSG_RESULT($ac_adolc_cxxflags)])
345
346###########################################################################
347#                      COIN_PATCH_LIBTOOL_CYGWIN                          #
348###########################################################################
349
350# Patches to libtool for cygwin. Lots for cl, a few for GCC.
351# For cl:
352# - cygpath is not correctly quoted in fix_srcfile_path
353# - paths generated for .lib files is not run through cygpath -w
354
355#
356# REQUIRED FOR COMPILATION WITH CYGWIN !!!
357#
358 
359
360AC_DEFUN([AC_COIN_PATCH_LIBTOOL_CYGWIN],
361[ case "$CXX" in
362    cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
363      AC_MSG_NOTICE(Applying patches to libtool for cl compiler)
364      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
365          -e 's|fix_srcfile_path=\"\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
366          -e 's%compile_deplibs=\"\$dir/\$old_library \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$old_library | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
367          -e 's%compile_deplibs=\"\$dir/\$linklib \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$linklib | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
368          -e 's%lib /OUT:%lib -OUT:%' \
369          -e "s%cygpath -w%$CYGPATH_W%" \
370          -e 's%$AR x \\$f_ex_an_ar_oldlib%bla=\\`lib -nologo -list \\$f_ex_an_ar_oldlib | xargs echo '"$mydos2unix"'\\`; echo \\$bla; for i in \\$bla; do lib -nologo -extract:\\$i \\$f_ex_an_ar_oldlib; done%' \
371          -e 's/$AR t/lib -nologo -list/' \
372          -e 's%f_ex_an_ar_oldlib="\($?*1*\)"%f_ex_an_ar_oldlib='\`"$CYGPATH_W"' \1`%' \
373          -e 's%^archive_cmds=.*%archive_cmds="\\$CC -o \\$lib \\$libobjs \\$compiler_flags \\\\\\`echo \\\\\\"\\$deplibs\\\\\\" | \\$SED -e '"\'"'s/ -lc\\$//'"\'"'\\\\\\` -link -dll~linknames="%' \
374          -e 's%old_archive_cmds="lib -OUT:\\$oldlib\\$oldobjs\\$old_deplibs"%old_archive_cmds="if test -r \\$oldlib; then bla=\\"\\$oldlib\\"; else bla=; fi; lib -OUT:\\$oldlib \\\\\\$bla\\$oldobjs\\$old_deplibs"%' \
375      libtool > conftest.bla
376
377      mv conftest.bla libtool
378      chmod 755 libtool
379      ;;
380    *)
381      AC_MSG_NOTICE(Applying patches to libtool for GNU compiler)
382      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
383          -e 's|"lib /OUT:\\$oldlib\\$oldobjs\\$old_deplibs"|"\\$AR \\$AR_FLAGS \\$oldlib\\$oldobjs\\$old_deplibs~\\$RANLIB \\$oldlib"|' \
384          -e 's|libext="lib"|libext="a"|' \
385      libtool > conftest.bla
386
387      mv conftest.bla libtool
388      chmod 755 libtool
389      ;;
390  esac ]) # COIN_PATCH_LIBTOOL_CYGWIN
391 
392
393SHAVE_INIT([autoconf],[enable])
394
395# output
396AC_CONFIG_FILES(Makefile
397                autoconf/shave-libtool
398                autoconf/shave
399                ADOL-C/Makefile
400                ADOL-C/src/Makefile
401                ADOL-C/src/drivers/Makefile
402                ADOL-C/src/sparse/Makefile
403                ADOL-C/src/tapedoc/Makefile
404                ADOL-C/doc/version.tex
405                ADOL-C/examples/Makefile
406                ADOL-C/examples/additional_examples/Makefile
407                ADOL-C/examples/additional_examples/clock/Makefile
408                ADOL-C/examples/additional_examples/checkpointing/Makefile
409                ADOL-C/examples/additional_examples/ext_diff_func/Makefile
410                ADOL-C/examples/additional_examples/fixpoint_exam/Makefile
411                ADOL-C/examples/additional_examples/hessmat/Makefile
412                ADOL-C/examples/additional_examples/lufact/Makefile
413                ADOL-C/examples/additional_examples/openmp_exam/Makefile
414                ADOL-C/examples/additional_examples/scal/Makefile
415                ADOL-C/examples/additional_examples/speelpenning/Makefile
416                ADOL-C/examples/additional_examples/taylor/Makefile
417                ADOL-C/examples/additional_examples/detexam/Makefile
418                ADOL-C/examples/additional_examples/helm/Makefile
419                ADOL-C/examples/additional_examples/lighthouse/Makefile
420                ADOL-C/examples/additional_examples/ode/Makefile
421                ADOL-C/examples/additional_examples/sparse/Makefile
422                ADOL-C/examples/additional_examples/tapesave/Makefile
423                ADOL-C/examples/additional_examples/pow/Makefile
424                ADOL-C/examples/additional_examples/timing/Makefile
425                ADOL-C/test/Makefile
426                MSVisualStudio/v10/sparse/config.h
427                MSVisualStudio/v10/nosparse/config.h
428                MSVisualStudio/v10/x64/sparse/config.h
429                MSVisualStudio/v10/x64/nosparse/config.h
430                adolc.spec
431)
432
433AC_OUTPUT
434
435#call libtool for cygwin
436AC_COIN_PATCH_LIBTOOL_CYGWIN
437warn=false
438# echo configuration
439echo \
440"
441-----------------------------------------------------------------------------
442Configuration:
443
444  C compiler:                       ${CC}
445  C++ compiler:                     ${CXX}
446  Linker:                           ${LD}
447  Source code location:             `pwd`
448  Install path:                     ${prefix}
449 
450  CFLAGS:                           ${ac_adolc_cflags}
451  CXXFLAGS:                         ${ac_adolc_cxxflags}
452
453  Use ADOL-C debug mode:            ${adolc_debug}
454  Use ADOL-C hard debug mode:       ${adolc_harddebug}
455  Use ADOL-C adouble zeroing mode:  ${adolc_stdczero}"
456
457if [[ "x${ac_adolc_openmpflag}" != "x" ]] ; then
458    echo \
459"  Access thread number via errno:   ${adolc_tserrno}"
460fi
461
462echo \
463"  Use ADOL-C safe extern mode:      ${adolc_safe_extern}
464
465  Build sparse drivers:             ${sparse}
466  Build with ColPack:               ${have_colpack}"
467if test x$sparse = xyes && test x$have_colpack = xno; then
468    echo -e \
469"  \033@<:@1;31mCompressed sparse structures will not be available
470  Only sparsity patterns can be computed\033@<:@0m"
471    warn=true
472fi
473echo
474
475echo \
476"  Build documented examples:        ${docexa}
477  Build additional examples:        ${addexa}
478
479  See ADOL-C/src/config.h for further configuration information.
480-----------------------------------------------------------------------------"
481
482# check for make install problems resulting from missing write permission
483pdir=${prefix}
484writable=true
485while test "x${pdir}" != "x/" ; do
486    if test -e ${pdir} && test ! -w ${pdir}; then
487        writable=false
488        break
489    elif test ! -e ${pdir} ; then
490        pdir=`dirname ${pdir}`
491    else
492        break
493    fi
494done
495if test "x${pdir}" == "x/" ; then
496    writable=false
497fi
498if ! ${writable} ; then
499    echo -e \
500"  \033@<:@1;31mPrefix ${prefix} not writable
501  please run ./configure --prefix=DIR
502  with a writable directory path otherwise administrator privilages
503  will be required to run \`make install'\033@<:@0m"
504    warn=true
505fi
506
507case ${prefix} in
508   ${HOME}|${HOME}/*)
509if $warn ; then
510    for (( i=5; i>0; i-- )); do
511        echo -ne "\rPlease read the above messages carefully, continuing in ${i} seconds"
512        sleep 1
513    done
514    echo -e "\rPlease read the above messages carefully                                 "
515fi
516echo \
517"
518*****************************************************************************
519
520  To successfully compile and run programs using the ADOL-C shared library do
521  the following things:
522     compiling:
523        * add \"-I${prefix}/include\" to your compiler call
524     linking:
525        * add \"-L${prefix}/${_lib} -ladolc\" to your linker call
526        * extend your linker call by \"-Wl,--rpath -Wl,${prefix}/${_lib}\"
527          (if you wish to skip the point \"executing\")
528     executing (do one of the following things):
529        * add ${prefix}/${_lib} to your LD_LIBRARY_PATH variable
530        * ask your system administrator for adding ${prefix}/${_lib} to
531          the global file containing library search paths (/etc/ld.so.conf)
532
533     (or use the static library by replacing
534        \"-L${prefix}/${_lib} -ladolc\" with
535        \"${prefix}/${_lib}/libadolc.a\" when linking)
536
537  See README for instructions on how to change to a nonlocal installation!
538
539*****************************************************************************
540"
541;;
542esac
Note: See TracBrowser for help on using the repository browser.