source: stable/2.2/configure.ac @ 231

Last change on this file since 231 was 231, checked in by kulshres, 8 years ago

regenerate files for stable branch and get rid of binaries

Signed-off-by: Kshitij Kulshreshtha <kshitij@…>

  • Property svn:keywords set to Author Date Id Revision
File size: 19.1 KB
Line 
1##############################################################################
2# configure.ac -- Process this file with autoconf to produce configure
3# Revision: $Id: configure.ac 231 2011-06-08 12:16:34Z kulshres $
4#
5# Copyright (C) Andrea Walther, Andreas Kowarz
6#               
7# contains patches from the COIN OR libtool
8#
9##############################################################################
10define([ADOLC_VER], [2])
11define([ADOLC_SUB], [2])
12define([ADOLC_LVL], [1])
13
14AC_PREREQ(2.57)
15AC_INIT(adolc,
16        ADOLC_VER.ADOLC_SUB.ADOLC_LVL-stable,
17        [adol-c@list.coin-or.org])
18AC_REVISION($Revision: 231 $)
19AC_CONFIG_SRCDIR([ADOL-C/src/adolc.h])
20AC_CONFIG_AUX_DIR(autoconf)
21AC_CONFIG_HEADERS([ADOL-C/src/config.h])
22AC_PREFIX_DEFAULT(${HOME}/adolc_base)
23AM_INIT_AUTOMAKE([dist-bzip2])
24
25if test "x$CFLAGS" == x ; then
26    ac_shell_cflags="not_set"
27else
28    ac_shell_cflags="$CFLAGS"
29fi
30if test "x$CXXFLAGS" == x ; then
31    ac_shell_cxxflags="not_set"
32else
33    ac_shell_cxxflags="$CXXFLAGS"
34fi
35
36# checks for programs
37AC_PROG_CXX
38AC_PROG_CC
39AC_PROG_CPP
40AC_PROG_INSTALL
41AC_PROG_LN_S
42AC_PROG_MAKE_SET
43AC_LIBTOOL_WIN32_DLL
44AC_PROG_LIBTOOL
45DOLT
46
47AC_CHECK_SIZEOF([void *])
48if test "x$ac_cv_sizeof_void_p" = "x8" ; then
49   _lib=lib64
50else
51   _lib=lib
52fi
53libdir='${prefix}/${_lib}'
54AC_SUBST(_lib)
55AC_SUBST(libdir)
56
57# checks for header files
58AC_HEADER_STDC
59AC_HEADER_TIME
60AC_HEADER_STDBOOL
61AC_CHECK_HEADERS([stddef.h stdlib.h stdio.h string.h unistd.h sys/timeb.h])
62
63# checks for types
64AC_C_CONST
65AC_C_INLINE
66AC_TYPE_SIZE_T
67AC_STRUCT_TM
68
69# Checks for library functions
70AC_FUNC_MALLOC
71AC_FUNC_REALLOC
72AC_CHECK_FUNCS([floor ftime pow sqrt strchr strtol])
73
74# substitutions
75AC_SUBST(ac_aux_dir)
76
77# Checks for libraries
78AC_CHECK_LIB([m], [pow])
79
80# ADOL-C configuration
81AC_DEFINE(ADOLC_VERSION,ADOLC_VER,[ADOL-C Version])
82AC_DEFINE(ADOLC_SUBVERSION,ADOLC_SUB,[ADOL-C Subversion])
83AC_DEFINE(ADOLC_PATCHLEVEL,ADOLC_LVL,[ADOL-C Patchlevel])
84ADOLC_VERSION=ADOLC_VER
85ADOLC_SUBVERSION=ADOLC_SUB
86ADOLC_PATCHLEVEL=ADOLC_LVL
87AC_SUBST(ADOLC_VERSION)
88AC_SUBST(ADOLC_SUBVERSION)
89AC_SUBST(ADOLC_PATCHLEVEL)
90
91AC_MSG_CHECKING(whether to use ADOL-C debug mode)
92AC_ARG_ENABLE(debug,
93              [
94AS_HELP_STRING([--enable-debug],[enable ADOL-C debug mode [default=no]])],
95  [AC_DEFINE(ADOLC_DEBUG,1,[ADOL-C debug mode])
96   AC_MSG_RESULT(yes)
97   adolc_debug="yes"],
98  [AC_MSG_RESULT(no)
99   adolc_debug="no"])
100
101AC_MSG_CHECKING(whether to use ADOL-C hard debug mode)
102AC_ARG_ENABLE(harddebug,
103              [
104AS_HELP_STRING([--enable-harddebug],[enable ADOL-C hard debug mode
105 [default=no]])],
106  [AC_DEFINE(ADOLC_HARDDEBUG,1,[ADOL-C hard debug mode])
107   AC_DEFINE(ADOLC_DEBUG,1,[ADOL-C debug mode])
108   AC_MSG_RESULT(yes)
109   adolc_harddebug="yes"],
110  [AC_MSG_RESULT(no)
111   adolc_harddebug="no"])
112
113AC_MSG_CHECKING(whether standard adouble constructor shall zero value)
114AC_ARG_ENABLE(stdczero,
115              [
116AS_HELP_STRING([--enable-stdczero],[adouble standard constructor zeros value
117(at the cost of performance) [default=no]])],
118  [AC_DEFINE(ADOLC_ADOUBLE_STDCZERO,1,[ADOL-C adouble zeroing mode])
119   AC_MSG_RESULT(yes)
120   adolc_stdczero="yes"],
121  [AC_MSG_RESULT(no)
122   adolc_stdczero="no"])
123
124AC_MSG_CHECKING(whether errno is thread save)
125AC_ARG_ENABLE(tserrno,
126              [
127AS_HELP_STRING([--enable-tserrno],[use errno as thread number cache [default=no]])],
128  [AC_DEFINE(ADOLC_THREADSAVE_ERRNO,1,[ADOL-C thread save errno mode])
129   AC_MSG_RESULT(yes)
130   adolc_tserrno="yes"],
131  [AC_MSG_RESULT(no)
132   adolc_tserrno="no"])
133
134AC_MSG_CHECKING(whether external function call forces backup of all adoubles)
135AC_ARG_ENABLE(safe_extern,
136              [
137AS_HELP_STRING([--enable-safe-extern],[backup all adoubles before calling an external function [default=no]])],
138  [AC_DEFINE(ADOLC_SAFE_EXTERN,1,[ADOL-C safe extern mode])
139   AC_MSG_RESULT(yes)
140   adolc_safe_extern="yes"],
141  [AC_MSG_RESULT(no)
142   adolc_safe_extern="no"])
143
144# ADOL-C Sparse facility
145AC_MSG_CHECKING(whether to build sparse drivers)
146AC_ARG_ENABLE(sparse,
147            [
148AS_HELP_STRING([--enable-sparse],[build sparse drivers [default=disabled]])],
149            [sparse=$enableval
150             AC_MSG_RESULT(yes)],
151            [sparse="no"
152             AC_MSG_RESULT(no)])
153
154test "x${ac_pwd}" = x && ac_pwd=`pwd`
155abs_srcdir=`readlink -f ${ac_pwd}/${srcdir}`
156AC_ARG_WITH(colpack,
157        [
158AS_HELP_STRING([--with-colpack],[path to the colpack library and headers [default=${srcdir}/ThirdParty/ColPack]])],
159                [colpack=$withval],
160                [colpack=${abs_srcdir}/ThirdParty/ColPack])
161
162if test "x${_lib}" != xlib ; then
163   dirlist="${_lib} lib build/${_lib} build/lib"
164else
165   dirlist="${_lib} build/${_lib}"
166fi
167
168AC_LANG_PUSH([C++])
169for dir in $dirlist ; do
170    unset ac_cv_header_ColPackHeaders_h
171    COLPACK_CFLAGS="-I$colpack/$dir/../include"
172    COLPACK_LIBDIR="$colpack/$dir"
173    COLPACK_LIBS="-L$COLPACK_LIBDIR -lColPack -Wl,-rpath,$COLPACK_LIBDIR"
174    save_CPPFLAGS="$CPPFLAGS"
175    save_LIBS="$LIBS"
176    CPPFLAGS="$CPPFLAGS $COLPACK_CFLAGS"
177    LIBS="$COLPACK_LIBS $LIBS"
178    AC_MSG_CHECKING(for ColPack in $COLPACK_LIBDIR)
179    AC_CHECK_HEADER([ColPackHeaders.h],[have_colpackheaders=yes],[have_colpackheaders=no])
180    if test x$have_colpackheaders = xyes ; then
181        AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <ColPackHeaders.h>],
182                          [ColPack::GraphColoring g])],
183                       [have_colpack=yes
184                        AC_MSG_RESULT(linking with -lColPack succeeded)],
185                       [have_colpack=no,
186                        AC_MSG_RESULT(linking with -lColPack failed)])
187    else
188        have_colpack=no
189    fi
190    CPPFLAGS="$save_CPPFLAGS"
191    LIBS="$save_LIBS"
192    if test x$have_colpack = xyes ; then
193        break
194    fi
195done
196AC_LANG_POP([C++])
197AM_CONDITIONAL(HAVE_LIBCOLPACK,[test x$have_colpack = xyes])
198if test x$have_colpack = xyes; then
199   # test if the directories exists and what is the real path
200   # if not then we found ColPack in some standard location
201   # and these variables are useless
202   COLPACK_LIBDIR=`readlink -f $COLPACK_LIBDIR`
203   if test -n $COLPACK_LIBDIR ; then
204      colpack_incdir=`readlink -f $COLPACK_LIBDIR/../include`
205      if test -n $colpack_incdir ; then
206         COLPACK_CFLAGS="-I$colpack_incdir"
207      else
208         COLPACK_CFLAGS=""
209      fi
210      COLPACK_LIBS="-L$COLPACK_LIBDIR -lColPack -Wl,-rpath,$COLPACK_LIBDIR"
211   else
212      COLPACK_CFLAGS=""
213      COLPACK_LIBS=""
214   fi
215   # if the real path to ColPack is inside the ${srcdir}
216   # then we should statically link all ColPack objects inside libadolc
217   # it is likely that the srcdir is not needed anymore after make install
218   # and thus deleted thus no more ColPack to dynamically link to
219   # an external ColPack path is less likely to be removed
220   if echo $COLPACK_LIBDIR | grep -q ^${abs_srcdir} ; then
221       echo will link ColPack static as it was found in the source directory
222       test -d $COLPACK_LIBDIR/.tmp && rm -rf $COLPACK_LIBDIR/.tmp
223       mkdir -p $COLPACK_LIBDIR/.tmp/
224       mkdir -p $COLPACK_LIBDIR/.tmp/.libs
225       ( cd $COLPACK_LIBDIR/.tmp/ ; $AR x ../libColPack.a ; cp *.o .libs/
226         for i in *.o ; do j=`echo $i | sed 's/\.o/\.lo/' `
227                 cat >$j <<EOF
228# $j - a libtool object file
229# Generated by doltcompile, not libtool
230pic_object='.libs/$i'
231non_pic_object='$i'
232EOF
233        done
234        )
235       COLPACK_LIBS=`find "$COLPACK_LIBDIR/.tmp" -name \*.lo -printf "%p "`
236   fi
237   sparse=yes
238   echo "will build sparse drivers as linking with -lColPack succeeded"
239fi
240AM_CONDITIONAL(SPARSE,[test x${sparse} = xyes])
241
242if test x$sparse = xyes && test x$have_colpack = xyes; then
243        AC_DEFINE(HAVE_LIBCOLPACK,[1],[Define 1 if ColPack is available])
244else
245        COLPACK_CFLAGS=""
246        COLPACK_LIBS=""
247fi
248AC_SUBST(COLPACK_CFLAGS)
249AC_SUBST(COLPACK_LIBS)
250
251# ADOL-C Examples
252AC_MSG_CHECKING(whether to build documented examples)
253AC_ARG_ENABLE(docexa,
254            [
255AS_HELP_STRING([--enable-docexa],[build documented examples [default=disabled]])],
256            [docexa=$enableval
257             AC_MSG_RESULT(yes)],
258            [docexa="no"
259             AC_MSG_RESULT(no)])
260AM_CONDITIONAL(DOCEXA,[test x${docexa} = xyes])
261
262AC_MSG_CHECKING(whether to build additional examples)
263AC_ARG_ENABLE(addexa,
264            [AS_HELP_STRING([--enable-addexa],
265                            [build additional examples [default=disabled]])],
266            [addexa=$enableval
267             AC_MSG_RESULT(yes)],
268            [addexa="no"
269             AC_MSG_RESULT(no)])
270AM_CONDITIONAL(ADDEXA,[test x${addexa} = xyes])
271
272AC_MSG_CHECKING(whether to build parallel example)
273AC_ARG_ENABLE(parexa,
274            [AS_HELP_STRING([--enable-parexa],
275                            [build parallel example [default=disabled], if enabled -with-openmp-flag=FLAG required])],
276            [parexa=$enableval
277             AC_MSG_RESULT(yes)],
278            [parexa="no"
279             AC_MSG_RESULT(no)])
280AM_CONDITIONAL(PAREXA,[test x${parexa} = xyes])
281
282# ADOL-C Compilation flags
283AC_MSG_CHECKING(which flag to use to enable OpenMP)
284AC_ARG_WITH(openmp-flag,
285            [AS_HELP_STRING([--with-openmp-flag=FLAG],
286                            [use FLAG to enable OpenMP at compile time [default=none]])],
287            [ac_adolc_openmpflag=$withval
288             msg_result=$withval
289             AC_MSG_RESULT($ac_adolc_openmpflag)],
290            [ac_adolc_openmpflag=""
291             msg_result="none"
292             AC_MSG_RESULT($ac_adolc_openmpflag)])
293
294AC_MSG_CHECKING(which CFLAGS to use)
295AC_ARG_WITH(cflags,
296            [AS_HELP_STRING([--with-cflags=FLAGS],
297                            [use CFLAGS=FLAGS (default: -O2)])],
298            [ac_adolc_cflags="$withval"
299             if test x${adolc_debug} == xyes ||
300                test x${adolc_harddebug} == xyes ; then
301                ac_adolc_cflags="$ac_adolc_cflags -g -O0"
302             fi
303             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
304             AC_SUBST(ac_adolc_cflags)
305             AC_MSG_RESULT($ac_adolc_cflags)],
306            [if test "$ac_shell_cflags" = "not_set"; then
307                ac_adolc_cflags="-O2"
308                if test x${adolc_debug} == xyes ||
309                   test x${adolc_harddebug} == xyes ; then
310                   ac_adolc_cflags="-g -O3 -Wall -ansi"
311                fi
312             else
313                ac_adolc_cflags="$CFLAGS"
314             fi
315             ac_adolc_cflags="$ac_adolc_cflags $ac_adolc_openmpflag"
316
317             AC_SUBST(ac_adolc_cflags)
318             AC_MSG_RESULT($ac_adolc_cflags)])
319
320AC_MSG_CHECKING(which CXXFLAGS to use)
321AC_ARG_WITH(cxxflags,
322            [AS_HELP_STRING([--with-cxxflags=FLAGS],
323                            [use CXXFLAGS=FLAGS (default: -O2)])],
324            [ac_adolc_cxxflags="$withval"
325             if test x${adolc_debug} == xyes ||
326                test x${adolc_harddebug} == xyes ; then
327                ac_adolc_cxxflags="$ac_adolc_cxxflags -g -O0"
328             fi
329             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
330             AC_SUBST(ac_adolc_cxxflags)
331             AC_MSG_RESULT($ac_adolc_cxxflags)],
332            [if test "$ac_shell_cxxflags" = "not_set"; then
333                ac_adolc_cxxflags="-O2"
334                if test x${adolc_debug} == xyes ||
335                   test x${adolc_harddebug} == xyes ; then
336                   ac_adolc_cxxflags="-g -O0 -Wall"
337                fi
338             else
339                ac_adolc_cxxflags="$CXXFLAGS"
340             fi
341             ac_adolc_cxxflags="$ac_adolc_cxxflags $ac_adolc_openmpflag"
342            AC_SUBST(ac_adolc_cxxflags)
343             AC_MSG_RESULT($ac_adolc_cxxflags)])
344
345###########################################################################
346#                      COIN_PATCH_LIBTOOL_CYGWIN                          #
347###########################################################################
348
349# Patches to libtool for cygwin. Lots for cl, a few for GCC.
350# For cl:
351# - cygpath is not correctly quoted in fix_srcfile_path
352# - paths generated for .lib files is not run through cygpath -w
353
354#
355# REQUIRED FOR COMPILATION WITH CYGWIN !!!
356#
357 
358
359AC_DEFUN([AC_COIN_PATCH_LIBTOOL_CYGWIN],
360[ case "$CXX" in
361    cl* | */cl* | CL* | */CL* | icl* | */icl* | ICL* | */ICL*)
362      AC_MSG_NOTICE(Applying patches to libtool for cl compiler)
363      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
364          -e 's|fix_srcfile_path=\"\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
365          -e 's%compile_deplibs=\"\$dir/\$old_library \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$old_library | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
366          -e 's%compile_deplibs=\"\$dir/\$linklib \$compile_deplibs\"%compile_deplibs="'\`"$CYGPATH_W"' \$dir/\$linklib | sed -e '"'"'sY\\\\\\\\Y/Yg'"'"\`' \$compile_deplibs\"'% \
367          -e 's%lib /OUT:%lib -OUT:%' \
368          -e "s%cygpath -w%$CYGPATH_W%" \
369          -e 's%$AR x \\$f_ex_an_ar_oldlib%bla=\\`lib -nologo -list \\$f_ex_an_ar_oldlib | xargs echo '"$mydos2unix"'\\`; echo \\$bla; for i in \\$bla; do lib -nologo -extract:\\$i \\$f_ex_an_ar_oldlib; done%' \
370          -e 's/$AR t/lib -nologo -list/' \
371          -e 's%f_ex_an_ar_oldlib="\($?*1*\)"%f_ex_an_ar_oldlib='\`"$CYGPATH_W"' \1`%' \
372          -e 's%^archive_cmds=.*%archive_cmds="\\$CC -o \\$lib \\$libobjs \\$compiler_flags \\\\\\`echo \\\\\\"\\$deplibs\\\\\\" | \\$SED -e '"\'"'s/ -lc\\$//'"\'"'\\\\\\` -link -dll~linknames="%' \
373          -e 's%old_archive_cmds="lib -OUT:\\$oldlib\\$oldobjs\\$old_deplibs"%old_archive_cmds="if test -r \\$oldlib; then bla=\\"\\$oldlib\\"; else bla=; fi; lib -OUT:\\$oldlib \\\\\\$bla\\$oldobjs\\$old_deplibs"%' \
374      libtool > conftest.bla
375
376      mv conftest.bla libtool
377      chmod 755 libtool
378      ;;
379    *)
380      AC_MSG_NOTICE(Applying patches to libtool for GNU compiler)
381      sed -e 's|fix_srcfile_path=\"`cygpath -w \"\$srcfile\"`\"|fix_srcfile_path=\"\\\`'"$CYGPATH_W"' \\\"\\$srcfile\\\"\\\`\"|' \
382          -e 's|"lib /OUT:\\$oldlib\\$oldobjs\\$old_deplibs"|"\\$AR \\$AR_FLAGS \\$oldlib\\$oldobjs\\$old_deplibs~\\$RANLIB \\$oldlib"|' \
383          -e 's|libext="lib"|libext="a"|' \
384      libtool > conftest.bla
385
386      mv conftest.bla libtool
387      chmod 755 libtool
388      ;;
389  esac ]) # COIN_PATCH_LIBTOOL_CYGWIN
390 
391
392SHAVE_INIT([autoconf],[enable])
393
394# output
395AC_CONFIG_FILES(Makefile
396                autoconf/shave-libtool
397                autoconf/shave
398                ADOL-C/Makefile
399                ADOL-C/src/Makefile
400                ADOL-C/src/drivers/Makefile
401                ADOL-C/src/sparse/Makefile
402                ADOL-C/src/tapedoc/Makefile
403                ADOL-C/doc/version.tex
404                ADOL-C/examples/Makefile
405                ADOL-C/examples/additional_examples/Makefile
406                ADOL-C/examples/additional_examples/clock/Makefile
407                ADOL-C/examples/additional_examples/checkpointing/Makefile
408                ADOL-C/examples/additional_examples/ext_diff_func/Makefile
409                ADOL-C/examples/additional_examples/fixpoint_exam/Makefile
410                ADOL-C/examples/additional_examples/hessmat/Makefile
411                ADOL-C/examples/additional_examples/lufact/Makefile
412                ADOL-C/examples/additional_examples/openmp_exam/Makefile
413                ADOL-C/examples/additional_examples/scal/Makefile
414                ADOL-C/examples/additional_examples/speelpenning/Makefile
415                ADOL-C/examples/additional_examples/taylor/Makefile
416                ADOL-C/examples/additional_examples/detexam/Makefile
417                ADOL-C/examples/additional_examples/helm/Makefile
418                ADOL-C/examples/additional_examples/lighthouse/Makefile
419                ADOL-C/examples/additional_examples/ode/Makefile
420                ADOL-C/examples/additional_examples/sparse/Makefile
421                ADOL-C/examples/additional_examples/tapesave/Makefile
422                ADOL-C/examples/additional_examples/pow/Makefile
423                ADOL-C/examples/additional_examples/timing/Makefile
424                ADOL-C/test/Makefile
425                MSVisualStudio/v10/sparse/config.h
426                MSVisualStudio/v10/nosparse/config.h
427                MSVisualStudio/v10/x64/sparse/config.h
428                MSVisualStudio/v10/x64/nosparse/config.h
429                adolc.spec
430)
431
432AC_OUTPUT
433
434#call libtool for cygwin
435AC_COIN_PATCH_LIBTOOL_CYGWIN
436warn=false
437# echo configuration
438echo \
439"
440-----------------------------------------------------------------------------
441Configuration:
442
443  C compiler:                       ${CC}
444  C++ compiler:                     ${CXX}
445  Linker:                           ${LD}
446  Source code location:             `pwd`
447  Install path:                     ${prefix}
448 
449  CFLAGS:                           ${ac_adolc_cflags}
450  CXXFLAGS:                         ${ac_adolc_cxxflags}
451
452  Use ADOL-C debug mode:            ${adolc_debug}
453  Use ADOL-C hard debug mode:       ${adolc_harddebug}
454  Use ADOL-C adouble zeroing mode:  ${adolc_stdczero}"
455
456if [[ "x${ac_adolc_openmpflag}" != "x" ]] ; then
457    echo \
458"  Access thread number via errno:   ${adolc_tserrno}"
459fi
460
461echo \
462"  Use ADOL-C safe extern mode:      ${adolc_safe_extern}
463
464  Build sparse drivers:             ${sparse}
465  Build with ColPack:               ${have_colpack}"
466if test x$sparse = xyes && test x$have_colpack = xno; then
467    echo -e \
468"  \033@<:@1;31mCompressed sparse structures will not be available
469  Only sparsity patterns can be computed\033@<:@0m"
470    warn=true
471fi
472echo
473
474echo \
475"  Build documented examples:        ${docexa}
476  Build additional examples:        ${addexa}
477
478  See ADOL-C/src/config.h for further configuration information.
479-----------------------------------------------------------------------------"
480
481# check for make install problems resulting from missing write permission
482pdir=${prefix}
483writable=true
484while test "x${pdir}" != "x/" ; do
485    if test -e ${pdir} && test ! -w ${pdir}; then
486        writable=false
487        break
488    elif test ! -e ${pdir} ; then
489        pdir=`dirname ${pdir}`
490    else
491        break
492    fi
493done
494if test "x${pdir}" == "x/" ; then
495    writable=false
496fi
497if ! ${writable} ; then
498    echo -e \
499"  \033@<:@1;31mPrefix ${prefix} not writable
500  please run ./configure --prefix=DIR
501  with a writable directory path otherwise administrator privilages
502  will be required to run \`make install'\033@<:@0m"
503    warn=true
504fi
505
506case ${prefix} in
507   ${HOME}|${HOME}/*)
508if $warn ; then
509    for (( i=5; i>0; i-- )); do
510        echo -ne "\rPlease read the above messages carefully, continuing in ${i} seconds"
511        sleep 1
512    done
513    echo -e "\rPlease read the above messages carefully                                 "
514fi
515echo \
516"
517*****************************************************************************
518
519  To successfully compile and run programs using the ADOL-C shared library do
520  the following things:
521     compiling:
522        * add \"-I${prefix}/include\" to your compiler call
523     linking:
524        * add \"-L${prefix}/${_lib} -ladolc\" to your linker call
525        * extend your linker call by \"-Wl,--rpath -Wl,${prefix}/${_lib}\"
526          (if you wish to skip the point \"executing\")
527     executing (do one of the following things):
528        * add ${prefix}/${_lib} to your LD_LIBRARY_PATH variable
529        * ask your system administrator for adding ${prefix}/${_lib} to
530          the global file containing library search paths (/etc/ld.so.conf)
531
532     (or use the static library by replacing
533        \"-L${prefix}/${_lib} -ladolc\" with
534        \"${prefix}/${_lib}/libadolc.a\" when linking)
535
536  See README for instructions on how to change to a nonlocal installation!
537
538*****************************************************************************
539"
540;;
541esac
Note: See TracBrowser for help on using the repository browser.